[XSL] Problème d'incrémentation

Version imprimable

Voici en gros ce que j'ai côté XML :

Code:

1
2
3
4
5
 
<Personnes>
   <Personne Type="Adulte" Nombre="2"/>
   <Personne Type="Enfant" Nombre="5"/>
</Personnes>

et le XML que je doit obtenir :

Code:

1
2
3
4
5
6
7
8
 
<Personne id="1" Type="ADULTE"/>
<Personne id="2" Type="ADULTE"/>
<Personne id="3" Type="ENFANT"/>
<Personne id="4" Type="ENFANT"/>
<Personne id="5" Type="ENFANT"/>
<Personne id="6" Type="ENFANT"/>
<Personne id="7" Type="ENFANT"/>

En XSL, j'ai une fonction, enfin template :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
<xsl:template name="for.loop.persons">
  <xsl:param name="start"/>
  <xsl:param name="total"/>
  <xsl:param name="Type"/>
 
  <xsl:if test="$start &lt;= $total">
	<Personne>
          <xsl:attribute name="id">
            <xsl:value-of select="$start"/>
          </xsl:attribute>
          <xsl:attribute name="Type">
            <xsl:value-of select="$Type"/>
          </xsl:attribute>
        </Personne>
  </xsl:if>
 
  <xsl:if test="$start &lt;= $total">
    <xsl:call-template name="for.loop.persons">
      <xsl:with-param name="start">
        <!-- Increment index-->
	<xsl:value-of select="$start + 1"/>
      </xsl:with-param>
      <xsl:with-param name="total">
	<xsl:value-of select="$total"/>
      </xsl:with-param>
      <xsl:with-param name="Type">
	<xsl:value-of select="$Type"/>
      </xsl:with-param>
    </xsl:call-template>
  </xsl:if>
 
</xsl:template>

Et voilà l'endroit où je traite cela :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
<xsl:template match="Voyage/Personnes">
  <xsl:for-each select="Personne">
    <xsl:call-template name="for.loop.persons">
      <xsl:with-param name="start">
        1
      </xsl:with-param>
      <xsl:with-param name="total">
        <xsl:value-of select="@Nombre"/>
      </xsl:with-param>
      <xsl:with-param name="Type">
        <xsl:for-each select="@Type">
	  <xsl:value-of select="translate(.,$LowerLetters,$UpperLetters)"/>
	</xsl:for-each>
      </xsl:with-param>
    </xsl:call-template>
  </xsl:for-each>
</xsl:template>

Le problème est que j'obtiens :

Code:

1
2
3
4
5
6
7
8
 
<Personne id="1" Type="ADULTE"/>
<Personne id="2" Type="ADULTE"/>
<Personne id="1" Type="ENFANT"/>
<Personne id="2" Type="ENFANT"/>
<Personne id="3" Type="ENFANT"/>
<Personne id="4" Type="ENFANT"/>
<Personne id="5" Type="ENFANT"/>

Je sais que c'est parceque je donne 1 en paramètre d'entrée de start, je sais que ça vient d'un mauvais passage de paramètres, mais j'ai essayé avec position(), en faisant des opérations du style position() + (position()-1) qui ne marche pas toujours....

Bref, là je sature :P :lol: :cry:

Bonjour,

ton problème vient du fait que tu essayes de tout traiter en une seule fonction. Il t'en faut deux :
- Une pour faire une itération sur tes éléments Personnes, et qui va gérer l'id par type de personne
- Une autre pour générer chaque ligne de voyageur, en incrémentant l'id que lui a transmis la précédente fonction.

Le nombre de voyageurs a générer et l'id doivent être traités dans des variables séparées.

Ca donne ça :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
 
	<xsl:template match="/Personnes">
		<voyage>
			<xsl:call-template name="boucle">
				<xsl:with-param name="voyageur" select="Personne[1]"/>
			</xsl:call-template>	
		</voyage>
	</xsl:template>
 
	<xsl:template name="boucle">
		<xsl:param name="id" select="1"/>
		<xsl:param name="voyageur"/>
		<xsl:variable name="nombre" select="$voyageur/@Nombre"/>
		<xsl:if test="$nombre != ''">
			<xsl:call-template name="genere-voyageur">
				<xsl:with-param name="id" select="$id"/>
				<xsl:with-param name="nombre" select="$nombre"/>
				<xsl:with-param name="type-voyageur" select="$voyageur/@Type"/>
			</xsl:call-template>
			<xsl:call-template name="boucle">
				<xsl:with-param name="id" select="$id + $nombre"/>
				<xsl:with-param name="voyageur" select="$voyageur/following-sibling::Personne[1]"/>
			</xsl:call-template>
		</xsl:if>
	</xsl:template>
 
	<xsl:template name="genere-voyageur">
		<xsl:param name="id"/>
		<xsl:param name="nombre"/>
		<xsl:param name="type-voyageur"/>
		<xsl:if test="$nombre != 0">
			<Personne>
				<xsl:attribute name="Type"><xsl:value-of select="$type-voyageur"/></xsl:attribute>
				<xsl:attribute name="id"><xsl:value-of select="$id"/></xsl:attribute>
			</Personne>
			<xsl:call-template name="genere-voyageur">
				<xsl:with-param name="id" select="$id + 1"/>
				<xsl:with-param name="nombre" select="$nombre - 1"/>
				<xsl:with-param name="type-voyageur" select="$type-voyageur"/>
			</xsl:call-template>
		</xsl:if>
	</xsl:template>
 
</xsl:stylesheet>

28/01/2005, 12h32
OXyGN

Ca marche merci beaucoup. C'est vraiment pas évident le XSL à coder quand on a l'habitude plus du C ou Java :P . Pfiouu...
28/01/2005, 12h48
GrandFather

Citation:

Envoyé par OXyGN

Ca marche merci beaucoup. C'est vraiment pas évident le XSL à coder quand on a l'habitude plus du C ou Java :P . Pfiouu...

Tu pourrais coder ces fonctions de la même manière en C ou en Java. Si ce n'est qu'avec ces langages l'usage de la récursivité est optionnel, tandis qu'avec XSLT c'est quasiment obligatoire.

Ah, et n'oublie pas de mettre le tag [Résolu] avec le bouton qui va bien. :)