[Paradox] Automatiser l'export de table en CSV

Bonjour,
qq connait-il un utilitaire en ligne de commande qui permettrait d'exporter tout ou partie des champs d'une table Paradox en CSV ?

Sinon un composant ou un source traitant du sujet ?

La structure des tables Paradox, créées sous Delphi, est-elle identique pour les versions de Delphi 3 à 7 ?

Merci

oui, SQL-View par exemple, peut s'utiliser en ligne de commande :wink:

Il faut lui passer un script XML :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
<?xml version="1.0" encoding="ISO-8859-1" ?> 
<sqlview-run> 
  <run connection="La connexion sur la base paradox">  
    <query> 
      select * 
      from latable 
    </query> 
    <output> 
      <file filename="c:\fichier.csv" 
            rewrite="true" 
            separator=";" 
            header="true"/> 
    </output> 
  </run> 
</sqlview-run>

Bloon

Super !
Merci

Pour ceux que ça intéresse, vois 2 scripts dédié à l'export.

Le premier parcourt un répertoire dédiée contenant les tables à exporter et pour chaque construit un fichier XML avec les noms de table approprié.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
@Echo off
 rem ImportPdx.cmd
 rem Le nom du répertoire doit se terminer par un backslash '\' 
Set DirPDXExport=C:\Temp\SqlView\
 
 rem Traiter tous les fichiers Paradox
For %%I in (%DirPDXExport%\*.db) do call ::Traite "%%I"
goto end
 
:Traite
 rem exécute le SqlView pour le fichier courant
Call MakeXML.cmd %1 "%DirPDXExport%"
 
SqlView.exe /run="%XmlFile%" /quit=yes
 
:end
rem debug
rem echo %FileDir%@
rem echo %FileName%@
rem echo %DirExport%@
rem echo %FileExport%@
rem echo %XmlFile%@
rem echo %DirPDXExport%@
 
set FileDir=
set FileName=
set DirExport=
Set FileExport=
set XmlFile=
Set DirPDXExport=

Le second crée le fichier XML

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
@echo off
 rem MakeXML.cmd
 rem Construit un fichier XML pour SQl-View dans le répertoire courant.
 rem %1 = le nom du fichier de la table concernée.
 rem %2 = le nom du répertoire où écrire le fichier CSV
 
 rem Récupére le nom du fichier sans extension
For /F "tokens=*" %%I in ('echo %1') do set FileDir=%%~dpI& set FileName=%%~nI
 
 rem Supprime les guillemets du paramétre 2
For /F "tokens=*" %%I in ('echo %2') do set DirExport=%%~dpI
 
 rem Construit le nom du fichier XML
set XmlFile=%FileDir%%FileName%.XML
 
 rem Le nom fichier du fichier CSV utilisé par Sqlview
Set FileExport=%DirExport%%FileName%.CSV
 
 rem Supprime l'ancien fichier s'il existe
if exist "%XmlFile%" Del "%XmlFile%" /F
set StrConnexion=ExportPDX
 
 rem génére le fichier XML pour la table courante
 rem le caractére ^ permet de ne pas interpréter les symboles de redirection ^< et ^>
echo ^<?xml version="1.0" encoding="ISO-8859-1" ?^>>>"%XmlFile%"
echo ^<sqlview-run^>>>"%XmlFile%"
echo  ^<run connection="%StrConnexion%"^>>>"%XmlFile%"
echo   ^<query^>>>"%XmlFile%"
echo    select *>>"%XmlFile%"
rem ici on insére le nom du fichier de la table paradox concernée
echo    from %FileName%>>"%XmlFile%"
echo   ^</query^>>>"%XmlFile%"
Echo    ^<output^>>>"%XmlFile%"
Echo     ^<file filename="%FileExport%">>"%XmlFile%"
Echo       rewrite="true">>"%XmlFile%"
Echo       separator=";">>"%XmlFile%"
Echo       header="true"/^>>>"%XmlFile%"
Echo   ^</output^>>>"%XmlFile%"
Echo  ^</run^>>>"%XmlFile%"
Echo ^</sqlview-run^>>>"%XmlFile%"

Recopier toutes vos tables dans un répertoire dédiée, copier les scripts et l'exécutable SqlView dans ce même répertoire puis Ouvrez une console, placez-vous dans le même répertoire, exécutez ImportPdx.cmd.

Il reste 2-3 petite choses à ajouter( Chemin vers SqlView,...) mais c'est exploitable tel que.
Je vous laisse faire les adaptations et le support. :lol: