Pilotage d' Excel

Version imprimable

17/01/2008, 21h30
Delbeke

Pilotage d' Excel

Bonsoir, tous

Je développe une application qui génére des fichiers excel, elle marche bien et je serais tres heureux si ce $=*&(?$ d'excel n'etait pas utilisé par ailleurs.

Si, lorsque mon programme tourne, quelqu'un s'avise de fermer excel (parce qu'il l'utilse dans le cadre de son travail), mon progrmme agonise avec des messages tellemnt affreux, que j'ose pas les répeter ici.

Quelqu'un a t' il des infos sur le moyen de piloter excel de façon, heu, disons comme un process séparé de celui qui est utilisé par les utilsateurs du poste ?

Que je puisse fermer ma session excel sans fermer les autres et si les autres sont fermées, que la mienne continue.

J'ai jamais fais ... mais peu-être en utilisant les événements de l'objet application Excel ... l'événement WorkbookBeforeClose .. qui apparaît à chaque fermeture de classeur.. et peu être utiliser pour "filtrer" la fermeture de tes classeurs....

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
 Dim WithEvents oExcel As Excel.Application
 Dim MonClasseur As Excel.Workbook ' Le classeur utilisé par mon application
Private Sub Form_Load()
 Set oExcel = New Excel.Application
 oExcel.Visible = True
 'Création de mon Classeur
 Set MonClasseur = oExcel.Workbooks.Add
 
End Sub
'
'événement sur fermeture d'un classeur..
'
Private Sub oExcel_WorkbookBeforeClose(ByVal Wb As Excel.Workbook, Cancel As Boolean)
  If Wb Is MonClasseur Then
     MsgBox "Fermer d'abords l'application " & App.EXEName
     Cancel = True
  End If
End Sub

;)

17/01/2008, 23h36
Delbeke

Je n'avais pas pensé à déclarer mes variables excel avec with events. Une piste que je vais tenter d'exploiter. Merci bbil, en tout cas
18/01/2008, 10h41
DarkVader

Couplé avec GetObject("", "Excel.Application") cela devrait faire ton affaire
sinon tu as aussi la possibilité de développer ton appli en tant qu'Addin.
18/01/2008, 11h04
Delbeke

Merci Darkvader.

Je ne connais pas le developpement d'addin pour excel. je vais me documenter la dessus.

Encore merci a tous ceux qui m'ont aidé a trouver une solution honorable

Et aux autres aussi :)

voila le code qui semble fonctionner dans tous les cas

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Option Explicit
 
Dim WithEvents AppExcel As Excel.Application  'atention, déclaré avec withevent
Dim WbExcel As Excel.Workbook
Dim WsExcel As Excel.Worksheet
Dim ExcelOnLine As Boolean        'flag à true si excel etait déjà ouvert
                                  'quand on a ouvert le fichier
Dim ExcelClosable As Boolean      'flag mis à false tant que l'on a pas décidé
                                  'qu'excel pouvait être fermé
 
Private Sub AppExcel_WorkbookBeforeClose(ByVal Wb As Excel.Workbook, Cancel As Boolean)
  'evenement declenché par l'objet Excel.Application
  'à chaque fermeture de workbook
  'note : si plusieurs feuilles sont fermées par la fermeture d'excel
  '       un seul refus empeche sa fermeture
  If Wb Is WbExcel Then
    'il s'agit de la fermeture de notre feuille
    If ExcelClosable Then
      'on a autorisé la fermeture d'excel, donc on ne fait rien
    Else
      'on refuse la fermeture du workbook
      Cancel = True
    End If
  End If
End Sub
 
 
Private Sub cmdOpenFile_Click()
  On Error Resume Next
  'on va essayer de retrouver une occurence de appExcel
  'si excell n'est pas lancé, on aura une erreur que
  'l'on va trapper
  Set AppExcel = GetObject(, "Excel.Application")
  If Err Then
    'excel n'est pas démarrer
    'on le démarre
    Set AppExcel = CreateObject("Excel.Application")
    ExcelOnLine = False
  Else
    'excel est démarré
    ExcelOnLine = True
  End If
 
  AppExcel.Application.Visible = True
  AppExcel.Application.Interactive = True
  'ouverture du workbook
  Set WbExcel = AppExcel.Workbooks.Open(txtFileName.Text)
  'et on refuse la fermeture d'excel
  ExcelClosable = False
  Set WsExcel = WbExcel.Worksheets(1)
  WsExcel.Unprotect
End Sub
 
Private Sub cmdWriteCell_Click()
  'un exemple d'ecriture dans la feuille
  WsExcel.Cells(1, 1) = "AAA"
 
End Sub
 
Private Sub cmdCloseFile_Click()
  'on  ferme notre fichier
  'donc excel doit pouvoir être fermé
  ExcelClosable = True
  WbExcel.Close False 'sans enreister pour ce simple test
  If ExcelOnLine Then
    'si excell etait lancé au démarrage
    'on n'a rien à faire
  Else
    'si on a lancé excel
    'on vérifie s'il reste de workbooks ouverte
    If AppExcel.Workbooks.Count = 0 Then
      'plus de workbooks, on ferme excel
      AppExcel.Quit
    End If
  End If
  'un peu de ménage
  Set WsExcel = Nothing
  Set WbExcel = Nothing
  Set AppExcel = Nothing
End Sub
 
Private Sub Form_Load()
  OpenFile1.InitDir = App.Path
End Sub

Ajouter sur une feuille,
un textbox : txtFileName
trois boutons de commandes : cmdOpenFile,cmdWriteCell,cmdCloseFile
et coler le code ci-dessus dans la feuille.