Problème de calculer avec textbox et produire un single ou double ?

Version imprimable

19/01/2007, 19h16
zizou2007

Problème de calculer avec textbox et produire un single ou double ?

salut à tous.
j'utilise une feuille avec objet ADO dans laquelle j'ai mis des textbox. j'essaie de calculer un montant avec, mais le résultat ne se fait qu'en integer, bien que j'ai utilisé CStr. Par exemple:
textBox3.Text = CStr(CSng(textBox1.Text) * CSng(textBox2.Text)
mais j'obtiens pas de virgule.
Pouvez vous m'aider. et merci.
19/01/2007, 19h26
sovo

Bonsoir et bienvenu dans le forum.

Et si tu essayais ceci :

Code:

textBox3.Text = CDec(textBox1.Text) * CDec(textBox2.Text)
19/01/2007, 20h45
zizou2007

Partiellement Résolu.

merci SOVO.
ça provoque les mêmes erreurs que CDbl ou CSng.
mais j'ai trouvé que mon problème était que dans ma configuration système, j'avais la virgule "," comme symbôle décximal et je l'ai changé en point ".", et maintenant ça marche.
mais j'aimerais toujours avoir des chifres décimaux en virgule plutôt qu'en point, ce sera plus lisible.
19/01/2007, 22h00
sovo

tu pourais tout simplement utliser la fonction replace

Code:

textBox3.Text = replace(textBox3.Text, ".", ",")

Salut

Ou encore...

Code:

1
2
Dim nbrDecimal As Double
nbrDecimal = Val(Replace(Text1.Text, ",", "."))

Une petite fonction à mettre dans un coin :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Private Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" _
 (ByVal locale As Long,  ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
 
Private Declare Function GetUserDefaultLCID Lib "kernel32" () As Long
Private Const LOCALE_STHOUSAND = &HF       'séparateur des milliers
Private Const LOCALE_SDECIMAL = &HE        'séparateur décimal
 
 
Private Function CVal(nbretxt As String) As Double
'-- Convertie une chaine en Double, indépendament des paramètres régionaux
 
Dim lngResultat As Long
Dim buffer As String
Dim SepDec As String, SepMil As String
Dim loc As Long
 
    'récupère l'identifiant de l'information locale de type utilisateur
    On Error GoTo CVal_Error
 
    loc = GetUserDefaultLCID()
 
    'Récupère le séparateur décimal
    lngResultat = GetLocaleInfo(loc, LOCALE_SDECIMAL, buffer, 0)
    buffer = String(lngResultat, 0)
    GetLocaleInfo loc, LOCALE_SDECIMAL, buffer, lngResultat
    SepDec = Left(buffer, 1)
 
    'Récupère le séparateur des Milliers
    lngResultat = GetLocaleInfo(loc, LOCALE_STHOUSAND, buffer, 0)
    buffer = String(lngResultat, 0)
    GetLocaleInfo loc, LOCALE_STHOUSAND, buffer, lngResultat
    SepMil = Left(buffer, 1)
 
    'Effectue le remplacement
    nbretxt = Replace(nbretxt, SepMil, "")
    nbretxt = Replace(nbretxt, SepDec, ".")
 
    CVal = Val(nbretxt)
 
    On Error GoTo 0
    Exit Function
 
CVal_Error:
    Err.Clear
    CVal = 0
End Function

22/01/2007, 14h11
zazaraignée

Super! J'la mets au frais!

Dis donc Thierry, sovo et moi, on a l'air de deux amateurs de ping-pong essayant de se mesurer à un champion de tennis! ;)
22/01/2007, 14h18
ThierryAIM

Citation:

Envoyé par zazaraignée

Dis donc Thierry, sovo et moi, on a l'air de deux amateurs de ping-pong essayant de se mesurer à un champion de tennis! ;)

Meuh nan ;)
J'avais ça dans un coin, car j'en avais assez des Replace et consors en fonction de la langue de l'OS et des paramètres régionaux , alors je vous en fait profiter
22/01/2007, 14h23
Theocourant

Citation:

Envoyé par zazaraignée

Super! J'la mets au frais!

Dis donc Thierry, sovo et moi, on a l'air de deux amateurs de ping-pong essayant de se mesurer à un champion de tennis! ;)

Je suis d'accord avec toi, dire que je me suis fait c**** à monter un système bancal pour résoudre ce problème, j'enrage de ne pas avoir trouvé cette solution simplissime.

:ccool: Thierry

+

Théo qui va de ce pas mettre le code de côté.

Perso, j'utiises un petit module dans le quel je redéfinis la fonction val
Code:

1 2 3 4 5 6 Public Function Val(Nombre as variant) as Double Dim strTemp as String strTemp = Nombre strTemp = Replace(Nombre, "," , ".") Val = VBA.Val(strTemp) End Function
Comme çà, je n'ai plus a m'occuper dans reglagles de chaque poste.

23/01/2007, 01h22
zazaraignée

Et y'a pas de conflits entre la fonction Val de VB et la tienne? (C'est ma soirée des questions de conflits)
23/01/2007, 12h27
ThierryAIM

Citation:

Envoyé par Delbeke

Perso, j'utiises un petit module dans le quel je redéfinis la fonction val

Comme çà, je n'ai plus a m'occuper dans reglagles de chaque poste.

Je suis tombé sur un poste client qui utilisait ' comme séparateur de milliers et ça m'avait mis en rogne, rien ne marchait
D'ou, à l'époque, ma fonction CVal (par analogie aux fonctions de conversion), un coup de rechercher/remplacer et depuis je n'utilisise plus jamais le Val de VB :lol:
24/01/2007, 07h23
Delbeke

Citation:

Envoyé par zazaraignée

Et y'a pas de conflits entre la fonction Val de VB et la tienne? (C'est ma soirée des questions de conflits)

Nan, pas de probleme de conflit, j'ai utilisé plusieurs fois cette technique pour redefinir des fonctions vb . dans le reste du code on peut toujours utiliser l'ancienne version en mettant VBA. devant la fonction
Ex:
Mavaleur = Val(strValue) utilse la fonction redéfinie
Mavaleur = VBA.Val(strValue) utilise la fonction standard
27/01/2007, 18h59
zizou2007

Résolu.

Merci à vous tous pour toutes vos explications, parce que ça marche pour moi. salut.