[VBA]excel vers pdf

Version imprimable

[VBA]excel vers pdf

bonjour,
comment fait on pour passer le chemin du sendkey?
un bout de code:
Code:

1 2 3 4 5 6 7 Const ThePath As String = "C:\documents an settings\admin\bureau" Const TheFile As String = "Essai" Sub pdf() SendKeys ThePath & TheFile + "~" ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True End Sub
lorsque que je fais ca, la boite de dialogue s'ouvre et me dit que
"and settings\admin\bureau\essai" n'est pas un chemin valide 8O

quelqu'un peut m'aider??;)

12/10/2007, 15h09
Jean-Philippe André

salut,
il faut faire un

Code:

Replace(ThePath,"\","\\")

je crois
12/10/2007, 15h13
Oussbaba au rhum

merci de la reponse

pourquoi faire un replace? le sendkey ne prend pas les slash en charge?
12/10/2007, 15h15
Jean-Philippe André

non justement ^^
12/10/2007, 15h15
fred65200

bonjour

mets un slash à la fin
Const ThePath As String = "C:\documents an settings\admin\bureau\"
et ça doit fonctionner.

Salutations
frd65200
12/10/2007, 15h17
Jean-Philippe André

lol, au passage, il manque un d à and :p

1 pièce(s) jointe(s)

ca marche pas!!:P

Code:

1
2
3
4
5
6
7
8
9
Option Explicit
 
Const ThePath As String = "C:\documents an settings\admin\bureau\"
Const TheFile As String = "TheTestingFile.pdf"
 
Sub pdf()
SendKeys ThePath & TheFile + "~"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True
End Sub

12/10/2007, 15h24
fred65200

re

le D

Const ThePath As String = "C:\documents and settings\admin\bureau\"

Si tu n'est pas sous Vista, télécharge Clickie pour copier les noms de dossier /fichier,
Sur Vista, Shift + Clic sur le dossier / Fichier
ligne "Copier en tant que chemin d'accès"
@+
12/10/2007, 15h28
Oussbaba au rhum

Oups, c'est corrigé
mais cela ne change rien.........
12/10/2007, 15h30
Jean-Philippe André

essaie de récupérer le path du bureau par les variable environ()
12/10/2007, 15h31
fred65200

re

et ça

SendKeys ThePath & TheFile + "~"

SendKeys ThePath & TheFile & "~"

cordialement
12/10/2007, 17h24
Oussbaba au rhum

jpcheck,
je ne connais pas ce type de variables(eh oui un newb:oops:)

fred65200,
le fait de mettre l& ne change rien

Auriez une autre methode pr automatiser la saisie du nom de fichier?

re bonjour,
résumons le chemin est bon

Si tu le fais manuellement, tu choisis ton fichier et tu cliques sur ENTER

Essaies de mettre une temporisation, je t'ai mis 5, fais tes essais et réduis le délai d'attente

SendKeys ThePath & TheFile , True
Attendre 5
Sendkeys "~", true
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True
Code:

1 2 3 4 5 6 7 8 9 10 Function Attendre(Secondes As Integer) ' Cette procédure temporise pendant le nombre de secondes qu'on lui transmet en argument Dim Début As Long, fin As Long, Chrono As Long Début = Timer fin = Début + Secondes Do Until Timer >= fin DoEvents Loop End Function
fred65200

merci de ton aide fred
j'ai fait les tests.tout d'abord, j'ai du integrer la function attendre dans le sub car la pile était insuffisante
voilà le code:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Sub pdf2() SendKeys ThePath & TheFile, True 'attente Dim Début As Long, fin As Long, Chrono As Long Début = Timer fin = Début + 1 Do Until Timer >= fin DoEvents Loop 'envoi touche entrée SendKeys "~", True ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True End Sub
en fonction, ce code m'ouvre indefiniment la fenetre windows d'enregistrement de fichier

je ne sais plus quoi faire...8O

Citation:
Envoyé par fred65200
Code:

1 2 3 4 5 6 7 8 9 10 Function Attendre(Secondes As Integer) ' Cette procédure temporise pendant le nombre de secondes qu'on lui transmet en argument Dim Début As Long, fin As Long, Chrono As Long Début = Timer fin = Début + Secondes Do Until Timer >= fin DoEvents Loop End Function
Hello Fred, tu sais qu'on peut remplacer cette fonction par

Code:

Wait Secondes

;)
Ceci dit, je n'ai toujours pas compris le problème.
Oussbaba au rhum, tu as toujours le message sur "C:\Documents and Settings\admin\bureau\essai" n'est pas un chemin valide ?

15/10/2007, 09h49
Oussbaba au rhum

bonjour ouskel'nor
je vais essayer de faire au plus simple
mon but est d'automatiser la sortie en pdf d'un excel sans le passage par la fenetre d'enregistrement windows
l'impression pdf fonctionne jusqu'à la fenetre d'enregistrement où celle ci me demande comment et où je veux enregistrer le pdf
c'est cette étape que je veux automatiser en codant le chemin et le nom
15/10/2007, 10h49
ouskel'n'or

Désolé mais je n'ai pas la solution.
Printout a deux paramètres : PrintToFile et PrToFileName. Je n'ai jamais testé et en principe c'est fait pour créer un fichier d'impression mais tu peux toujours tester... Je ne peux pas le faire (j'utilise pdfcreator) A tout hasard...

Code:

... , PrintToFile:=True, PrToFileName:=Chemin & NomFich

Je ne pense pas que ça fonctionnera mais sait-on jamais :(
J'ai vu passer une réponse où les paramètres de fichier, de path et de format étaient définis mais il s'agissait (ici) d'Acrobat Distiller.
Enfin, quelle version d'Excel as-tu ? Avec 2007, tu as un export au format pdf disponible (voir la FAQ)
Après, je suis sec :cry:

Dans Acrobat Distiller ( si tu l'as )
Menu Fichier | Préférences
Décocher les Options idoines dans "Options de Sortie"
Sinon un code similaire , à adapter

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
'   sous VBE Menu Outils | Références
'   Cocher Acrobat Distiller
 
Sub Tst_Adobe_PDF_02()
Dim sNomFichierPS As String
Dim sNomFichierPDF As String
Dim PDFDist As PdfDistiller
 
'   sur un PC Personnel : a priori Choix libre du Nom et de l'emplacement du fichier de sortie
'
'   Sur un PC "Entreprise"
'   Il faut être logué en Administrateur ou en Avoir les droits pour utiliser Distiller
'   Les chemins doivent être de la forme :
'       "C:\Documents and Settings\UserName\Mes documents\....."
 
    sNomFichierPS = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.ps"
    sNomFichierPDF = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.pdf"
 
    ActiveSheet.Range("Zone").PrintOut copies:=1, Preview:=False, _
        ActivePrinter:="Acrobat PDF", PrintToFile:=True, _
        Collate:=True, PrToFilename:=sNomFichierPS
 
    Set PDFDist = New PdfDistiller
    PDFDist.FileToPDF sNomFichierPS, sNomFichierPDF, ""
    Set PDFDist = Nothing
 
    Kill sNomFichierPS
    Kill ThisWorkbook.Path & "\" & "Essai_AdobbePDF.log"
End Sub

merci bcp kiki
mon pb est resolu grace a ton code que j'ai un peu modifié

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub Adobe_PDF()
 
Dim NomPS, NomPDF, NomLog As String
Dim nom, path, dte As String
Dim PDFm As PdfDistiller
 
    nom = ActiveSheet.Range("E13").Value '& ActiveSheet.Range("C36")
    path = "\\*****\partage\"
 
    NomPS = path & nom & ".ps"
    NomPDF = path & nom & ".pdf"
    NomLog = path & nom & ".log"
 
    ActiveSheet.PrintOut copies:=1, Preview:=False, _
        ActivePrinter:="Acrobat PDF on Ne00:", PrintToFile:=True, _
        Collate:=True, PrToFilename:=NomPS
 
    Set PDFm = New PdfDistiller
    PDFm.FileToPDF NomPS, NomPDF, ""
    Set PDFm = Nothing
 
    Kill NomPS
    Kill NomLog
End Sub

:king:Encore merci pour votre aide et votre rapidité:king:

15/10/2007, 16h05
kiki29

Re
Une remarque dans Dim NomPS, NomPDF, NomLog As String seul NomLog sera de type String mais pas NomPS ni NomPDF qui seront de type Variant
donc : Dim NomPS As String, NomPDF As String , NomLog As String
-d°- pour le reste

Une autre remarque : à quoi bon répéter un code simlilaire à celui proposé sinon pour encombrer le paysage ?
15/10/2007, 18h24
Oussbaba au rhum

merci pour cette remarque

le fait de diffuser mon code est uniquement pour montrer ce a quoi vous avez participer

de plus a pres plusieurs tests, l'imprimante par de faut ne se modifie pas avec ce code.je m'explique, bien que ce soit l'imprimante pdf dans le code, il imprime en fichier sur l'imprimante hp....:cry:

Normal ! Tu désignes l'imprimante PDF dans ta ligne de commande, tu ne modifies pas l'imprimante par défaut.
Pour modifier l'imprimante par défaut, il faudrait mettre

Code:

Application.activeprinter = "Acrobat PDF on Ne00:"

Et pour remettre l'imprimante par défaut, tu dois mettre avant la ligne
Code:

1 2 3 4 5 6 7 ImpriDefaut = Application.activeprinter 'puis Application.activeprinter = "Acrobat PDF on Ne00:" 'Ton code pour générer le PDF '....... 'puis, pour rétablir Application.activeprinter = ImpriDefaut
Bonne soirée

15/10/2007, 21h50
fred65200

merci pour l'info ouslel'n'ou

Citation:

Hello Fred, tu sais qu'on peut remplacer cette fonction par
Code :
Wait Secondes

Je ne connaissais pas.:yaisse2:
fred65200
15/10/2007, 22h46
ouskel'n'or

Donnant donnant ! Que m'apprends-tu aujourd'hui ? Il te reste une heure 18... 17 ...:mouarf:
15/10/2007, 23h24
kiki29

Re,
ou peut-être plutôt
Application.ActivePrinter = "Adobe PDF sur NeXY:"
ou XY sera à trouver via le macro recorder
16/10/2007, 09h22
ouskel'n'or

Citation:

Envoyé par kiki29

Re,
ou peut-être plutôt
Application.ActivePrinter = "Adobe PDF sur NeXY:"
ou XY sera à trouver via le macro recorder

Ouskel' est la macro Recorder ? :lol:
Hello Kiki,
La question sur les PDF est récurrente. Il serait intéressant que tu places ton code dans Contribuez. Tu donnes le contexte (Distiller ou pas Distiller), le code et les outils annexes, par exemple la fameuse macro Recorder...
Tu seras le bienvenu et ton code pourra être mis dans la FAQ.
Par avance, merci pour tous
A+

PS - Sais-tu à quoi correspond exactement le "on NeNN:" ou "sur NeNN:" nécessaire dans la désignation de l'imprimante ? Merci

j'ai resolu mon pb d'imprimante
ca venait du fait que le port n'est pas toujours le meme
j'ai donc trouvé ceci(eh non ce n'est pas de moi:oops:) qui marche nickel
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Sub SélectImprimante() For i = 0 To 9 nom = "Adobe PDF sur Ne0" & i & ":" On Error Resume Next Application.ActivePrinter = nom If ActivePrinter = nom Then Exit For End If Next End Sub
merci pour votre aide:king:

Pour me contredire moi même en encombrant le paysage, en combinant l'ensemble des codes fournis par Oussbaba au rhum et Ouskel'n'or, au final le code devrait être du style

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
'   sous VBE Menu Outils | Références
'   Cocher Acrobat Distiller
 
Sub Tst_Adobe_PDF_03()
Dim sNomFichierPS As String
Dim sNomFichierPDF As String
Dim sNomFichierLOG As String
Dim PDFDist As PdfDistiller
Dim PrinterDefault As String
 
    '   Sur un PC "Personnel" : a priori choix libre du Nom
    '   et de l'emplacement du fichier de sortie
    '
    '   Sur un PC "Entreprise" :
    '   Il faut être logué en Administrateur ou en
    '   Avoir les droits pour utiliser Distiller
    '   Les chemins PS PDF LOG devront être de la forme :
    '       "C:\Documents and Settings\UserName\.....\....."
 
    '   Si l'on a plusieurs imprimantes il faut :
    '       Sélectionner l'imprimante virtuelle Adobe PDF tout en conservant
    '           trace de l'imprimante utilisée par défaut
    '   Le N° de port réseau NeXY varie suivant le PC sur lequel la macro tourne
 
    PrinterDefault = Application.ActivePrinter
    Application.ActivePrinter = Imprimante_AdobePDF
 
    sNomFichierPS = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.ps"
    sNomFichierPDF = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.pdf"
    sNomFichierLOG = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.log"
 
    '   Impression d'une zone nommée
    ActiveSheet.Range("Zone").PrintOut Copies:=1, Preview:=False, _
                                       ActivePrinter:="Acrobat PDF", PrintToFile:=True, _
                                       Collate:=True, PrToFilename:=sNomFichierPS
 
    Set PDFDist = New PdfDistiller
    PDFDist.FileToPDF sNomFichierPS, sNomFichierPDF, ""
    Set PDFDist = Nothing
 
    Kill sNomFichierPS
    Kill sNomFichierLOG
 
    Application.ActivePrinter = PrinterDefault
End Sub
 
Private Function Imprimante_AdobePDF() As String
Dim i As Integer
Dim NomPortReseau As String
    ' 11 imprimantes réseau
    For i = 0 To 10
        If i < 10 Then
            NomPortReseau = "Adobe PDF sur Ne0" & i & ":"
        Else
            NomPortReseau = "Adobe PDF sur Ne" & i & ":"
        End If
        On Error Resume Next
        Application.ActivePrinter = NomPortReseau
        If ActivePrinter = NomPortReseau Then
            Exit For
        End If
    Next i
    Imprimante_AdobePDF = NomPortReseau
End Function

16/10/2007, 13h05
Oussbaba au rhum

Citation:

Envoyé par kiki29

Pour me contredire moi même en encombrant le paysage, en combinant l'ensemble des codes fournis par Oussbaba au rhum et Ouskel'n'or, au final le code devrait être du style

:mouarf: elle est pas mal celle la :mouarf: