procédure ou fonction commune à plusieurs UserForm

Version imprimable

Bonjour à tous,

Je vous contact aujourd'hui car j'aurai besoin de faire une manip un peut spécifique et je fais appel à vous pour m’aider.

Contexte

J'ai trois UserForm qui contiennent chacun une ListBox, cependant ils ne sont pas appelés pour la même raison.

Comment créer une procédure ou une fonction commune pour déterminer par exemple le nombre de colonnes, leur largeur … ou d’autres propriétés sans avoir à la répéter dans chaque propriétés des 3 UserForm ??

Bien sûr créer une procédure pour chaque UserForm, c’est une solution basique, mais je souhaiterai testé une procédure générique ou commune à tous les formulaire du projet.

Voici le code dans chaque Private Sub UserForm_Initialize :
Code:

1 2 MyUserform = "MyNameForm" … PropriétésListBoxUserForm
Et dans un module standard :
Code:

1 2 3 4 5 6 7 8 Public MyNameForm As String Sub PropriétésListBoxUserForm() MyNameForm.ListBox1.ColumnCount = 3 MyNameForm.ListBox1.ColumnWidths = "70;70;70" MyNameForm.Entetes.ColumnCount = 3 MyNameForm.Entetes.ColumnWidths = "70;70;70" End If End Sub
Mais lorsque je charge un des trois UserForm j’ai le message suivant :
”Erreur de compilation” Argument non facultatif

D’où vient l’erreur ?

Après de multiples essais et recherches je ne trouve pas de solution.

Merci d’avance pour votre aide.

Sincères salutations @+.

27/01/2025, 19h32
Nain porte koi

Hello,

je pense (pas sûr) que la réponse serait dans un module de classe
https://tissotemmanuel.developpez.co...les-de-classe/
28/01/2025, 08h28
Philippe Tulliez
Bonjour,
Comme en principe les propriétés ColumnCount et ColumnWidths dépendent de la liste des données, il est tout à fait possible de prévoir une procédure placée dans un module standard avec comme arguments l'objet ListBox ou ComboBox et l'objet Range (liste de données qui doit être affichée dans le ListBox ou ComboBox

Exemple pour les arguments
Code:

1 2 3 Sub LoadListBox(ctrlListBox As Object, ByVal ListRange As Range) ' Ici le code End Sub
28/01/2025, 10h53
modus57

Bonjour, :D:lun:

Merci pour vos réponses.

Nain porte koi je n’ai pas fait le test de passer par un module de classe, je ne suis pas certain que cela allégera le nombres de lignes de codes, si c’est pas le cas autant choisir une solution basique et créer une procédure pour chaque UserForm.

Mr TULLIEZ votre solution est plus intéressante mais je ne vois pas comment la mettre en œuvre avec un tableau structuré ?

Dans mon projet les trois UserForm contiennent chacun 1 ListBox (Entetes) pour les entêtes et 1 ListBox(ListBox1) pour les données ils sont appelés pour des raisons différentes.

La procédure commune doit définir les propriétés nombre et taille des colonnes des 2 ListBox au chargement de chaque UserForm.

Et récupérer dans la ListBox (Entetes) les noms de colonnes du tableau structuré avec cette ligne de code :

Code:

.entetes.List = Sheets("BDD").ListObjects(1).HeaderRowRange.Value

Si mes explication ne sont pas assez claires je peux joindre un classeur épuréde mon projet.

@+
28/01/2025, 11h18
Philippe Tulliez

Bonjour,
Je ne comprends pas trop que représente le ListBox pour les en-tête ?
On ne peux associer une ligne de titre à un ListBox ou ComboBox qu'à la seule condition d'utiliser la propriété RowSource de ces objets.
La solution que je peux proposer modifie les propriétés ColumnCount, ColumnWidths du ListBox défini par l'argument ctrlListBox et recalcule la propriété Width du UserForm où se trouve le ListBox ou ComboBox.
28/01/2025, 11h53
modus57

1 pièce(s) jointe(s)

Voici une petite explication.

La ListBox (Entetes) sert uniquement pour afficher les noms des colonnes du tableau structuré (Tableau1) voici le code en dur pour l’UserForm1 à l’initialisation :

Code:

Me.Entetes.List = Sheets("BDD").ListObjects(1).HeaderRowRange.Value

Cette ListBox(Entetes) et la ListBox1 ont les mêmes nombre et tailles de colonnes.

Pièce jointe 663933

J’utilise cette méthode qui me parait simple et plus intéressante à mettre en œuvre que des Labels ou TextBox à ajuster
pour les titres des colonnes de la Listbox1 ou la propriété ColumnHeads à True !

1 pièce(s) jointe(s)

Bonjour,

Voici une fonction générique qui fait le job

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub InitListBox(ctrlListBox As Object, _
                ByVal ListRange As Range, _
                Optional ResizeForm As Boolean = True)
  ' Author : Philippe Tulliez (https://magicoffice.be/)
  ' Initialisation du ListBox
  '  Modifie les propriétés suivantes du ListBox ou ComboBox
  '   ColumnCount
  '   ColumnWidths
  '   List
  '  Modifie la propriété Width du UserForm si ResizeForm est à True (Default)
  ' Arguments
  '   ctrListBox     : (ListBox) Ctrl ListBox à initialiser
  '   ListRange      : Liste traitée par le ListBox --> Propriété RowSource
  Dim tcol() As String, C As Long, tw As Double
  With ctrlListBox
  .List = ListRange.Value
  .ColumnCount = ListRange.Columns.Count ' Nombre de colonnes dans ListBox
   ReDim tcol(.ColumnCount - 1)
   ' Calcul largeur des colonnes et le place dans un string
   For C = 1 To .ColumnCount
       tcol(C - 1) = CStr(ListRange.Cells(1, C).Width): tw = tw + tcol(C - 1)
   Next
  .ColumnWidths = Join(tcol, ";")
  .ListIndex = -1
   '
   DoEvents
   ' Rectifie la largeur du ListBox si ResizeForm = True (Default)
  .Width = tw + UBound(tcol) + 10
   If ResizeForm Then
   .Parent.Width = .Left + .Width + 30
   End If
  End With
End Sub

Exemple d'une procédure qui invoque InitListBox

Code:

1
2
3
4
5
6
7
8
9
10
11
Sub Main()
  Const TableName As String = "t_Data" ' Nom du tableau structuré
  Dim oRange As Range
  Set oRange = Range(TableName)
  With UserForm1
   InitListBox ctrlListBox:=.lst_Header, ListRange:=oRange.ListObject.HeaderRowRange, ResizeForm:=False
   InitListBox ctrlListBox:=.lst_Data, ListRange:=oRange, ResizeForm:=True
  .Show
  End With
  Set oRange = Nothing
End Sub

Illustration
Si l'on souhaite le redimensionnement automatique du UserForm par rapport à la largeur du ListBox, celui-ci doit être dans la partie gauche du UserForm sans autres contrôles à sa droite.
Pièce jointe 663939

Bonjour M. THULLIEZ,

Très bon boulot et bravo pour votre solution. :ccool:

J’ai finalement trouvé une solution très simple pour arriver au mon résultat souhaité.

Dans un module standard :
Code:

1 2 3 4 5 6 7 8 Sub PropriétésListBoxUSF(USF) USF.entetes.ColumnCount = 3 USF.entetes.ColumnWidths = "240;75;50" USF.ListBox1.ColumnCount = 3 USF.ListBox1.ColumnWidths = "240;75;50" 'entêtes ListBox USF.entetes.List = Sheets("Feuil1").ListObjects(1).HeaderRowRange.Value End Sub
Et dans chaque UserForm dans le module « Private Sub UserForm_Initialize() » :

Code:

Call PropriétésListBoxUSF(Me)

Ça fonctionne nickel chrome.

Merci pour votre contribution.

31/01/2025, 12h38
Philippe Tulliez

Bonjour,
C'est effectivement une solution plus courte mais moi, ce qui m'a toujours agacé c'est calculer la largeur des colonnes à afficher dans le ListBox ou ComboBox et donc avec ma fonction, le calcul est automatique et de plus la largeur du ListBox et du UserForm s'adapte automatiquement. J'ai d'ailleurs développé une fonction plus complète pour afficher ou pas certaines colonnes.
Cela me fait gagner un temps fou dans le développement.