[XSLT]tableau double entrée avec cellule manquante

Version imprimable

Bonjour, je tourne en rond sur un problème depuis un bon moment

j'ai un flux xml
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 <depenses> <depenses_row> <nature>degradations</nature> <annee>2001</annee> <valdepense>58</valdepense> </depenses_row> <depenses_row"> <nature>portier</nature> <annee>2002</annee> <valdepense>200</valdepense> </depenses_row> <depenses>
et je veux transformer cela en un tableau html à double entrée vias xsl
Code:

1 2 3 4 |*********** | 2001 | 2002 | |Dégradation | 58 | | |portier | | 200 |
si la matrice était pleine, aucun problème mais comme vous le voyez il y a des cellules vides dans le tableau qui correspondent à des valeurs absentes dans le flux XML. Je ne vois pas comment provoquer l'affichage de ces cellules vides sur une absence de données ?

Merci pour vos réponses ou un liens sur un problème similaire

25/01/2005, 20h36
GrandFather

Bonjour,

est-ce que le nombre d'années est fixe ou peut varier ?
26/01/2005, 09h53
nferay

Précision

Pour nos essais nous sommes partis sur le postula que le nombre d'année était fixe et si j'avais une solution pour cela je serais déjà très content.

Dans l'absolue nous aimerions trouver une transformation xsl indépendante du nombre de valeur que peut prendre les entêtes du tableau à double entrée.

En effet nous utilisons déjà des transformations xsl sur des flux xml extraits de base de données décisionnel (dataware, datamart) pour générer de simples tableaux. La séparation entre extraction des données et mise en forme pour l'affichage dans un browser est vraiment sympa avec XML/XSL. Aujourd'hui nous souhaitons aller plus loin en créant des tableaux à doubles entrée. Dans les flux XML issu de nos datamarts le nombre de valeur des axes d'analyse (entête du tableau à double entrée) n'est pas forcément prévisible et souvent il n'y a pas d'enregistrement pour certaines valeurs des axes comme l'illustre mon exemple.
26/01/2005, 12h10
GrandFather

Comme se décrit dans ton fichier XML une nature ("portier" par exemple) ayant une valeur pour chaque colonne (année) ?

précision sur flux

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
<depenses> 
<depenses_row> 
  <nature>degradations</nature> 
  <annee>2001</annee> 
  <valdepense>58</valdepense> 
</depenses_row> 
<depenses_row"> 
  <nature>portier</nature> 
  <annee>2001</annee> 
  <valdepense>150</valdepense> 
</depenses_row> 
<depenses_row"> 
  <nature>portier</nature> 
  <annee>2002</annee> 
  <valdepense>200</valdepense> 
</depenses_row> 
<depenses>

Sur cet exemple pas de cellule manquante pour portier. Nous avons aussi classé pour une nature donnée les années par ordre croissant.

Voici une solution possible :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
	<xsl:output method="html" encoding="ISO-8859-1"/>
 
	<xsl:key name="annees" match="annee" use="."/>
	<xsl:key name="natures" match="nature" use="."/>
 
	<xsl:template match="/depenses">
		<table border="1">
			<!-- Génération de la ligne d'en-tête -->
			<tr>
				<td>Natures</td>
				<xsl:for-each select="/depenses/depenses_row/annee[generate-id(.) = generate-id(key('annees',.)[1])]">
					<td><xsl:value-of select="."/></td>
				</xsl:for-each>
			</tr>
			<!-- Génération des lignes de nature -->
			<xsl:for-each select="depenses_row/nature[generate-id(.) = generate-id(key('natures',.)[1])]">
				<xsl:variable name="var-nature" select="."/>
				<tr>
					<td><xsl:value-of select="."/></td>
					<xsl:for-each select="/depenses/depenses_row/annee[generate-id(.) = generate-id(key('annees',.)[1])]">
						<td><xsl:value-of select="/depenses/depenses_row[annee = current() and nature = $var-nature]/valdepense"/></td>
					</xsl:for-each>
				</tr>
			</xsl:for-each>
		</table>
	</xsl:template>
 
 
</xsl:stylesheet>

Elle est particulièrement peu efficace (ça peut poser problème avec de gros flux XML) mais elle fonctionne.
Elle est basée sur le principe de la méthode Muench, qui permet de regrouper les données.

[EDIT] J'avais oublié les <tr> autour de la ligne d'en-tête... :oops: [/EDIT]

27/01/2005, 12h06
nferay

[résolu]Merci

Merci beaucoup pour ton précieux exemple et ta réactivité.
08/03/2005, 14h15
WebPac

Bonjour, je me permets de m'incruster pour poser une petite question, GrandFather, tu dis :

Citation:

Elle est particulièrement peu efficace (ça peut poser problème avec de gros flux XML) mais elle fonctionne.

Pourquoi cette méthode est-elle peu efficace et dans l'absolu, existerait-il une solution efficace, je n'ose demander laquelle mais déjà si elle existe.

Merci.
08/03/2005, 14h55
GrandFather

Citation:

Envoyé par WebPac

Pourquoi cette méthode est-elle peu efficace et dans l'absolu, existerait-il une solution efficace, je n'ose demander laquelle mais déjà si elle existe.

Elle est peu efficace car elle impose à chaque itération (chaque ligne) de nombreux parcours complets de l'arbre XML. En fait, il s'agit d'une sorte de crible, alors qu'on préfèrera un parcours séquentiel de l'arbre XML par la feuille de style.

Dans l'idéal, le tableau devrait être réparti par lignes dans le XML, avec une valeur (même vide) pour chaque colonne du tableau entier. La feuille de style devient alors triviale. Ce format XML est moins compact que celui présenté, mais le traitement en est facilité.
08/03/2005, 15h07
WebPac

Merci pour la réponse, je comprends.