[XSLT] for-each et variables

Version imprimable

03/08/2007, 17h40
Mil17

[XSLT] for-each et variables

Bonjour,

J ai des données stockées au format xml de type :
CLIENT
PRODUIT
QUANTITE
PRIX
QUANTITE_BASE

QUANTITE_BASE est identique pour toutes les données du couple CLIENT PRODUIT.

Je dois dans un tableau créer une nouvelle donnée QUANTITE_DE_BASE et modifier QUANTITE en fonction de QUANTITE_BASE.

En gros j ai ces données :

Citation:

CLIENT : C1
PRODUIT : P1
QUANTITE : 500
PRIX : 5
QUANTITE_BASE : 600

CLIENT : C1
PRODUIT : P1
QUANTITE : 300
PRIX : 6
QUANTITE_BASE : 600 (idem que celui du dessus car mm couple client produit)

CLIENT : C2
PRODUIT : P1
QUANTITE : 800
PRIX : 3
QUANTITE_BASE : 500

-----
Je dois obtenir un tableau avec

Citation:

CLIENT : C1
PRODUIT : P1
QUANTITE : 0
PRIX : 5
QUANTITE_DE_BASE : 500 (=QUANTITE car QUANTITE<QUANTITE_BASE, je dois garder en mémoire les 100 de la QUANTITE_BASE restant pour le prochain couple client/produit)

CLIENT : C1
PRODUIT : P1
QUANTITE : 0 (car il y a des QUANTITE_BASErestant)
PRIX : 6
QUANTITE_DE_BASE : 100 (QUANTITE_BASErestant<QUANTITE dc on affiche 100 et on garde en mémoire les 200 que l on a pas encore affiché 300-100=QUANTITE-QUANTITE_BASErestant)

CLIENT : C1
PRODUIT : P1
QUANTITE : 200 (la QUANTITE RESTANTE)
PRIX : 6
QUANTITE_DE_BASE : 0 (car il n y a plus de QUANTITE_BASErestant)

--> pour ce couple on a bien une quantité totale de 500+300 mais répartie en 500 + 100 + 200
Pour le couple suivant C2/P1:

Citation:

CLIENT : C2
PRODUIT : P1
QUANTITE : 0
PRIX : 3
QUANTITE_DE_BASE : 500

CLIENT : C2
PRODUIT : P1
QUANTITE : 300
PRIX : 3
QUANTITE_DE_BASE : 0

L'algo pour moi ne pose pas vraiment de pb ... Le seul hic c est les variables en xslt !!

Il faudrait que j arrive à initialiser une variable avant mon for-each et que j arrive à la modifier dans ma boucle ... Sauf que j ai la valeur de ma quantite_base dans la boucle ...
En plus, je crois qu il y a des souci avec les variables, des questions de noeuds en xslt.
Je comprends pas trop comment m en sortir malgré les tuto et posts lus jusqu à maintenant !!!

Voici ma boucle sans cette variable pour le moment :

Citation:

<x:for-each select="//NIVEAU1">
<tr >
<x:attribute name="class">r<x:value-of select="position() mod 2"/></x:attribute>
<td ><x:value-of select="@CLIENT"/></td>
<td ><x:value-of select="@PRODUIT"/></td>
<td ><x:value-of select="@QUANTITE "/></td>
<td ><x:value-of select="@PRIX"/></td>
<td ><x:value-of select="@QUANTITE_DE_BASE"/></td>
</tr>
</x:for-each>

En fait je vois comment déclarer une variable et l initialiser

Citation:

<x:variable nom="base">0</x:variable>

mais comment lui affecter une valeur par la suite ?

Merci d avance
05/08/2007, 12h21
Erwy

En xslt les variables sont immutables, plus assimllable a des constantes
http://xml.developpez.com/faq/?page=3#xslt_variable
06/08/2007, 10h18
Mil17

C est bien ce que j avais lu dc je me demandais comment faire !!!
06/08/2007, 11h01
valal

Citation:

Envoyé par Mil17

C est bien ce que j avais lu dc je me demandais comment faire !!!

il me seble qu'il a repondu à ta question qui était :

Code:

mais comment lui affecter une valeur par la suite ?

si tu veux une autre reponse, pose une autre question ;)
06/08/2007, 11h06
Erwy

En xslt on evite les algo itératifs ont fait du recursif.
Réecrit ton algo en recursif
06/08/2007, 11h29
Mil17

OKI je vais voir ce que je peux faire mais comme c est un peu complexe ...

Bref, j ai une question encore !
Voila, j ai écrit ce petit code ;

Citation:

<x:variable name="maValATester">a</x:variable>
[un peu de code sans intéret]
<x:if test="$maValATester='a'">
<x:variable name="maValATester"><x:value-of select="@VALEUR"/></x:variable>
</x:if>
<x:value-of select="@VALEUR"/>
<x:if test="$maValATester='N'">
Je suis là
</x:if>

Mon souci c est que "je suis là" ne s'affiche pas alors que @VALEUR est bien égal à N.
La preuve qd je fais <x:value-of select="@VALEUR"/> j'obtiends bien N ...
Le souci c'est que maValATester garde 'a' comme valeur ! Et moi j ai du mal avec le récursif !!!

Comment faire ?
06/08/2007, 11h33
Erwy

Pb de localité des variables voir

http://erwy.developpez.com/cours/langage/xslt/variable/
06/08/2007, 11h40
Mil17

oui je sais ...
J ai bien lu ce doc, mais je ne vois pas vraiment comment m en sortir.
La récursivité je veux bien mais j'ai 5 à 6 conditions particulières qui donnent un affichage dans un tableau .. Bref, je ne pense pas m en sortir comme ça ...
Ca veut dire que finalement j suis dans la panade c'est ça ?
06/08/2007, 12h44
Mil17

Bon et bien j ai cru comprendre qu il n y avait pas de solution ... Tantpis va falloir que je revois ma methode ;)

Merci qd même ...

Citation:

Envoyé par Mil17

Bon et bien j ai cru comprendre qu il n y avait pas de solution ...

Si on te l'a dit je n'irais pas dire le contraire
xml d'entrée

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
<?xml version="1.0" encoding="UTF-8"?>
<liste>
	<item>
		<P>1</P>
		<C>1</C>
		<Q>400</Q>
		<QB>800</QB>
	</item>
	<item>
		<P>1</P>
		<C>1</C>
		<Q>300</Q>
		<QB>800</QB>
	</item>
	<item>
		<P>1</P>
		<C>1</C>
		<Q>300</Q>
		<QB>800</QB>
	</item>
</liste>

xslt

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
	<xsl:template match="/">
		<table>
			<xsl:call-template name="DECREC">
				<xsl:with-param name="lst" select="liste/item[P=1 and C=1]"/>
				<xsl:with-param name="Qt" select="0"/>
			</xsl:call-template>
		</table>
	</xsl:template>
	<xsl:template name="DECREC">
		<xsl:param name="lst"/>
		<xsl:param name="Qt"/>
		<xsl:if test="$lst[1]">
			<xsl:variable name="QtCl">
				<xsl:choose>
					<xsl:when test="$lst[1]/QB &lt; ($Qt + $lst[1]/Q)">
						<xsl:choose>
							<xsl:when test="$lst[1]/QB &lt; $Qt">
								<xsl:value-of select="0"/>
							</xsl:when>
							<xsl:otherwise>
								<xsl:value-of select="$lst[1]/QB - $Qt"/>
							</xsl:otherwise>
						</xsl:choose>
					</xsl:when>
					<xsl:otherwise>
						<xsl:value-of select="$lst[1]/Q"/>
					</xsl:otherwise>
				</xsl:choose>
			</xsl:variable>
			<l>
				<P>
					<xsl:value-of select="$lst[1]/P"/>
				</P>
				<C>
					<xsl:value-of select="$lst[1]/C"/>
				</C>
				<Q>0</Q>
				<QB>
				<xsl:value-of select="number($QtCl)"/>					
				</QB>
			</l>
			<xsl:choose>
				<xsl:when test="$QtCl &lt; $lst[1]/Q">
				<l>
					<P>
						<xsl:value-of select="$lst[1]/P"/>
					</P>
					<C>
						<xsl:value-of select="$lst[1]/C"/>
					</C>
					<Q>
						<xsl:value-of select=" $lst[1]/Q -  number($QtCl)"/>
					</Q>
					<QB>0</QB>
				</l>
				</xsl:when>
				<xsl:otherwise>
					<xsl:call-template name="DECREC">
						<xsl:with-param name="lst" select="$lst[position() &gt; 1]"/>
						<xsl:with-param name="Qt" select="$Qt+$QtCl"/>
					</xsl:call-template>
				</xsl:otherwise>
			</xsl:choose>
		</xsl:if>
	</xsl:template>
</xsl:stylesheet>

xml de sortie

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
<?xml version="1.0" encoding="UTF-8"?>
<table>
	<l>
		<P>1</P>
		<C>1</C>
		<Q>0</Q>
		<QB>400</QB>
	</l>
	<l>
		<P>1</P>
		<C>1</C>
		<Q>0</Q>
		<QB>300</QB>
	</l>
	<l>
		<P>1</P>
		<C>1</C>
		<Q>0</Q>
		<QB>100</QB>
	</l>
	<l>
		<P>1</P>
		<C>1</C>
		<Q>200</Q>
		<QB>0</QB>
	</l>
</table>

08/08/2007, 16h11
Mil17

J'ai fini par utilisé la fonction "preceding-sibling" qui m'a permis, de façon récursive, de jouer avec mes valeurs précédentes pour un champ donné de ma table ...
Tout fonctionne à présent parfaitement.
Je remercie ceux qui ont tenté de me venir en aide et me permets ce petit message supplémentaire, qui aiguillera peut etre d'autres personnes dans la même panade que moi et leur permettra de perdre un peu moins de temps ;)

Encore merci