Combobox de recherche

Version imprimable

Bonjour,
J'ai un petit souci avec une combox, en fait j'avais à la base une texbox de recherche qui marchait bien et là j'ai voulu changer la texbox de recherche en combobox de recherche, c'est a dire que le critère de recherche est ce que l'utilisateur a choisi dans la combobox.
Voici le code:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Sub affiche_result_Click() combo = combobox1 'textbox1.text ou autre ligne = Worksheets("résultats de la recherche").Range("A65536").End(xlUp).Row 'modifier le nom de la feuille qui reçoit. On admet que cellule de la colonne A est toujours remplie With Worksheets("analyse").Range("E1:E5000") 'modifier le nom de la feuille origine Set c = .Find(combo, LookIn:=xlValues) If Not c Is Nothing Then firstAddress = c.Address Do i = i + 1 maligne = c.Row Worksheets("résultats de la recherche").Range("A" & i + ligne & ":p" & i + ligne).Value = Worksheets("analyse").Range("A" & maligne & ":p" & maligne).Value 'modifier le nom des lfeuilles Set c = .FindNext(c) Loop While Not c Is Nothing And c.Address <> firstAddress End If End With End Sub
De plus j'aimerai integrer également unenouvelle contrainte dans la recherche, c'est à dire le choix d'une combobox 2. Les résultats seraient alors l'intersection des resultats de la combobox1 et 2.Voilà.
Merci beaucoup pour votre aide.
Bonne soirée

17/12/2007, 17h49
fred65200

bonsoir,

essaie

Code:

combo = ComboBox1.Text

dans ton code, combobox1 est en minuscules et devrait s'écrire ComboBox1
est ce que ta combobox1 existe?

cordialement
17/12/2007, 18h02
arnold95

Ok. Merci.en fait j'ai trouvé la réponse, j'avais juste à selectionner la feuille avant de faire la macro. Par contre il reste la deuxième partie de la question qui consite a prendre le résultat des deux combobox pour lancer la recherche....

Code:

1
2
3
4
5
Dim maValeur1 As String
Dim maValeur2 As String
 
maValeur1 = ComboBox1.List(ComboBox1.ListIndex)
maValeur2 = ComboBox2.List(ComboBox2.ListIndex)

18/12/2007, 09h17
arnold95

Merci, en fait çà je l'avais mon problème est de savoir comment prendre en compte ces deux conditions dans la fonction find.

Citation:

Envoyé par arnold95

... Les résultats seraient alors l'intersection des resultats de la combobox1 et 2.Voilà. ...

Que veux tu dire par "l'intersection"?

Veux tu trouver une cellule contenant la valeur de ComboBox1 ET celle de ComboBox2?

Veux tu trouver une ligne contenant la valeur de ComboBox1 dans une cellule ET celle de ComboBox2 dans une autre cellule?

Dand le premier cas, une fois que Find a trouvé une cellule contenant la valeur de ComboBox1, on doit tester:
Code:

1 2 ' Si cette ligne est vraie, c.Vlaue contient aussi la valeur de ComboBox2 If InStr(1, c.Value, ComboBox2.List(ComboBox2.ListIndex)) > 0 Then
Dans le deuxième cas, une fois que Find a trouvé une cellule contenant la valeur de ComboBox1, on doit interroger chaque cellule à sa droite dans une boucle:
Code:

1 2 3 4 5 6 Dim cln As Long For cln = 1 To wksAnalyse.UsedRange.Columns.Count - 1 If InStr(1, c.Offset(0, cln).Value, ComboBox2.List(ComboBox2.ListIndex)) > 0 Then ' Ligne contenant les deux est trouvée End If Next cln

En passant, j'ai pris la liberté de reformuler ton code pour qu'il soit:

1.- plus clair, en faisant une indentation plus systématique
2.- plus rapide, en évitant les résolutions d'appels de membres des objet par le stockage dans des variable comme wksAnalyse et wksResultat
3.- plus facile à déboguer, en déclarant toutes les variables en début de procédure et avec des types spécifiques
4.- plus facile à modifier, en créant des constantes qui permettent de remplacer des valeur en un seul endroit sans les rechercher partout dans le code.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub affiche_result_Click()
    Const COL As String = "A"
    Dim wksAnalyse As Worksheet
    Dim wksResultat As Worksheet
    Dim c As Range
    Dim cln As Long
    Dim i As Long
    Dim ligne As Long
    Dim maligne As Long
    Dim firstAddress As String
 
    Set wksAnalyse = Worksheets("analyse")
    Set wksResultat = Worksheets("résultats de la recherche")
 
    'modifier le nom de la feuille qui reçoit. On admet que cellule de la colonne A est toujours remplie
    ligne = wksResultat.Range(COL & ":" & COL).Cells( _
                                                    wksResultat.Range(COL & ":" & COL).Cells.Count _
                                                    ).End(xlUp).Row
    'modifier le nom de la feuille origine
    With wksAnalyse.Range("E1:E5000")
        Set c = .Find(ComboBox1.List(ComboBox1.ListIndex), LookIn:=xlValues)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                i = i + 1
                maligne = c.Row
                wksResultat.Range(COL & i + ligne & ":p" & i + ligne).Value = wksAnalyse.Range(COL & maligne & ":p" & maligne).Value     'modifier le nom des lfeuilles
                Set c = .FindNext(c)
                If c Is Nothing Then Exit Do     ' Cette ligne est séparée du While suivant pour rapidité et
            Loop While c.Address <> firstAddress '   éviter le plantage de l'appel c.Address quand c = Nothing
        End If
    End With
End Sub

Ça devrait faire exactement ce que ça faisait auparavant, quoiqu'une ligne comme:

Code:

wksResultat.Range(COL & i + ligne & ":p" & i + ligne).Value = wksAnalyse.Range(COL & maligne & ":p" & maligne).Value     'modifier le nom des lfeuilles

n'assignera pas les valeurs de toutes les cellules comme tu semble le vouloir. Pour ça, il faudrait faire:

Code:

1
2
wksAnalyse.Range(COL & maligne & ":p" & maligne).Copy
wksResultat.Range(COL & i + ligne).PasteSpecial

Voilà!
;)