VBA Excel - Split TextToColumns

Version imprimable

Bonjour à tous,

Je transforme les données d'une colonne contenant ce type de données :
"DSO / CHAMPAGNE ARDENNE / INTERVENTIONS AUBE / POLE BAR S / CAR OPE INT EXP AUB B"

Je zoome sur le caractère "/" pour séparer mes données.

Je me suis appuyé sur la code suivant pour cela (je suis parti de l'enregistreur et j'ai adapté) :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Sheets("DATA_V").Columns("F:F").Select Selection.TextToColumns Destination:=Range("Z1"), DataType:=xlDelimited, _ TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _ Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar _ :="/", FieldInfo:=Array(Array(1, 1), Array(2, 1), Array(3, 1), Array(4, 1), Array(5, _ 1)), TrailingMinusNumbers:=True
Hélas j'ai quelques situations qui font que cela ne marche pas très bien :
DSO / ALSACE FRANCHE COMTE / DIRECTION TERRITORIALE 70/39 / DIRECTION TERRITORIALE 70/39 / AFC TER DTL 39/70

Comme il y a des "/", dans certains descriptions, j'ai des colonnes en plus de l'attendu.
J'ai fait des tests comme l'ajout d'espaces OtherChar :=" / " mais cela ne marche pas comme attendu car je voudrais uniquement que le split se fasse quand on a un espace avant et après le caractère "/"
Savez-vous si une alternative existe ?

Merci pour aide

17/02/2025, 18h51
mapeh

Bonsoir,
Power Query pourrait le faire nativement, mais si préférence pour le VBA, pourquoi ne pas remplacer " / " par "" avant le split?
Bonne soirée

je voulais dire par le back slash, mais l'éditeur n'en veut pas

Citation:

\

Bonjour,

un peu dans l'idée de ce que proposait mapeh

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
 
 
Sheets("DATA_V").Columns("F:F").Select
 
    Selection.Replace What:=" / ", Replacement:="µ", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False, FormulaVersion:=xlReplaceFormula2
 
        Selection.TextToColumns Destination:=Range("Z1"), DataType:=xlDelimited, _ 
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _ 
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar _ 
        :="µ", FieldInfo:=Array(Array(1, 1), Array(2, 1), Array(3, 1), Array(4, 1), Array(5, _ 
        1)), TrailingMinusNumbers:=True

Oui, la même chose en plus condensé:

Code:

1
2
3
4
5
    With Sheets("DATA_V").Columns("F:F")
        .Replace What:=" / ", Replacement:="|", LookAt:=xlPart
        .TextToColumns Destination:=Range("Z1"), DataType:=xlDelimited, Other:=True, OtherChar:="|"
        .Replace What:="|", Replacement:=" / ", LookAt:=xlPart
    End With

Bien cordialement.

Bonjour,
Citation:
Envoyé par EricDgn
Oui, la même chose en plus condensé:
Code:

1 2 3 4 5 With Sheets("DATA_V").Columns("F:F") .Replace What:=" / ", Replacement:="|", LookAt:=xlPart .TextToColumns Destination:=Range("Z1"), DataType:=xlDelimited, Other:=True, OtherChar:="|" .Replace What:="|", Replacement:=" / ", LookAt:=xlPart End With
Bien cordialement.
Ayant été confronté plusieurs fois à un comportement étrange de l'instruction TextToColumns, je préfère éviter ce "condensement".
Excel garde en mémoire (le temps de sa session), les options définies lors d'une éventuelle utilisation antérieure de la fonction "Convertir" à partir du ruban "Données".
Et parfois, le fait de ne pas spécifier tous les paramètres dans le code peut amener à des résultats "surprenants".
Et pour la dernière ligne, vraiment nécessaire? ("Convertir" supprime le délimiteur, il me semble???)
Bonne journée

18/02/2025, 11h12
EricDgn

Le dernier Convertir (Replace) n'est là que pour revenir au texte initial dans la colonne initiale. Le TextToColumn supprime le délimiteur dans les colonnes créées, il ne modifie pas le texte de départ, lequel reste inchangé... sauf si la destination est la cellule de départ, auquel cas le texte initial est écrasé (et on n'y retrouvera plus le délimiteur).
Cordialement.
18/02/2025, 12h03
mapeh

Re-,

Citation:

Envoyé par EricDgn

Le dernier Convertir (Replace) n'est là que pour revenir au texte initial dans la colonne initiale. Le TextToColumn supprime le délimiteur dans les colonnes créées, il ne modifie pas le texte de départ, lequel reste inchangé... sauf si la destination est la cellule de départ, auquel cas le texte initial est écrasé (et on n'y retrouvera plus le délimiteur).
Cordialement.

Au temps pour je...
Si j'avais été plus attentif, j'aurais effectivement vu que le texte fractionné est restitué en colonne "Z"...
Désolé :oops:
18/02/2025, 13h11
jurassic pork

1 pièce(s) jointe(s)

Hello,
Avec la fonction RegexSplitJP de mon complément Excel XlDnaLibJP qui utilise les expressions régulières
cela peut se faire par formule :
la fonction a comme paramètre la cellule qui contient le texte à éclater et en deuxième paramètre
le motif de l'expression régulière qui va servir de séparateur pour éclater le texte
Par exemple avec cette formule

Code:

=REGEXSPLITJP(A1;"\s+/\s+")

le motif correspond à 1 ou plus espace suivi d'un slash suivi d'un ou plus espace.
Le Résultat va s''étendre sur plusieurs colonnes sur la même ligne :

Pièce jointe 664616

Ami calmant, J.P

Bonjour

par formule FRACTIONNER.TEXTE si version récente d'Excel :

Code:

=FRACTIONNER.TEXTE(A1;" / ")

sinon Power Query en quelques clics avec la fonctionnalité de fractionnement par délimiteur
Code:

1 2 3 4 5 let Source = Votre_Source, #"Fractionner la colonne par délimiteur" = Table.SplitColumn(Source, "Votre_Colonne", Splitter.SplitTextByDelimiter(" / ", QuoteStyle.Csv)) in #"Fractionner la colonne par délimiteur"
Stéphane

1 pièce(s) jointe(s)

Bonjour,

En VBA on peut utiliser les tableaux mémoire.

Je t'ai mis un exemple en PJ.

Bien sûr ce n'est qu'un exemple pour savoir si l'idée et le résultat te conviennent. Ensuite il faut adapter en prenant en considération le décompte automatique du nombre de lignes, de colonnes, .....

Pour le moment je n'ai mis que 1 000 lignes et 5 colonnes d'exemple.

Teste et dis nous.

Le code pour ceux qui n'ouvrent pas les fichiers

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Option Explicit
Sub test()
 
Dim valeur_cours As String
 
Dim tablo_origine()
Dim index_1_tablo_origine As Long
 
Dim tablo_sortie() As String
 
ThisWorkbook.Sheets("Feuil1").Range("B1:F1000").Clear
 
tablo_origine = ThisWorkbook.Sheets("Feuil1").Range("A1:A1000").Value
 
ReDim tablo_sortie(1 To 1000, 1 To 5)
 
For index_1_tablo_origine = 1 To 1000
 
    valeur_cours = tablo_origine(index_1_tablo_origine, 1)
 
    tablo_sortie(index_1_tablo_origine, 1) = Split(valeur_cours, " / ")(0)
    tablo_sortie(index_1_tablo_origine, 2) = Split(valeur_cours, " / ")(1)
    tablo_sortie(index_1_tablo_origine, 3) = Split(valeur_cours, " / ")(2)
    tablo_sortie(index_1_tablo_origine, 4) = Split(valeur_cours, " / ")(3)
    tablo_sortie(index_1_tablo_origine, 5) = Split(valeur_cours, " / ")(4)
 
Next index_1_tablo_origine
 
ThisWorkbook.Sheets("Feuil1").Range("B1:F1000") = tablo_sortie
 
End Sub

Bonjour,

En effet les tableaux VBA peuvent être un vrai plus en terme de rapidité de traitement

une version qui ne présume pas d'un résultat sur 5 colonnes (et juste pour lancer d'éventuelles discussions)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub test()
 
Dim valeur_cours As String
 
Dim tablo_origine()
 
Dim tablo_sortie()
Dim index_1_tablo_origine As Long
 
ThisWorkbook.Sheets("Feuil1").Range("B1:F1000").Clear
 
tablo_origine = ThisWorkbook.Sheets("Feuil1").Range("A1:A1000").Value
 
ReDim tablo_sortie(1 To 1000)
 
For index_1_tablo_origine = 1 To 1000
 
    valeur_cours = tablo_origine(index_1_tablo_origine, 1)
 
    tablo_sortie(index_1_tablo_origine) = Split(valeur_cours, " / ")
 
    ThisWorkbook.Sheets("Feuil1").Range("B" & index_1_tablo_origine).Resize(1, UBound(tablo_sortie(index_1_tablo_origine), 1) + 1).Value = tablo_sortie(index_1_tablo_origine)
Next index_1_tablo_origine
 
End Sub

19/02/2025, 17h00
Alex020181

Yes tototiti2008 mais attention tu n'as pas modifié la ligne de réinitialisation en laissant B:F

Code:

ThisWorkbook.Sheets("Feuil1").Range("B1:F1000").Clear

Dans ce cas comme on ne prévoit pas le nombre de colonnes à l'avance il faut tout supprimer sur la droite par sécurité

Code:

ThisWorkbook.Sheets("Feuil1").Range("B1:XFD1000").Clear

Ou bien si il y a toujours le même nombre de colonnes on peut aussi faire cette suppression des anciennes éventuelles données à la fin juste avant l'insertion du tableau.

Code:

ThisWorkbook.Sheets("Feuil1").Range("B" & index_1_tablo_origine).Resize(1, UBound(tablo_sortie(index_1_tablo_origine), 1) + 1).clear
19/02/2025, 17h03
tototiti2008

Re,

Tu veux dire que j'aurais dû mettre plus de colonnes ? du type

Code:

ThisWorkbook.Sheets("Feuil1").Range("B1:Z1000").Clear

si ça dépasse 5 colonnes de résultat ?
19/02/2025, 17h05
tototiti2008

ou alors

Code:

ThisWorkbook.Sheets("Feuil1").Range("A1").currentregion.offset(0,1).Clear
19/02/2025, 17h06
Alex020181

Bon ;) je vais arrêter de spammer. Ce qui compte c'est que le demandeur comprenne le code et l'adapte comme il le souhaite.
27/02/2025, 02h46
Alex020181

Encore un cas de non retour. Sympa. Après on se demande pourquoi on aide de moins en moins...