Tuto sur LocalConnection

Bonjour,

Comme il y a eu des questions un peu restées sans réponse sur le fameux
LocalConnection, je me demandais si un tuto ne serait pas le bien venu sur le sujet.

Cependant je suis nouveau ici et j'ai peu cherché pour tout dire.

Bref ma question est: Est ce utile à la communauté ou est ce que je retarde d'une
bonne guerre ?

Si ça vous branche je cherche un sujet, sinon tantpistantmieux :)

Bonne journée à toutes et à tous,
Goofyt

salut
il y a un très bon exemple dans la doc de flash :)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
// Code in LocalConnectionSenderExample.as
package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.net.LocalConnection;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.events.StatusEvent;
    import flash.text.TextFieldAutoSize;
 
    public class LocalConnectionSenderExample extends Sprite {
        private var conn:LocalConnection;
 
        // UI elements
        private var messageLabel:TextField;
        private var message:TextField;
        private var sendBtn:Sprite;
 
        public function LocalConnectionSenderExample() {
            buildUI();
            sendBtn.addEventListener(MouseEvent.CLICK, sendMessage);
            conn = new LocalConnection();
            conn.addEventListener(StatusEvent.STATUS, onStatus);
        }
 
        private function sendMessage(event:MouseEvent):void {
            conn.send("myConnection", "lcHandler", message.text);
        }
 
        private function onStatus(event:StatusEvent):void {
            switch (event.level) {
                case "status":
                    trace("LocalConnection.send() succeeded");
                    break;
                case "error":
                    trace("LocalConnection.send() failed");
                    break;
            }
        }
 
        private function buildUI():void {
            const hPadding:uint = 5;
            // messageLabel
            messageLabel = new TextField();
            messageLabel.x = 10;
            messageLabel.y = 10;
            messageLabel.text = "Text to send:";
            messageLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(messageLabel);
 
            // message
            message = new TextField();
            message.x = messageLabel.x + messageLabel.width + hPadding;
            message.y = 10;
            message.width = 120;
            message.height = 20;
            message.background = true;
            message.border = true;
            message.type = TextFieldType.INPUT;
            addChild(message);
 
            // sendBtn
            sendBtn = new Sprite();
            sendBtn.x = message.x + message.width + hPadding;
            sendBtn.y = 10;
            var sendLbl:TextField = new TextField();
            sendLbl.x = 1 + hPadding;
            sendLbl.y = 1;
            sendLbl.selectable = false;
            sendLbl.autoSize = TextFieldAutoSize.LEFT;
            sendLbl.text = "Send";
            sendBtn.addChild(sendLbl);
            sendBtn.graphics.lineStyle(1);
            sendBtn.graphics.beginFill(0xcccccc);
            sendBtn.graphics.drawRoundRect(0, 0, (sendLbl.width + 2 + hPadding + hPadding), (sendLbl.height + 2), 5, 5);
            sendBtn.graphics.endFill();
            addChild(sendBtn);
        }
    }
}

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
// Code in LocalConnectionReceiverExample.as
package {
    import flash.display.Sprite;
    import flash.net.LocalConnection;
    import flash.text.TextField;
 
    public class LocalConnectionReceiverExample extends Sprite {
        private var conn:LocalConnection;
        private var output:TextField;
 
        public function LocalConnectionReceiverExample()     {
            buildUI();
 
            conn = new LocalConnection();
            conn.client = this;
            try {
                conn.connect("myConnection");
            } catch (error:ArgumentError) {
                trace("Can't connect...the connection name is already being used by another SWF");
            }
        }
 
        public function lcHandler(msg:String):void {
            output.appendText(msg + "\n");
        }
 
        private function buildUI():void {
            output = new TextField();
            output.background = true;
            output.border = true;
            output.wordWrap = true;
            addChild(output);
        }
    }
}

Bonjour,

Citation:

il y a un très bon exemple dans la doc de flash

Pour qui est habitué a programmer la doc est largement suffisante. Une doc complete avec des exemple, des didactiel, en français en plus ( de quoi pouvons nous rever de mieux ? )

Oui mais les autres? ceux qui commence ... :? ceux pour qui un evenement n'est rien d'autre qu'une manifestation populaire, ceux pour qui une classe n'est rien d'autre qu'en endroit ou l'on pose ses fesses pendant 2heures (et ensuite la récréation), ceux pour qui une exeption est un truc exeptionnel :? ceux pour qui AS est la carte qui vau 11pt a la belote, ceux pour qui propriété et methode est plus étrange que le mystere de la chammbre jaune, ceux pour qui ActiveX est un film interdit au moins de 18ans ... bref

Et bien a toi goofyt ( bonne ame ) qui voulai retourner l'ascenceur, je te dirai fais ton chemin sans demander l'avis des autres ....

@ phiphi: Je ne pense pas que tu ais commencer sans avoir lu un seul tuto ...

-------------------
Il est plus rapide de demander pardon que de demander la permission.