Vb6 : substitution d'une variable par sa valeur dans une chaîne

Version imprimable

16/04/2007, 11h51
Mordread

Vb6 : substitution d'une variable par sa valeur dans une chaîne

Bonjour !

Tout d'abord pour ce programme, je suis obligé de passer par VB6 (pas eu le choix du langage...:? )

Après lecture d'un fichier INI, je me retrouve avec des chemins DOS utilisant des variables d'environnement, du style :

sMaVariable = "c:\test\%USERNAME%\voila"

ou bien :

sMaVariable = "%APPDATA%\Adobe\%VERNUMBER%\pouet"

Je vais par la suite être ammené à bosser sur ces répertoires (folderexists, filecopy etc.) dans mon programme VB6;

Ca va, jusque là ? Alors voilà le problème !

FolderExists(sMaVariable), ça foire car elle contient des %VARD'ENV% et que les fonctions VB6 ne les traduisent malheureusement pas !

Je me suis dit "pas de problème, suffit de remplacer ces %VARS% par leur valeur dos, récupérées avec un GetEnvironmentVariable", mais gérer tous les cas de figure semble complexe...

Des idées, des suggestions ?
18/04/2007, 13h26
karl3i

Salut,

cherche du côté de ExpandEnvironmentVariables. Ca permet précisément de remplacer le %nomvariable% par <valeur de la variable>.

Karl3i.

Citation:

Envoyé par karl3i

Salut,

cherche du côté de ExpandEnvironmentVariables. Ca permet précisément de remplacer le %nomvariable% par <valeur de la variable>.

Karl3i.

C'est une méthode .NET, elle n'existe hélas pas en VB6

Pour l'instant utilise une fonction un peu monstrueuse :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
'-----------------------------------------------------------------------------------------------
' Conversion d'un chemin en transformant les variables d'environnement en valeurs absolues
'-----------------------------------------------------------------------------------------------
Private Function ConvertPathName(ByVal sNatPath As String) As String
    Dim myRegExp    As New RegExp
    Dim myMatches   As MatchCollection
    Dim myMatch     As Match
    Dim l           As Long
    Dim lpBuffer    As String
    
    ' Par défaut
    ConvertPathName = sNatPath
    
    'On utilise les expressions régulières pour isoler une éventuelle variable DOS
    myRegExp.IgnoreCase = True
    myRegExp.Global = True
    
    ' On cherche une variable d'environnement caractérisée par le délimiteur "%"
    myRegExp.Pattern = "%([A-Z]*)%"
    Set myMatches = myRegExp.Execute(sNatPath)
            
    ' Si le chemin contient des variables d'environnement
    If myMatches.Count > 0 Then
    
        For Each myMatch In myMatches
            lpBuffer = String(512, 0)
            l = GetEnvironmentVariable(Mid(myMatch.Value, 2, Len(myMatch.Value) - 2), lpBuffer, 512)
            If l <> 0 Then
                lpBuffer = Left(lpBuffer, l)
                myRegExp.Pattern = myMatch.Value
                sNatPath = myRegExp.Replace(sNatPath, lpBuffer)
            End If
        Next
        
        ConvertPathName = sNatPath
    End If
End Function