Affectation à la variable de boucle FOR 'i'

Version imprimable

Salut à tous, je doit dire que je suis tombé sur une erreur qui me laisse perplexe: voici le code:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
function tfrmMain.arrayToPointer(value:string;zone:boolean):Pointer;
var i,i2 : integer;
begin
if zone then
	for i:=0 to length(fieldswG) - 1 do
          if(UpperCase(fieldswG[i])=UpperCase(value)) then
          begin
            result:=@fieldswg[i];
            exit;
          end
else
	for i:=0 to length(fieldsw) - 1 do
          if(UpperCase(fieldsw[i])=UpperCase(value)) then
          begin
            result:=@fieldsw[i];
            exit;
          end;
end;

Quand je compile j'obtiens ceci:
[Pascal Erreur] Unit1.pas(840): E2081 Affectation à la variable de boucle FOR 'i'

Alors que:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
function tfrmMain.arrayToPointer(value:string;zone:boolean):Pointer;
var i,i2 : integer;
begin
if zone then
	for i:=0 to length(fieldswG) - 1 do
          if(UpperCase(fieldswG[i])=UpperCase(value)) then
          begin
            result:=@fieldswg[i];
            exit;
          end
else
	for i2:=0 to length(fieldsw) - 1 do
          if(UpperCase(fieldsw[i2])=UpperCase(value)) then
          begin
            result:=@fieldsw[i2];
            exit;
          end;
end;

fonctionne...
fieldsw et fieldswG sont des 'array of string' globaux...

T'as un problème dans tes begin/end.

Voici le même code indenté à la Borland :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
function tfrmMain.arrayToPointer(value: string; zone: boolean): Pointer;
var
   i, i2: integer;
 
begin
  if zone then
    for i := 0 to length(fieldswG) - 1 do
      if (UpperCase(fieldswG[i]) = UpperCase(value)) then
      begin
        result := @fieldswg[i];
        exit;
      end
      else
        for i := 0 to length(fieldsw) - 1 do
          if (UpperCase(fieldsw[i]) = UpperCase(value)) then
          begin
            result := @fieldsw[i];
            exit;
          end;
end;

[EDIT]
En gros, tu fais une boucle sur i à l'intérieur d'une boucle sur i.

Voici ce qui corrigerait la situation :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
function tfrmMain.arrayToPointer(value: string; zone: boolean): Pointer;
var
  i, i2: integer;
 
begin
  if zone then
  begin
    for i := 0 to length(fieldswG) - 1 do
      if (UpperCase(fieldswG[i]) = UpperCase(value)) then
      begin
        result := @fieldswg[i];
        exit;
      end;
  end
  else
  begin
    for i := 0 to length(fieldsw) - 1 do
      if (UpperCase(fieldsw[i]) = UpperCase(value)) then
      begin
        result := @fieldsw[i];
        exit;
      end;
  end;
end;

11/10/2006, 16h53
hy00ga

Exact :) Il essaye d'affecter Ton else au if(UpperCase.....) au lieu d'au "if zone" ce qui est pas ce que tu veux :) Faut faire gaffe quand on a plusieurs structures if et/ou boucle imbriqués. On a interet a mettre le begin/else meme si il n'y a qu'un bloc d'instruction dedans :) En plus c'est plus lisible .. enfin je trouve :)
11/10/2006, 17h03
nek_kro_kvlt

merci a vous deux, on mettras ça sur le compte de la fatigue ;)