XML : création d'une architecture hiérarchisé

Bonjour à tous

J'ai un petit souci avec la création d'un fichier xml depuis une macro Vb Excel

J'ai réussi à créer des élement fils de l'element racine, des élements petit fils de la racine mais je n'arrive pas à créer des arrières petits fils

Pour etre plus clair voici un exemple :mrgreen:

je souhaite avoir quelque chose de ce genre
Code:

1 2 3 4 5 6 7 8 9 <racine> <Personne> <Nom>Nom1</Nom> <Prenom>Prenom1</Prenom> <titre> <ref> Mr X </ref> </titre> </Personne> </racine>
Ce que j'arrive à créer :
Racine , Personne , Nom, titre (mais ce n'est qu'une balise <titre />)

Ce que je n'arrive pas à faire :
créer ref et le rattaché à titre

Si vous pouviez m'aider sur la partie création de Titre et de ref , je vous en serais reconnaissant

tiens ... j'en profite pour remettre le code complet .. avec "l'indentention"
telle que proposée ici

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
 
'Create a DOMDocument object.
Dim xmlDoc 'As New DOMDocument40
'Create the reader.
Dim rdr' As New SAXXMLReader40
'Create the writer.
Dim wrt 'As New MXXMLWriter40
Set xmlDoc = CreateObject("MSXML2.DOMDOCUMENT.3.0")
set rdr = CreateObject("MSXML2.SAXXMLReader")
set wrt = CreateObject("MSXML2.MXXMLWriter")
'Load the DOM document.
xmlDoc.async = False
xmlDoc.resolveExternals = False
 
'-- Créer un document XML
Set oRacine = xmlDoc.createElement("Racine")
 
' Ajouter la racine dans le document
xmlDoc.appendChild oRacine
 
' Ajouter un élément
Set oElement = xmlDoc.selectSingleNode("Racine")  ' positionnement sur la racine
Set oElement = xmlDoc.createElement("element")    ' création d'un fils membre
xmlDoc.documentElement.appendChild oElement       ' crée le fils de la racine
 
' Ajouter des champs balises
Set oNom = xmlDoc.createElement("nom")
oNom.Text = "LENOM"
oElement.appendChild oNom
Set oNom = Nothing
 
Set oPrenom = xmlDoc.createElement("prenom")
oPrenom.Text = "Prénom"
oElement.appendChild oPrenom
Set oPrenom = Nothing
 
'-----------------------------------
set oTitre = xmlDoc.createElement("titre")
set oRef   = xmlDoc.createElement("ref")
oRef.Text = "Mr X"
oTitre.appendChild oRef
oElement.appendChild oTitre
Set oRef = Nothing
Set oTitre = Nothing
 
Set oElement = Nothing
 
'Set properties on the XML writer.
wrt.byteOrderMark = True
wrt.omitXMLDeclaration = False
wrt.indent = True
 
'Set the XML writer to the SAX content handler.
Set rdr.contentHandler = wrt
Set rdr.dtdHandler = wrt
Set rdr.errorHandler = wrt
 
'Parse the DOMDocument object.
rdr.parse xmlDoc
 
xmlDoc.loadXML wrt.output
xmlDoc.save "NewXML.xml"

En un mot : PARFAIT! :yaisse2:
Encore merci