[VB6-OOo]Open Office Calc

Version imprimable

Salut tout le monde :mrgreen:

J'ai une petite question à propos d'openoffice calc.

Lorsque j'ai un fichier excel, je fais comme ca :
Code:

1 2 3 4 5 Set MonExcel = New Excel.Application MonExcel.ReferenceStyle = xlR1C1 Set MonClasseur = MonExcel.Workbooks.Open(CommonDialogFichier.FileName) Set MaFeuille = MonClasseur.Worksheets(1)
Dans la variable MonExcel, j'ai bien le fichier sans que le fichier soit ouvert !

Et en OOo Calc, je fais ca :
Code:

1 2 3 4 Set serviceManager = CreateObject("com.sun.star.serviceManager") Set Desktop = serviceManager.createInstance("com.sun.star.frame.Desktop") Set Document = Desktop.LoadComponentFromURL(Fichier, "_blank", 0, args)
Mais alors là, ca m'ouvre le fichier ...

Question : est-il possible d'utiliser mon fichier OOo dans la variable "Document" sans pour autant être obligé d'ouvrir ce fichier avec ".LoadComponentFromURL" ? :D

Vala, j'espere que c'est clair, c'est pas une question intéressante, je suis désolé :mrgreen: :mrgreen:

Merci à tous :mouarf:

24/11/2006, 14h27
SilkyRoad

bonjour

Citation:

Dans la variable MonExcel, j'ai bien le fichier sans que le fichier soit ouvert !

Tu es sur que le classeur n'est pas ouvert? Ne serait il pas ouvert et masqué ?

michel

rebonjour

S'il s'agit de garder l'application OOo masquée pendant le traitement, tu peux tester:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Sub Test()
Dim serviceManager As Object, Desktop As Object, Document As Object
    Dim Fichier As String
    Dim Args(0) As Object
    Dim T As Date
 
    'Appel fonction de conversion
    Fichier = ConvertToURL("C:\Documents and Settings\mimi\LeClasseur.ods")
 
    'Création d'une instance Open Office
    Set serviceManager = CreateObject("com.sun.star.ServiceManager")
    Set Desktop = serviceManager.createInstance("com.sun.star.frame.Desktop")
 
    '-----------------------------------------------------------
    'Tableau pour les paramètres du mode masqué
    Set Args(0) = _
        serviceManager.Bridge_getStruct("com.sun.star.beans.PropertyValue")
 
    'Arguments Open Office pour masquer le fichier
    Args(0).Name = "Hidden" 'nom de l'argument
    Args(0).Value = True 'valeur de l'argument
 
    'Ouverture du fichier
    Set Document = _
        Desktop.loadComponentFromURL(Fichier, "_blank", 0, Args())
    '----------------------------------------------------------
 
    'Ecrit dans la cellule A1 de la feuille
    Document.getSheets.getByName("Feuille1").getCellRangeByName("A1").Value = 19
 
    'Enregistre les modifications
    Document.store
    DoEvents
 
    '--------
    'ajoute une temporisation de 2 secondes pour empécher que le fichier
    'ne se ferme avant la fin de la création
    T = Timer + 2: Do Until Timer > T: DoEvents: Loop
    '--------
 
    'Fermeture du fichier:
    'L'argument True indique que les modifications
    'vont être sauvegardées à la fermeture.
    Document.Close (True)
 
    MsgBox "Opération terminée"
End Sub

Code:

1
2
3
4
5
6
7
Function ConvertToURL(Fichier As String)
'fonction de conversion  au format URL
Dim Cible As String
    Cible = Fichier
    Cible = Replace(Cible, "\", "/")
    ConvertToURL = "file:///" & Cible
End Function

michel

24/11/2006, 15h06
shaftJackson

Citation:

Envoyé par SilkyRoad

bonjour
Tu es sur que le classeur n'est pas ouvert? Ne serait il pas ouvert et masqué ?

Je pense aussi que ca vient de là, le propriété 'visible' de ton classeur doit être par défaut à 'false' au lieu de 'true'. Tu peux tester en debug pour en être sure !
24/11/2006, 16h11
Kokito

Citation:

Envoyé par shaftJackson

Je pense aussi que ca vient de là, le propriété 'visible' de ton classeur doit être par défaut à 'false' au lieu de 'true'. Tu peux tester en debug pour en être sure !

Voui en fait c'est ca huhu :mouarf:

Merci pour ton code SilkyRoad !!! C'est nickel !!!! Youpeee :mouarf:

Merci à tous enfin à vous deux :D