Ajout et Suppression entre deux listBox

Mon problème est le suivant : j'ai deux listbox en multiselection. je veux transférer des items de la première liste à l'autre. en utilisant deux buttons ">>>"
"<<<" ou le drag and drop. (les éléments de la première liste sont toujours fixe)

Inscrit le mercredi 13 juillet 2005, Total message: 35, discussions ouvertes: 11, Nbr.de TAGs utilisés: 9, moyenne: 82/100 :ccool:

bonjour
Il doit exister des reponses dans les tutos ou en faisant une recherche, on est dimanche et j'ai le temps, ton suivit des discutions ouvertes par toi m'insite a te montrer cette façon de procéder.
Sur une Form, 2 Commandbuttons et 2 ListBoxs, chaqu'un indexé 0 et 1
ne pas oublier de mettre List1(0) et List1(1) proprieté MultiSelect = 2 - Extended avant de lancer l'application

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Option Explicit
Dim T As Integer
Dim IndexSrc As Integer
Dim IndexDes As Integer
Private Sub Form_Load()
List1(0).Top = 120: List1(0).Left = 90: List1(0).Height = 2595: List1(0).Width = 1485
List1(1).Top = 120: List1(1).Left = 2280: List1(1).Height = 2595: List1(1).Width = 1485
Command1(0).Top = 150: Command1(0).Left = 1680: Command1(0).Height = 315: Command1(0).Width = 525
Command1(1).Top = 510: Command1(1).Left = 1680: Command1(1).Height = 315: Command1(1).Width = 525
Command1(0).Caption = ">>>": Command1(1).Caption = "<<<"
Me.Height = 3180: Me.Width = 4005
For T = 0 To 9
 List1(0).AddItem "Ligne " & CStr(T) & " de la liste 1"
 List1(1).AddItem "Ligne " & CStr(T) & " de la liste 2"
Next T
End Sub
 
 
'*********** avec des boutons ******************
Private Sub Command1_Click(Index As Integer)
IndexSrc = Index
If Index = 0 Then IndexDes = 1 Else IndexDes = 0
 
If List1(IndexSrc).SelCount > 0 Then 'au moins une ligne selectionnée
 'passer la/les lignes dans List1(IndexDes)
 For T = 0 To List1(IndexSrc).ListCount - 1
  If List1(IndexSrc).Selected(T) = True Then
   List1(IndexDes).AddItem List1(IndexSrc).List(T)
  End If
 Next T
 'supprimer la/les lignes de List1(IndexSrc)
 For T = List1(IndexSrc).ListCount - 1 To 0 Step -1
  If List1(IndexSrc).Selected(T) = True Then
   List1(IndexSrc).RemoveItem (T)
  End If
 Next T
End If
End Sub
 
'*********** en drag and drop ******************
Private Sub List1_DragDrop(Index As Integer, Source As Control, X As Single, Y As Single)
Command1_Click (Source.Index)
End Sub
Private Sub List1_MouseDown(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button = 2 Then 'bouton droit de la souris
 If List1(Index).SelCount > 0 Then 'au moins une ligne selectionnée
  'Drag > vbBeginDrag par default soit 1 Commence à faire glisser object
  List1(Index).Drag
 End If
End If
End Sub

Salut

Merci