VBA - SI ERREUR chemin d'accès pour enregistrer

Version imprimable

Bonjour,

Dans mon fichier j'ai un code permettant d'enregistrer le résultat de mon formulaire en PDF.
Plusieurs personnes utilisent ce fichier mais le nom du répertoire diffère en fonction des personnes ( pour certains c'est M:\.... pour d'autres O:\.... ou encore Z:\....

Est il possible d'avoir un code du type si réseau non existant alors enregistrer sur le suivant?

Voici mon code de base :
Code:

1 2 3 4 5 6 7 8 9 Dim NomFichier As String NomFichier = Sheets("Fiche de renseignement Pôle").Range("E6").Value & " - " & Sheets("Fiche de renseignement Pôle").Range("D6").Value Sheets("Fiche de renseignement Pôle").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _ "M:\ATLAS\COMMUN\ATLAS\16 - Circuit arrivée-départ\01 - Circuits\" & NomFichier & ".pdf", _ Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _ :=False, OpenAfterPublish:=True
Je vous remercie pour votre aide

05/03/2025, 10h11
Philippe Tulliez

Bonjour,
La propriété Path de l'objet Thisworbook indique le chemin du classeur où se trouve le classeur contenant le code Vba
05/03/2025, 10h40
tototiti2008

Bonjour,

Si M:, O:, Z: représentent le même serveur réseau, on peut envisager de mettre le chemin réseau du type
\\NomServeur\DossierServeurPartage\

Évidement si le nom du serveur change, ça peut poser problème

1 pièce(s) jointe(s)

Citation:

Envoyé par tototiti2008

Bonjour,

Si M:, O:, Z: représentent le même serveur réseau, on peut envisager de mettre le chemin réseau du type
\\NomServeur\DossierServeurPartage\

Évidement si le nom du serveur change, ça peut poser problème

Bonjour,

j'ai essayé en inscrivant le nom du réseau mais cela ne fonctionne pas. Ai je fait la bonne manip'?
De plus, pour moi ce nom de réseau change en fonction de la ville où se trouve l'utilisateur :?
Code:

1 2 3 4 5 6 NomFichier = Sheets("Fiche de renseignement Pôle").Range("E6").Value & " - " & Sheets("Fiche de renseignement Pôle").Range("D6").Value Sheets("Fiche de renseignement Pôle").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _ "\\inf11mpd--wi01\ATLAS\COMMUN\ATLAS\16 - Circuit arrivée-départ\01 - Circuits\" & NomFichier & ".pdf", _ Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _ :=False, OpenAfterPublish:=True
Pièce jointe 665189

05/03/2025, 15h35
Philippe Tulliez

Bonjour,
Si le classeur se trouve sur le réseau l'instruction ThisWorkbook.Path doit vous renvoyer le chemin complet
05/03/2025, 15h47
Anne-Sushi

Citation:

Envoyé par Philippe Tulliez

Bonjour,
Si le classeur se trouve sur le réseau l'instruction ThisWorkbook.Path doit vous renvoyer le chemin complet

Je suis relativement novice en VBA. Pouvez vous m'expliquer plus en détail?

Bonjour,
Mes applications en VBA, que ce soit avec Power Query, Access, Word, PowerPoint ou Excel sont toujours installées dans un répertoire dédié qui contient lui même des sous-répertoires comme Template, Pdf, etc.
En utilisant Thisworkbook.Path cela me permet de connaître le chemin où se trouve le classeur central de l'application parce-qu'évidemment les chemins peuvent être différents d'un PC à l'autre

Voici un exemple d'une procédure qui exporte en pdf la feuille active dans le sous-répertoire du classeur où se trouve le code VBA
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Option Explicit Sub Main() Const SubFolder As String = "\pdf\" ' Nom du sous-répertoire où sauver le pdf Dim PathName As String ' Chemin du répertoire courant Dim FileName As String ' Nom du fichier Dim FullName As String ' Nom complet du fichier (Répertoire courant + Sous-dossier + FileName) FileName = Format(Now, "YYMMDD_HH-MM") & " Test.pdf" PathName = ThisWorkbook.Path FullName = PathName & SubFolder & FileName ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _ FileName:=FullName End Sub

Re,

Évidement comme proposé par Philippe si Thisworkbook.path permet de connaitre le chemin du réseau, c'est la solution la plus simple

Pour le code
Code:

1 2 3 4 5 6 7 8 9 Dim NomFichier As String NomFichier = Sheets("Fiche de renseignement Pôle").Range("E6").Value & " - " & Sheets("Fiche de renseignement Pôle").Range("D6").Value Sheets("Fiche de renseignement Pôle").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _ "M:\ATLAS\COMMUN\ATLAS\16 - Circuit arrivée-départ\01 - Circuits\" & NomFichier & ".pdf", _ Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _ :=False, OpenAfterPublish:=True
En effet, j'ai testé chez moi Worksheets(1).ExportAsFixedFormat plante avec un chemin réseau
Mais assez étonnamment Thisworkbook.ExportAsFixedFormat a marché chez moi avec un chemin réseau
Pourquoi ? je l'ignore

05/03/2025, 17h40
tototiti2008

Re,

Non, finalement, mon deuxième essai de Sheets(1).ExportAsFixedFormat avec un chemin réseau a marché, pas compris ce qui avait planté tout à l'heure

Bonjour,

Merci pour vos reponses :)

J'ai modifié le code comme suit :

Code:

1
2
3
4
5
6
7
8
9
  Const SubFolder As String = "\01 - Circuits\" ' Nom du sous-répertoire où sauver le pdf
  Dim PathName As String ' Chemin du répertoire courant
  Dim FileName As String ' Nom du fichier
  Dim FullName As String ' Nom complet du fichier (Répertoire courant + Sous-dossier + FileName)
  FileName = Sheets("Fiche de renseignement Pôle").Range("E6").Value & " - " & Sheets("Fiche de renseignement Pôle").Range("D6").Value
  PathName = ThisWorkbook.Path
  FullName = PathName & SubFolder & FileName
Sheets("Fiche de renseignement Pôle").ExportAsFixedFormat Type:=xlTypePDF, _
                                  FileName:=FullName

Cependant, autre point, dans mon code j'ai une condition pour dire si c'est tel cas, alors ce code, si c'est l'autre cas alors l'autre code. Et là... je n'y arrive pas avec ce nouveau code, j'ai le message " déclaration existant dans la portée en cours"

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
If Pole_PCD = "Oui" Then
Sheets("Fiche de renseignement Pôle").Range("K8") = Circuit
Sheets("Fiche de renseignement Pôle").Range("K9") = Motif
Sheets("Fiche de renseignement Pôle").Range("K10") = Pole_PCD
Sheets("Fiche de renseignement Pôle").Range("K11") = Statut
Sheets("Fiche de renseignement Pôle").Range("K12") = Corps
Sheets("Fiche de renseignement Pôle").Range("K13") = Date_circuit
Sheets("Fiche de renseignement Pôle").Range("B6") = TextBox17
Sheets("Fiche de renseignement Pôle").Range("C6") = Grade
Sheets("Fiche de renseignement Pôle").Range("D6") = TextBox1
Sheets("Fiche de renseignement Pôle").Range("E6") = TextBox15
Sheets("Fiche de renseignement Pôle").Range("B8") = Ville
Sheets("Fiche de renseignement Pôle").Range("D8") = Affectation
 
 
 
  Const SubFolder As String = "\01 - Circuits\" ' Nom du sous-répertoire où sauver le pdf
  Dim PathName As String ' Chemin du répertoire courant
  Dim FileName As String ' Nom du fichier
  Dim FullName As String ' Nom complet du fichier (Répertoire courant + Sous-dossier + FileName)
  FileName = Sheets("Fiche de renseignement Pôle").Range("E6").Value & " - " & Sheets("Fiche de renseignement Pôle").Range("D6").Value
  PathName = ThisWorkbook.Path
  FullName = PathName & SubFolder & FileName
Sheets("Fiche de renseignement Pôle").ExportAsFixedFormat Type:=xlTypePDF, _
                                  FileName:=FullName
 
 
Else
Sheets("Fiche de renseignement Autre").Range("K8") = Circuit
Sheets("Fiche de renseignement Autre").Range("K9") = Motif
Sheets("Fiche de renseignement Autre").Range("K10") = Pole_PCD
Sheets("Fiche de renseignement Autre").Range("K11") = Statut
Sheets("Fiche de renseignement Autre").Range("K12") = Corps
Sheets("Fiche de renseignement Autre").Range("K13") = CIMS
Sheets("Fiche de renseignement Autre").Range("B6") = TextBox17
Sheets("Fiche de renseignement Autre").Range("C6") = Grade
Sheets("Fiche de renseignement Autre").Range("D6") = TextBox1
Sheets("Fiche de renseignement Autre").Range("E6") = TextBox15
Sheets("Fiche de renseignement Autre").Range("B8") = Ville
Sheets("Fiche de renseignement Autre").Range("D8") = Affectation
 
  Const SubFolder As String = "\01 - Circuits\" ' Nom du sous-répertoire où sauver le pdf
  Dim PathName As String ' Chemin du répertoire courant
  Dim FileName As String ' Nom du fichier
  Dim FullName As String ' Nom complet du fichier (Répertoire courant + Sous-dossier + FileName)
  FileName = Sheets("Fiche de renseignement Autre").Range("E6").Value & " - " & Sheets("Fiche de renseignement Autre").Range("D6").Value
  PathName = ThisWorkbook.Path
  FullName = PathName & SubFolder & FileName
Sheets("Fiche de renseignement Autre").ExportAsFixedFormat Type:=xlTypePDF, _
                                  FileName:=FullName
 
End If

06/03/2025, 13h30
Philippe Tulliez

Bonjour,

Citation:

déclaration existant dans la portée en cours"

C'est normal.
On ne peut déclarer une variable qu'une seule fois et la valeur d'une constante ne peut plus être modifiée
A la place d'une constante, choisissez une variable pour le sous-répertoire.

Petit conseil : Ce n'est évidemment pas obligatoire mais il est plus facile pour la maintenance de déclarer les variables en tête de procédure. Dans l'ordre personnellement, je commence par déclarer mes constantes et ensuite les variables en commençant par les variables "objet". Cela me permet de ne pas oublier de les supprimer en fin de procédure.
06/03/2025, 16h29
Philippe Tulliez

Bonjour,
Je viens de relire votre code.
Finalement ni la constante, ni les variables ne sont concernées par la structure décisionnelle (le If) donc il faut conservé la déclaration de la constante et des variables en tête de procédure ainsi que l'affectation des variables. Les seules lignes à déplacer ce sont celles qui concerne l'exportation de la feuille après avoir rempli les cellules.
Il faut juste adapter le nom du fichier soit 'Fiche de renseignement Pôle" soit "Fiche de renseignement Autre" en fonction des critères et comme le nom des feuilles correspondes au nom des fichiers utiliser deux constantes et utiliser un bloc With...End With
06/03/2025, 17h26
Anne-Sushi

Citation:

Envoyé par Philippe Tulliez

Bonjour,
Je viens de relire votre code.
Finalement ni la constante, ni les variables ne sont concernées par la structure décisionnelle (le If) donc il faut conservé la déclaration de la constante et des variables en tête de procédure ainsi que l'affectation des variables. Les seules lignes à déplacer ce sont celles qui concerne l'exportation de la feuille après avoir rempli les cellules.
Il faut juste adapter le nom du fichier soit 'Fiche de renseignement Pôle" soit "Fiche de renseignement Autre" en fonction des critères et comme le nom des feuilles correspondes au nom des fichiers utiliser deux constantes et utiliser un bloc With...End With

Merci, cependant ne maitrisant pas, je n'ai pas bien compris ce qu'il faut que je fasse. Je ne vois pas comment utiliser le bloc With...End With[/QUOTE] :(

Bonjour,
Lorsque l'on utilise le même objet et/ou le même objet et propriété sur plusieurs lignes on crée un bloc With..End With
Ainsi au lieu d'avoir ces lignes
Code:

1 2 3 4 5 6 7 Sheets("Fiche de renseignement Autre").Range("K8") = Circuit Sheets("Fiche de renseignement Autre").Range("K9") = Motif Sheets("Fiche de renseignement Autre").Range("K10") = Pole_PCD Sheets("Fiche de renseignement Autre").Range("K11") = Statut Sheets("Fiche de renseignement Autre").Range("K12") = Corps Sheets("Fiche de renseignement Autre").Range("K13") = CIMS Sheets("Fiche de renseignement Autre").Range("B6") = TextBox17
on va écrire ceci
Code:

1 2 3 4 5 6 7 8 9 With Sheets("Fiche de renseignement Autre") .Range("K8").Value = Circuit .Range("K9").Value = Motif .Range("K10").Value = Pole_PCD .Range("K11").Value = Statut .Range("K12").Value = Corps .Range("K13").Value = CIMS .Range("B6").Value = TextBox17 End With
et au lieu d'utiliser en dur le nom de la feuille, je créerais une constante ou une variable. Cela facilite grandement la maintenance de votre code

Bonjour Anne,
Si je ne me trompe pas il y a moyen de raccourcir votre procédure en utilisant une variable Excel.WorkSheet.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
    Const SUBFOLDER As String = "\01 - Circuits\" ' Nom du sous-répertoire où sauver le pdf
 
    ' // Déclaration de la feuille cible, et affectation selon la valeur  de Pole_PCD
    Dim SheetCible  As Excel.Worksheet
    If Pole_PCD = "Oui" Then
        Set SheetCible = Sheets("Fiche de renseignement Pôle")
    Else
        Set SheetCible = Sheets("Fiche de renseignement Autre")
    End If
 
    With SheetCible ' // Utilisation d'un bloc With sur la variable SheetCible
        .Range("K8") = Circuit
        .Range("K9") = Motif
        .Range("K10") = Pole_PCD
        .Range("K11") = Statut
        .Range("K12") = Corps
        .Range("K13") = Date_circuit
        .Range("B6") = TextBox17
        .Range("C6") = Grade
        .Range("D6") = TextBox1
        .Range("E6") = TextBox15
        .Range("B8") = Ville
        .Range("D8") = Affectation
 
        Dim FileName As String
        FileName = .Range("E6").Value & " - " & .Range("D6").Value
 
        Dim PathName As String
        PathName = ThisWorkbook.Path
 
        Dim FullName As String
        FullName = PathName & SUBFOLDER & FileName
        .ExportAsFixedFormat Type:=xlTypePDF, _
                             FileName:=FullName
    End With

Bonjour à tous,

Merci pour vos message et pour votre aide! :D :D

J'ai testé les deux propositions et les deux fonctionnent.

J'ai opté pour la seconde, le première m'obligeant à donner des noms différents aux éléments afin de permettre l'enregistrement, ce qui faisait un code plus grand et un peu moins lisible pour moi, novice.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Const SUBFOLDER As String = "\01 - Circuits\" ' Nom du sous-répertoire où sauver le pdf
 
    ' // Déclaration de la feuille cible, et affectation selon la valeur  de Pole_PCD
    Dim SheetCible  As Excel.Worksheet
    If Pole_PCD = "Oui" Then
        Set SheetCible = Sheets("Fiche de renseignement Pôle")
    Else
        Set SheetCible = Sheets("Fiche de renseignement Autre")
    End If
 
    With SheetCible ' // Utilisation d'un bloc With sur la variable SheetCible
        .Range("K8") = Circuit
        .Range("K9") = Motif
        .Range("K10") = Pole_PCD
        .Range("K11") = Statut
        .Range("K12") = Corps
        .Range("K13") = Date_circuit
        .Range("B6") = TextBox17
        .Range("C6") = Grade
        .Range("D6") = TextBox1
        .Range("E6") = TextBox15
        .Range("B8") = Ville
        .Range("D8") = Affectation
 
        Dim FileName As String
        FileName = .Range("E6").Value & " - " & .Range("D6").Value
 
        Dim PathName As String
        PathName = ThisWorkbook.Path
 
        Dim FullName As String
        FullName = PathName & SUBFOLDER & FileName
        .ExportAsFixedFormat Type:=xlTypePDF, _
                             FileName:=FullName, _
                             OpenAfterPublish:=True
 
    End With