[VBA] userform dynamique

Version imprimable

[resolu] [VBA] userform dynamique

Bonjour,

Je suis sur un projet dans lequel je cree dynamiquement des controls dans mon userform. Le probleme c est que je n arrive pas a associer des fonctions a ses controls.

Lors de la definition de mon control, j aimerais pouvoir definir quelle fonction executer si on clique sur le control: une fonction du genre onclick qui appelle une macro.

voila par exemple un label qui est cree.
Code:

1 2 3 4 5 6 7 8 9 Set myLabel = mainscreen.Controls.add("forms.Label.1") With myLabel .name = "templabelC" & i - 1 & "L" & j .Object.Caption = labeltext .left = 54 + 60 * j - 60 .Top = 20 * i + 51 .Width = 70 .Height = 100 End With
Merci d' avance pour votre aide

21/09/2007, 13h53
ouskel'n'or

Regarde ici, je pense que tu y trouveras ton bonheur ;)
21/09/2007, 14h27
kepi

J ai regarde le lien que tu m as donne, ca permet juste de changer dynamiquement des controls qui sont deja bien defini dans ton userform. Moi je cree dynamiquement les controls dans le programme et je voudrais pouvoir y associer une fonction quand on clique dessus.

Que ce soit des label ou button, j arrive pas a affecter une action dessus

Bonsoir,

Dans un module de classe nommé DynButton:

Code:

1
2
3
4
5
Public WithEvents Button As MSForms.CommandButton
 
Private Sub Button_Click()
    MsgBox Button.Name
End Sub

Dans le formulaire:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim DynButtons As Collection
 
Private Sub UserForm_Initialize()
    Dim i As Integer, NewButton As MSForms.CommandButton
    'Crée une nouvelle collection
    Set DynButtons = New Collection
    For i = 1 To 3
        'Ajoute un bouton sur le formulaire
        Set NewButton = Me.Controls.Add("Forms.CommandButton.1")
        'Positionne le controle
        NewButton.Top = (i - 1) * 30
        'Ajoute une instance du module à la collection
        DynButtons.Add New DynButton
        'Connecte l'instance du module au bouton du formulaire
        Set DynButtons(i).Button = NewButton
    Next
End Sub

Le même principe est valable pour des Labels, Checkbox etc.

Cordialement,

Tirex28/

24/09/2007, 11h01
kepi

C est exactement ce que je recherchais et ca marche tres bien, merci beaucoup.
24/09/2007, 19h25
AlainTech

Tu n'aurais pas oublié de cliquer sur :resolu:, par hasard?