[XSLT] xsl:sort + apply-templates

Version imprimable

03/10/2007, 14h49
yos

[XSLT] xsl:sort + apply-templates
Salut tout le monde
J'ai une question sur le xsl:sort utilisé avec apply-templates
Code:

1 2 3 4 5 6 <xsl:apply-templates select="noeud"> <xsl:sort select"..."/> </xsl:apply-templates> <xsl:template match="noeud"> ...instructions... </xsltemplate>
dans mes resultat de transformation l'appel de templates ne s'applique pas sur le resulatat de sort
j'aimerai savoir comment faire appliquer l'appel de templates sur le resultat de tri plutot que sur le xml d'origine ?

merci pour votre aide
03/10/2007, 15h14
Morbo

Pourtant ça devrait marcher, c'est prévu pour marcher comme ça : http://xmlfr.org/w3c/TR/xslt/#tri
03/10/2007, 15h41
GrandFather

Bonjour,

Citation:

Envoyé par yos

dans mes resultat de transformation l'appel de templates ne s'applique pas sur le resulatat de sort

C'est pourtant bien ce qui doit se passer en réalité. Quel est le traitement du template 'noeud' ?

avec un exemple je serai plus explicite
imaginons un fichier xml

Code:

1
2
3
4
5
6
<data>
	<doc id="1" title="title one" />
	<doc id="2" title="title two" />
	<doc id="3" title="title three" />
	<doc id="4" title="title four" />
</data>

si je voeux trier sur les @title avec un tri "ascending" je ferais

Code:

1
2
3
<xsl:apply-templates select="doc">
 <xsl:sort select="@title" order="ascending" lang="fr"/>
</xsl:apply-templates>

j'obtiens

Code:

1
2
3
4
<doc id="4" title="title four"/>
<doc id="1" title="title one"/>
<doc id="3" title="title three"/>
<doc id="2" title="title two"/>

ça va jusqu'à là
maintenant j'aimrai pour chaque noeud son précédant direct

Code:

1
2
3
4
5
6
7
8
<xsl:template match="doc">
 <xsl:copy>
  <xsl:copy-of select="@*"/>
    <xsl:element name="precedant">
	<xsl:copy-of select="preceding-sibling::doc[1]"/>
   </xsl:element>
  </xsl:copy>
</xsl:template>

le resultat est le suivant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
        <doc id="4" title="title four">
		<precedant>
			<doc id="3" title="title three"/>
		</precedant>
	</doc>
	<doc id="1" title="title one">
		<precedant/>
	</doc>
	<doc id="3" title="title three">
		<precedant>
			<doc id="2" title="title two"/>
		</precedant>
	</doc>
	<doc id="2" title="title two">
		<precedant>
			<doc id="1" title="title one"/>
		</precedant>
	</doc>

alors que <doc id"4"> n'a pas de précédant dans le résultat de tri
l'appel de template se fait donc sur l'xml d'origine
le passage par une variable pourait résoudre le problème mais comment faire autrement?

Citation:

Envoyé par yos

l'appel de template se fait donc sur l'xml d'origine

L'appel du template se fait bien selon l'ordre spécifié par le tri, et c'est plutôt l'expression XPath preceding-sibling::doc[1] qui est évaluée selon le XML d'origine, nuance. ;)

Mis à part cela, il n'y a pas de solution simple à ton problème, hormis utiliser la fonction exslt:node-set() si ton processeur XSLT la supporte. Ce qui donne :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:exslt="http://exslt.org/common">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="data">
        <xsl:copy>
            <xsl:variable name="docs">
                <xsl:for-each select="doc">
                    <xsl:sort select="@title"/>
                    <xsl:copy-of select="."/>
                </xsl:for-each>
            </xsl:variable>
            <xsl:for-each select="exslt:node-set($docs)/*">
                <xsl:copy>
                    <xsl:copy-of select="@*"/>
                    <xsl:element name="precedent">
                        <xsl:copy-of select="preceding-sibling::doc[1]"/>
                    </xsl:element>
                </xsl:copy>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Merci GrandFather pour ta réponse
mon processeur ne supporte pas la fonction exslt:node-set()
pour résoudre ce problème, un passage par une variable pour stocker le résultat du tri avant d'appliquer l'expression xpath, cette solution est un peut lourde mais fonctionne

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="utf-8" indent="yes"/>
    <xsl:template match="/">
        <xsl:apply-templates/>
    </xsl:template>
 
    <xsl:template match="data">
       <xsl:variable name="docs">
            <xsl:for-each select="doc">
                <xsl:sort select="@title" order="ascending" lang="fr"/>
                <xsl:copy-of select="."/>
            </xsl:for-each>
        </xsl:variable>      
            <xsl:apply-templates select="$docs/doc"/>        
    </xsl:template>
 
 
    <xsl:template match="doc">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:element name="precedant">
                <xsl:copy-of select="preceding-sibling::doc[1]"/>
            </xsl:element>
        </xsl:copy>
    </xsl:template>

autres suggestions?

04/10/2007, 10h52
GrandFather

Citation:

Envoyé par yos

pour résoudre ce problème, un passage par une variable pour stocker le résultat du tri avant d'appliquer l'expression xpath, cette solution est un peut lourde mais fonctionne

Ah non, ça ne peut pas fonctionner. Ta variable ainsi créée n'est pas un node-set, mais un RTF (Result Tree Fragment) qui ne peut pas être utilisé dans une expression XPath ; à moins de le transformer au préalable en node-set, ce que fait justement exslt:node-set().

Je suis étonné que ton processeur XSLT ne supporte pas les extensions EXSLT, à peu près tous le font... MSXML ne les supporte pas en tant que telles, mais propose sa propre version avec un espace de noms particulier (urn:schemas-microsoft-com:xslt).
04/10/2007, 11h06
yos

Citation:

Ah non, ça ne peut pas fonctionner.

pourtant j'obtient bien le résultat attendu ?!
04/10/2007, 11h19
GrandFather

Citation:

Envoyé par yos

pourtant j'obtient bien le résultat attendu ?!

Pas possible, en tous cas avec Xalan, MSXML 3.0, MSXML 4.0 et le processeur XSLT d'Altova, avec lesquels je viens de vérifier.

Soit tu t'es trompé, soit tu utilises un processeur XSLT qui ne respecte pas du tout la spécification XSLT 1.0.

Edit: Tu n'utiliserais pas un processeur XSLT 2.0, par hasard ?
04/10/2007, 11h30
yos

Code:

Edit: Tu n'utiliserais pas un processeur XSLT 2.0, par hasard ?

c'est exactement cela :king:
mais pourquoi ça fonctionne avec XSLT2.0
04/10/2007, 14h21
GrandFather

Citation:

Envoyé par yos

mais pourquoi ça fonctionne avec XSLT2.0

Parce qu'en XSLT 2.0 le type de variable RTF n'existe (heureusement) plus.
04/10/2007, 17h52
yos

Merci grandFather pour toutes ces précisions
donc si j'ai bien compris ma solution serait bonne à condition d'utiliser XSLT2.0
et ma variable est bien un nod-set récupéré avec <xsl:copy> ?