problème wdSendToPrinter si variable word object

Version imprimable

Salut les gars (et les filles)

j'ai une question sur un problème qui commence à me :evilred:

Pour un publipostage j'utilise des variables object pour manipuler word
Code:

1 2 3 4 5 6 Dim appWord As Object Dim docWord As Object Set appWord = CreateObject("Word.Application") Set docWord = appWord.Documents.Open(ThisWorkbook.Path & "\formulaire attestation de non conduite")
Jusque la pas de problème

par contre quand j'arrive a la partie ou je lui demande d'imprimer le publipostage, il ne semble pas reconnaitre

Code:

.Destination = wdSendToPrinter

car il le gere comme si c'était un

Code:

.Destination = wdSendToNewDocument

et donc n'imprime pas mes documents mais me propose de les enregistrer

Ce qui me semble bizard c'est que si j'ai une référence word dans mon projet, ca fonctionne très bien. idem si j'utilise des variable Word.application etc.

Avez vous une idée?

PS : pour le moment je j'ai fais un
Code:

1 2 3 appWord.PrintOut Application.Wait TimeSerial(Hour(Now), Minute(Now), Second(Now) + 10)
le wait étant la pour laisser le temps à l'imprimante de se reveiller sinon ca sort avant de sortir une feuille

10/09/2007, 11h28
ouskel'n'or
Et si tu ajoutes la ligne
Code:

1 2 .Destination = wdSendToPrinter .Execute Pause:=True
S'il y a une erreur, il te l'indiquera... A tout hasard. Mais il est vrai qu'il faut laisser le temps à Word "d'inspirer" l'imprimante... et des fois, ces petites bêtes mettent du temps à se décider.
En outre, je mettrais des DoEvents un peu partout pour voir (à la place de ton Wait)
Juste une idée
10/09/2007, 11h36
jfontaine

la ligne

Code:

.Execute Pause:=True

est bien présente, mais c'est le

Code:

.Destination = wdSendToPrinter

qui pose problème puisque il se comporte comme

Code:

.Destination = wdSendToNewDocument

Pour info j'ai testé sur 2 machines différentes

Je met le code de la macro au cas ou

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
 
Public Sub publipostage(ByVal pageFin As Integer)
'Nécessite d'activer la référence "Microsoft Word xx.x Object Library"
'
Dim appWord As Object
Dim docWord As Object
 
'Dim appWord As Word.Application
'Dim docWord As Word.Document
 
Dim NomBase As String
 
NomBase = ThisWorkbook.Path & "\" & ThisWorkbook.Name
 
Application.ScreenUpdating = False
 
Set appWord = CreateObject("Word.Application")
'Set appWord = New Word.Application
 
appWord.Visible = False
 
'Ouverture du document principal Word
Set docWord = appWord.Documents.Open(ThisWorkbook.Path & "\formulaire attestation de non conduite")
 
'fonctionnalité de publipostage pour le document spécifié
With docWord.mailMerge
 
    'Ouvre la base de données
    .OpenDataSource Name:=NomBase, _
    Connection:="Driver={Microsoft Excel Driver (*.xls)};" & _
    "DBQ=" & NomBase & "; ReadOnly=True;", _
    SQLStatement:="SELECT * FROM [Saisie$]"
 
    'Spécifie la fusion vers l'imprimante
    '.Destination = wdSendToPrinter
    .Destination = wdSendToNewDocument
    .suppressBlankLines = True
    'Prend en compte l'ensemble des enregistrements
 
    With .DataSource
        .firstRecord = 2
        .LastRecord = pageFin
 
    End With
 
    'Exécute l'opération de publipostage
    .Execute Pause:= True
End With
 
'Edition
 
'Code si wdSendToNewDocument en commentaire si wdSendToPrinter
appWord.PrintOut
Application.ScreenUpdating = True
Application.Wait TimeSerial(Hour(Now), Minute(Now), Second(Now) + 10)
 
'Fermeture du document Word
docWord.Close False
appWord.Quit False
 
End Sub

10/09/2007, 12h34
ouskel'n'or
Il y a un truc qui m'étonne dans ton code, tu fixes les pages à imprimer après avoir envoyé le résultat de la fusion vers l'imprimante. J'ai vérifié dans l'aide Word, et j'ai eu ceci
Code:

1 2 3 4 5 6 7 With ActiveDocument.MailMerge .DataSource.FirstRecord = 1 .DataSource.LastRecord = 4 .Destination = wdSendToPrinter .SuppressBlankLines = True .Execute End With
Ensuite, il faut laisser au système le temps de traiter... J'ajouterais un doevents sur la ligne suivante. Sans garantie quant à l'efficacité, mais ton Wait pallie ce problème au cas où ce serait insuffisant.
Tu testes pour nous ?
A+
10/09/2007, 14h25
jfontaine

mettre le FirstRecord avant ne change rien.

je ne pense pas qu'il y ait un problème sur cette partie, puisque'il fonctionne si j'ajoute la référence word 11.
C'est quand je la retire que ca ne fait rien (pas d'erreur et pas d'impression. Juste word qui s'ouvre et se ferme avec le fichier de publipostage)
10/09/2007, 16h31
ouskel'n'or

Qu'est-ce qui t'ennuie avec le Printout ?
Tu as essayé avec DoEvents ?

Je crois que je me suis mal exprimé (c'est ce qui arrive quand sa sonne de partout :oops:

Je reprend.

Le code ci dessous fonctionne si la référence Microsoft Word 11 est ajouté au projet

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
 
Public Sub publipostage(ByVal pageFin As Integer)
'Nécessite d'activer la référence "Microsoft Word xx.x Object Library"
'
Dim appWord As Object
Dim docWord As Object
 
 
Dim NomBase As String
 
NomBase = ThisWorkbook.Path & "\" & ThisWorkbook.Name
 
Application.ScreenUpdating = False
 
Set appWord = CreateObject("Word.Application")
 
appWord.Visible = False
 
'Ouverture du document principal Word
Set docWord = appWord.Documents.Open(ThisWorkbook.Path & "\formulaire attestation de non conduite")
 
'fonctionnalité de publipostage pour le document spécifié
With docWord.mailMerge
 
    'Ouvre la base de données
    .OpenDataSource Name:=NomBase, _
    Connection:="Driver={Microsoft Excel Driver (*.xls)};" & _
    "DBQ=" & NomBase & "; ReadOnly=True;", _
    SQLStatement:="SELECT * FROM [Saisie$]"
 
    'Spécifie la fusion vers l'imprimante
    .Destination = wdSendToPrinter
 
    .suppressBlankLines = True
    'Prend en compte l'ensemble des enregistrements
 
    With .DataSource
        .firstRecord = 2
        .LastRecord = pageFin
 
    End With
 
    'Exécute l'opération de publipostage
    .Execute Pause:= True
End With
 
 
'Fermeture du document Word
docWord.Close False
appWord.Quit False
 
End Sub

Vu que le but d'utiliser des variables object est de ne pas avoir de référence qui pourraient faire planter le code si l'utilisateur n'a pas la meme version, je supprime donc la référence Microsoft Word 11.
Et la malheureusement ca n'imprime plus

10/09/2007, 18h46
SilkyRoad

bonjour Jerome, bonjour Ouskel'n'or

Si tu n'utilises pas la référence Word, remplace wdSendToPrinter par sa valeur , en l'occurence: 1.

Si tu veux connaitre la valeur des différentes constantes, ouvre Word pour faire des essais et utilise ce type de macro

Code:

MsgBox wdSendToPrinter

bonne soirée
michel
10/09/2007, 19h05
jfontaine

Super SilkyRoad ca marche parfaitement.
j'avais vu cette histoire de 1 mais je ne pensais pas que ca pouvait bloquer l'impression. :roll:

Merci aussi ouskel'n'or pour ton aide