problèmes Filtre combobox

Version imprimable

1 pièce(s) jointe(s)

Bonjour à tous

j'ai un combobox (désignation) que je filtre en fonction d'une autre ( catégorie articles).

lorsque je choisis une valeur dans la catégorie articles, les valeurs correspondantes a la désignation s'affiche bien.

mon soucis est que lorsque je choisis à nouveau un autre catégorie d'articles, au lieu que les valeurs dans le combobox désignation soit celle uniquement celle de la nouvelle catégorie , les nouvelles valeurs viennent s'ajouter à celle déjà saisie.

voici le code que j'ai utilisé.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 Private Sub ComboArticles_Change() Dim Lr As Long, i As Long Dim f As Worksheet Dim key As String Set f = Sheets("Articles") Me.ComboDesignation.ListIndex = -1 Lr = f.Range("a" & Rows.Count).End(xlUp).Row key = Me.ComboArticles.Value For i = 2 To Lr If key = f.Range("l" & i).Value Then Me.ComboDesignation.AddItem f.Range("B" & i).Value End If Me.ComboDesignation.ListIndex = -1 Next i Set f = Nothing End Sub
Pj: le fichier exemple

merci d'avance pour vos différentes contributions
cordialement

Salut, il suffit de vider la combobox avant de la remplir à nouveau selon l'article avec .Clear

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub ComboArticles_Change()
    Dim Lr As Long, i As Long
    Dim f As Worksheet
    Dim key As String
 
    Set f = Sheets("Articles")
 
    ' Vider la liste des items précédents
    Me.ComboDesignation.Clear
 
    Lr = f.Range("A" & f.Rows.Count).End(xlUp).Row
    key = Me.ComboArticles.Value
 
    For i = 2 To Lr
        If key = f.Range("L" & i).Value Then
            Me.ComboDesignation.AddItem f.Range("B" & i).Value
        End If
    Next i
 
    Me.ComboDesignation.ListIndex = -1
    Set f = Nothing
End Sub

Merci Franc pour ta réponse!

çà marche parfaitement.

je voudrais profiter aussi pour soumettre un autre souci.

Dans mon userform, j'alimente ma listview avec les infos provenant de détails facture.

je voudrais que lorsque celle ci est alimenter (listview) pouvoir avec le bouton enregistrer exporter les données contenues dans le listview vers la feuille e calcul (Achat).

j'ai essayer avec ce code mais il passe. aucune info n'est copié.
je sais que ce n'est pas l'objet du topic. mais si tu pouvais y jeter un coup d'œil

merci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Private Sub BtnEnregistrer_Click()
 
Dim Ws As Worksheet
Dim L As Long, Cl As Long, i As Long, j As Long, Lr As Long
Dim Tbl() As Variant
 
Set Ws = Worksheets("Achat")
Ws.Select
With Me.ListVAppro
 
    'mise en memoire de la listview
    L = .ListItems.Count
    Cl = .ColumnHeaders.Count
 
    ReDim Tbl(1 To L + 1, 1 To Cl)
 
    For i = 1 To L
        Tbl(i, 1) = .ListItems(i).Text
        For j = 1 To Cl - 1
            Tbl(i, j + 1) = .ListItems(i).ListSubItems(j).Text
        Next j
    Next i
 
If .ListItems.Count < 1 Then
 
    MsgBox " Ajouter des produits a la facture!", vbCritical + vbOKOnly, ""
 
    Exit Sub
Else
    If MsgBox("Voulez - vous enregistrer cette facture?", vbYesNo, "Demande de confirmation") = vbYes Then
 
        With Ws
        Lr = .Cells(Rows.Count, 1).End(xlUp).Row 'derniere ligne ocuppe sur la ligne A
 
        For i = 1 To L ' boucle sur les lignes du tableau
 
            .Range("c" & Lr + i) = Tbl(i, 1) ' Articles
            .Range("D" & Lr + i) = Tbl(i, 2) ' Qte
            .Range("e" & Lr + i) = Tbl(i, 3) ' PU
            .Range("f" & Lr + i) = Tbl(i, 4) ' Remise
            .Range("g" & Lr + i) = Tbl(i, 5) ' Montant
            .Range("b" & Lr + i) = CDate(Me.TextDate) ' Date
            .Range("h" & Lr + i) = Me.ComboFrs ' fournisseurs
            .Range("i" & Lr + i) = Tbl(i, 1) ' code facture
 
        Next i
 
      End With
 
    End If
End If
End With
 
Unload Me
FrmAppro.show
 
' reinitialiser listview
'Me.ListVAppro.ListItems.Clear
 
End Sub

Bonsoir,
De cette manière peut-être

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Private Sub BtnEnregistrer_Click()
 
    Dim Ws As Worksheet
    Set Ws = ThisWorkbook.Worksheets("Achat")    ' // Travailler plutôt avec le nom de code de la feuille !
    Ws.Select
 
    With Me.ListVAppro
        ' Vérifier si la ListView est vide
        If .ListItems.Count > 0 Then
            ' Mise en mémoire du tableau de la ListView
            Dim L As Long
            L = .ListItems.Count
 
            Dim Cl As Long
            Cl = .ColumnHeaders.Count
 
            Dim newRow As Long
            newRow = Ws.Cells(Ws.Rows.Count, "A").End(xlUp).Row + 1
 
            ReDim Tbl(1 To L, 1 To Cl)
            Dim i As Long
            For i = 1 To L
                Tbl(i, 1) = .ListItems(i).Text
                Dim j As Long
                For j = 1 To Cl - 1
                    Tbl(i, j + 1) = .ListItems(i).ListSubItems(j).Text
                Next j
 
                ' Effectuer les actions supplémentaires directement ici
                If IsDate(Me.TextDate) Then: Ws.Range("B" & newRow + i - 1).Value = CDate(Me.TextDate)  ' Date
                Ws.Range("H" & newRow + i - 1).Value = Me.ComboFrs ' Fournisseur
                Ws.Range("I" & newRow + i - 1).Value = Tbl(i, 1) ' Code facture
            Next i
 
            ' Copier le tableau en une seule opération
            Ws.Range("C" & newRow).Resize(UBound(Tbl, 1), UBound(Tbl, 2)).Value = Tbl
        Else
            MsgBox "Ajouter des produits à la facture!", vbCritical + vbOKOnly, "Erreur"
        End If
 
    End With
 
    'ToDo "On doit trouver mieux pour faire cela."
    Unload Me
    FrmAppro.Show
 
End Sub

Mais sans fichier impossible de tester...

03/04/2025, 11h45
Franc

Salut, ta macro fonctionne, mais pour je ne sais quelle raison, la copie des données commence à la ligne 712, donc tu ne vois rien. J'ai testé en supprimant les lignes de 2 à 711 et la macro copie bien les données en-dessous des lignes existantes. Ceci dit, il me semble que les valeurs ne se copient pas dans les bonnes colonnes. Je te conseillerais d'utiliser un tableau structuré plutôt qu'une plage de cellules, pas besoin de chercher la dernière ligne, référence aux colonnes via leur nom, etc...
03/04/2025, 12h56
Angeoffi

Citation:

Envoyé par Franc

Salut, ta macro fonctionne, mais pour je ne sais quelle raison, la copie des données commence à la ligne 712, donc tu ne vois rien. J'ai testé en supprimant les lignes de 2 à 711 et la macro copie bien les données en-dessous des lignes existantes. Ceci dit, il me semble que les valeurs ne se copient pas dans les bonnes colonnes. Je te conseillerais d'utiliser un tableau structuré plutôt qu'une plage de cellules, pas besoin de chercher la dernière ligne, référence aux colonnes via leur nom, etc...

Bonjour Franc

Excuse moi pour le temps de réponse. un peu déconnecté depuis.

merci

effectivement la copie des données commencent a partir de la ligne 712. je sais pas moi même pourquoi c'est ainsi.

j'ai également revue l'ordre de copie des données.

encore une fois merci
03/04/2025, 14h31
deedolith

Hello,

Code:

.Cells(Rows.Count, 1).End(xlUp)

Une réponse de Copilot:

Citation:

La méthode `Range.End` en VBA est souvent utilisée pour naviguer rapidement dans une feuille de calcul, notamment pour trouver la dernière cellule non vide d'une colonne ou d'une ligne. Cependant, ce n'est pas toujours la meilleure option pour localiser une cellule **vierge**. Cela dépend de votre contexte spécifique.

### Pourquoi `Range.End` ?
`Range.End(xlDown)` ou `Range.End(xlToRight)` suit un chemin similaire à la navigation par Ctrl + Flèche dans Excel, ce qui en fait un choix rapide pour atteindre la dernière cellule remplie dans une direction donnée. Cependant :
- Si la colonne ou la ligne contient des cellules vides intermédiaires, la méthode s'arrête avant.
- Elle ne recherche pas explicitement des cellules vierges.

### Alternatives pour trouver une cellule **vierge** :
Si vous cherchez **la première cellule vierge** après des données, ou **la toute dernière cellule remplie d'une plage**, d'autres approches peuvent être plus fiables :

1. **Utiliser UsedRange** :
```vba
Dim ws As Worksheet
Dim lastCell As Range
Set ws = ThisWorkbook.Sheets("NomDeLaFeuille")
Set lastCell = ws.UsedRange.Cells(ws.UsedRange.Rows.Count, ws.UsedRange.Columns.Count)
```

Cela vous donne une idée des limites des données dans la feuille.

2. **Boucle pour recherche explicite** :
Une boucle peut identifier la dernière cellule non vide de manière plus contrôlée :
```vba
Dim i As Long
For i = 1 To Rows.Count
If IsEmpty(Cells(i, 1)) Then
MsgBox "Première cellule vide : " & Cells(i, 1).Address
Exit For
End If
Next i
```

3. **SpecialCells** (pour chercher directement les cellules vides) :
```vba
Dim emptyCell As Range
Set emptyCell = ActiveSheet.Columns(1).SpecialCells(xlCellTypeBlanks)
MsgBox "Adresse de la première cellule vide : " & emptyCell.Address
```

### En conclusion :
`Range.End` est idéal pour des déplacements rapides dans des données **contiguës**, mais pour une recherche ciblée sur les cellules vierges, une méthode plus personnalisée comme une boucle ou `SpecialCells` est préférable. Vous pouvez combiner les approches selon vos besoins. 😊

Comme l'a indiqué Franc,
les tableaux structurés sont aussi une solution, vu qu'ils connaissent leurs nombre de ligne et colonnes.