Filtre dates avec VBA

Version imprimable

Bonjour

J'essaye de déployer une macro d'un fichier Excel (commencant en cellule B4, jusqu'à colonne P avec un nombre de lignes différentes chaque semaine)
Je n'arrive pas à faire les filtres au niveau des dates :

Colonne C (2ème colonne) Filtre sur Date >= aujourdhui et Date <= aujourdhui + 13 jours
ET Colonne K (10ème colonne) Filtre sur Date = aujourdhui

Les 2 filtres doivent être lancé en meme temps

ces 2 colonnes de date sont dans le format : [$-x-sysdate]jjjj, mmmm jj, aaaa (jeudi 20 novembre 2025)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 Sub Macro1() Dim ws As Worksheet Dim lastRow As Long Dim dateDuJour As Date Dim dateFin As Date ' Définir la feuille active Set ws = ActiveSheet ' Trouver la dernière ligne utilisée dans la colonne B lastRow = ws.Cells(ws.Rows.Count, "B").End(xlUp).Row ' Définir les dates dynamiquement dateDuJour = Date ' Date du jour (ex: 20/11/2025) dateFin = Date + 13 ' Date du jour + 13 jours (ex: 03/12/2025) ' Appliquer le filtre With ws.Range("$B$4:$P" & lastRow) ' Filtre sur la colonne 2 : entre dateDuJour et dateDuJour + 13 .AutoFilter Field:=2, Criteria1:=">=" & dateDuJour, Operator:=xlAnd, Criteria2:="<=" & dateFin ' Filtre sur la colonne 10 : égal à dateDuJour .AutoFilter Field:=10, Criteria1:="=" & dateDuJour End With End Sub
A chaque fois que je lance la macro, il ne me mets aucune ligne alors que ce jour j'ai une 60aines de lignes.

Savez vous me dire où est le beug ?

Merci d'avance

Bonjour,

à tester

Code:

1
2
3
4
5
6
    With ws.Range("$B$4:$P" & lastRow)
        ' Filtre sur la colonne 2 : entre dateDuJour et dateDuJour + 13
        .AutoFilter Field:=2, Criteria1:=">=" & clng(dateDuJour), Operator:=xlAnd, Criteria2:="<=" & clng(dateFin)
        ' Filtre sur la colonne 10 : égal à dateDuJour
        .AutoFilter Field:=10, Criteria1:="=" & clng(dateDuJour)
    End With

21/11/2025, 11h46
Nain porte koi
Hello,

autre solution : avec VBA il faut mettre les dates au format mois/jour/année
Code:

1 2 dateDuJour = Format(Date, "mm/dd/yyyy") dateFin = Format(Date + 13, "mm/dd/yyyy")
21/11/2025, 12h44
chipster62

1 pièce(s) jointe(s)

bonjour

merci pour vos propositions, mais cela ne marche toujours pas.

Je joins mon fichier.
Pièce jointe 671973

Si je filtre "manuellement" la date (entre le 21/11 et 04/12) et la date suivi (21/11/2025) j'ai 61 lignes.
alors que la macro ne m'en donne aucune.

Merci beaucoup de votre aide.

2 pièce(s) jointe(s)

Bonjour,
Je vous propose une approche plus moderne d'excel en utilisant comme source de données un tableau structuré et utiliser Power Query pour exporter les données suivant vos critères dans une autre feuille.

Code de la requête Power Query
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 let // --- Chargement des paramètres depuis Excel et typage au format Date --- pStartDate=Date.From(Excel.CurrentWorkbook(){[Name="pStartDate"]}[Content]{0}[Column1]), pEndDate = Date.From(Excel.CurrentWorkbook(){[Name="pEndDate"]}[Content]{0}[Column1]), // --- Chargement de la table t_Collect --- Source = Excel.CurrentWorkbook(){[Name="t_Collect"]}[Content], // On modifie le type des colonnes Date et Date suivi en date pour pouvoir les filtrer ModifyTypeDate = Table.TransformColumnTypes(Source,{{"Date", type date}, {"Date suivi", type date}}), // --- Filtrage --- FiltreFinal = Table.SelectRows( ModifyTypeDate, each [Date] >= pStartDate and [Date] <= pEndDate and [Date suivi] = pStartDate ), // Suppression de la colonne DateSuivi RemoveColumn_DateSuivi = Table.RemoveColumns(FiltreFinal,{"Date suivi"}) in RemoveColumn_DateSuivi
Illustration de la feuille contenant la liste exportée

Les cellules B1 et B2 de la feuille contenant l'exportation sont nommées respectivement pStartDate et pEndDate contenant pour la premire la fonction =AUJOURDHUI() et pour la seconde =pStartDate + 13
Pour actualiser la table exportée il suffit de faire un clic droit sur l'une des cellules et cliquer sur la commande Actualiser mais on peut bien entendu effectuer cette actualisation à l'aide d'une seule ligne de code VBA

Pièce jointe 671976

Bonjour,

Visiblement les filtres auto ont changé, il fut une époque où la transformation en entier marchait

En enregistrant une macro et avec quelques tests, une proposition

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Mail()
 
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim dateDuJour As String
    Dim dateFin As String
 
    ' Définir la feuille active
    Set ws = ActiveSheet
 
    ' Trouver la dernière ligne utilisée dans la colonne B
    lastRow = ws.Cells(ws.Rows.Count, "B").End(xlUp).Row
 
    ' Définir les dates dynamiquement
    'dateDuJour = Date          ' Date du jour (ex: 20/11/2025)
    'dateFin = Date + 13        ' Date du jour + 13 jours (ex: 03/12/2025)
    dateDuJour = Format(Date, "mm/dd/yyyy")
    dateFin = Format(Date + 13, "mm/dd/yyyy")
 
    ' Appliquer le filtre
    With ws.Range("$B$4:$P" & lastRow)
        ' Filtre sur la colonne 2 : entre dateDuJour et dateDuJour + 13
        .AutoFilter Field:=2, Criteria1:=">=" & dateDuJour, Operator:=xlAnd, Criteria2:="<=" & dateFin
        ' Filtre sur la colonne 10 : égal à dateDuJour
        .AutoFilter Field:=10, Operator:= _
            xlFilterValues, Criteria2:=Array(2, dateDuJour)
    End With
End Sub

J'ai transformé les dates en type long et ça fonctionne.
C'est pour éviter les dates contenant aussi la partie temps

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub Mail()
 
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim dateDuJour As Long
    Dim dateFin As Long
 
    ' Définir la feuille active
    Set ws = ActiveSheet
 
    ' Trouver la dernière ligne utilisée dans la colonne B
    lastRow = ws.Cells(ws.Rows.Count, "C").End(xlUp).Row
     ' Définir les dates dynamiquement
    'dateDuJour = Date          ' Date du jour (ex: 20/11/2025)
    'dateFin = Date + 13        ' Date du jour + 13 jours (ex: 03/12/2025)
    dateDuJour = Int(Date) ' éviter l'arroundi
    dateFin = Int(Date + 13)
    ' Appliquer le filtre
    With ws.Range("$B$4:$P" & lastRow)
        ' Filtre sur la colonne 2 : entre dateDuJour et dateDuJour + 13
         .AutoFilter Field:=2, Criteria1:=">=" & dateDuJour, Operator:=xlAnd, Criteria2:="<=" & dateFin
        ' Filtre sur la colonne 10 : égal à dateDuJour
         .AutoFilter Field:=10, Criteria1:=">=" & dateDuJour, Operator:=xlAnd, Criteria2:="<=" & dateDuJour
    End With
    Dim ret As Long
    On Error Resume Next
    ret = ws.Range("$B$4:$B$" & lastRow).SpecialCells(xlCellTypeVisible).Count
 
    MsgBox ret & " " & "trouvé(s)"
End Sub

21/11/2025, 23h45
tototiti2008

Bonsoir,

Quand même bizarre qu'avec la même valeur (date convertie en entier)

Code:

.AutoFilter Field:=10, Criteria1:="=" & dateDuJour

ne trouve rien mais

Code:

.AutoFilter Field:=10, Criteria1:=">=" & dateDuJour, Operator:=xlAnd, Criteria2:="<=" & dateDuJour

trouve les bons résultats

Un peu de cohérence chez MS ne ferait pas de mal

D'ailleurs sur ma version (avec les dates en texte format mm/dd/yyyy)

Code:

.AutoFilter Field:=10, Operator:=xlFilterValues, Criteria2:=Array(2, dateDuJour)

fonctionne mais

Code:

.AutoFilter Field:=10, Criteria1:=dateDuJour

ou

Code:

.AutoFilter Field:=10, Criteria1:="=" & dateDuJour

plante