Simplifier code VBA de 70 CommandButton

Version imprimable

1 pièce(s) jointe(s)

Bonjour à vous.

J’avais un fichier Word me permettant de suivre l'apprentissage de mes élèves que j'imprimai chaque année.
Disposant d'une tablette et le fichier étant existant, j’ai voulu ne plus imprimer le fichier et plutôt m'orienter vers une version numérique.
Pour cela, j'ai seulement ajouté 70 CommandButton dans le tableau avec des actions quand on clique dessus.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Private Sub CommandButton1_Click() If CommandButton1.Caption = "" Then CommandButton1.BackColor = &HFF8080 'violet CommandButton1.Caption = "ECA" ElseIf CommandButton1.Caption = "ECA" Then CommandButton1.BackColor = &H80FF80 'vert CommandButton1.Caption = "A" Else CommandButton1.BackColor = &H8000000F 'défault CommandButton1.Caption = "" End If End Sub
Ce fichier fonctionne très bien, mais si je souhaite modifier un élément, par exemple changer la couleur, je devrais le faire 40 fois.
J'ai regardé sur internet et j'ai trouvé des exemples avec des modules de classe, etc. mais plutôt orienter sur Excel avec des UF ce dont je ne dispose pas sur Word.
Du coup, je me tourne vers vous pour savoir s'il existe une solution ?

Voici un exemple de mon fichier de base.
Pièce jointe 658502

Merci d'avance pour votre aide.

Bonjour Xtr3m et bienvenue sur le forum,

Voici comment procéder en se basant sur ton fichier :

Créer un module de classe nommé Cls_CmdButton avec le code suivant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 
'objet contenant le CommandButton (et dont on va "intercepter" le Click
Private WithEvents m_o_btn As MSForms.CommandButton
 
'procédure permettant d'initialiser le CommandButton
Public Function InitButton(p_o_btn As MSForms.CommandButton) As Cls_CmdButton
    Set m_o_btn = p_o_btn
    Set InitButton = Me
End Function
 
'évènement Click du CommandButton
Private Sub m_o_btn_Click()
    With m_o_btn
        Select Case .Caption
            Case vbNullString
                .BackColor = &HFF8080       'violet
                .Caption = "ECA"
            Case "ECA"
                .BackColor = &H80FF80       'vert
                .Caption = "A"
            Case Else
                .BackColor = &H8000000F     'défault
                .Caption = vbNullString
        End Select
    End With
End Sub

Remplacer le code de ThisDocument par le suivant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Option Explicit
 
'collection contenant l'ensemble des boutons (objets Cls_CmdButton)
Private m_o_collBtns As VBA.Collection
 
'fonction permettant d'initialiser les boutons du document (ensemble des objets CommandButton)
Private Function InitBtns()
Dim l_o_ilShp As Word.InlineShape
Dim l_o_ctrl As Object
    If m_o_collBtns Is Nothing Then Set m_o_collBtns = New VBA.Collection
    For Each l_o_ilShp In ThisDocument.InlineShapes
        If l_o_ilShp.Type = wdInlineShapeOLEControlObject Then
            Set l_o_ctrl = l_o_ilShp.OLEFormat.Object
            If TypeName(l_o_ctrl) Like "CommandButton" Then
                With New Cls_CmdButton
                    m_o_collBtns.Add .InitButton(l_o_ctrl)
                End With
            End If
        End If
    Next
End Function
 
'à l'ouverture du document : initialiser les boutons
Private Sub Document_Open()
    InitBtns
End Sub

Ainsi, on parcoure l'ensemble des CommandButton une fois à l'ouverture du document pour les initialiser et on retrouve le même comportement que sur ton fichier original.

A+

29/08/2024, 21h14
Xtr3m

Bonjour mromain,

Merci c'est parfait. :D

Désolé d'avoir mis du temps pour te répondre mais j'ai d'abord essayé le code dans le fichier test que j'avais joint à ma demande puis je l'ai inséré dans le vrai fichier.
Et dans le vrai fichier le code fonctionne également parfaitement par contre comme j'ai un peu plus de 500 CommandButton cela coince.
J'ai de très grosses lenteurs et j'essayais de comprendre d’où ça venait.
Bien évidement, ce n'est pas ton code. Je pencherais plutôt pour un nombre excessif de CommandButton que le PC a du mal à "actualiser" lors du scroll des pages, à l'ouverture/fermeture et enregistrement.
Je vais regarder comment je peux alléger mon document.

J'ai toutefois une question, à quoi sert l'initialisation des CommandButton à l'ouverture du fichier ?

Encore merci de ton aide.

A+

1 pièce(s) jointe(s)

Bonjour Xtr3m, le forum,

Citation:

...j'ai un peu plus de 500 CommandButton cela coince.
J'ai de très grosses lenteurs et j'essayais de comprendre d'où ça venait.

Les lenteurs proviennent sûrement de ce nombre important de boutons.

Citation:

J'ai toutefois une question, à quoi sert l'initialisation des CommandButton à l'ouverture du fichier ?

Cela sert à "stocker en mémoire" chaque CommandButton pour pouvoir "capter ses évènements". (En me relisant, pas sûr que je sois très clair...)

Une piste consisterait à se passer des CommandButtons et à agir au clic-droit dans la cellule avec ce code dans le module ThisDocument :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Option Explicit
 
Private WithEvents m_o_wdApp As Word.Application
 
'à l'ouverture du classeur, garder en mémoire l'application Word dont on va "capter les évènements"
Private Sub Document_Open()
    Set m_o_wdApp = Application
End Sub
 
'au clic-droit dans l'application
Private Sub m_o_wdApp_WindowBeforeRightClick(ByVal Sel As Selection, Cancel As Boolean)
    If Sel.Type = wdSelectionIP Then                    'si la sélection est sur du texte
        If Sel.Range.Parent Is ThisDocument Then        'si le texte sélectionné apartient bien à ce document
            If Sel.Range.Tables.Count = 1 Then          'si le texte sélectionné appartient bien à une table
                If Sel.Range.Cells.Count = 1 Then       'si la sélection est sur qu'une cellule de la table
                    If (Sel.Range.Cells(1).RowIndex > 1) And (Sel.Range.Cells(1).ColumnIndex > 1) Then      'si la cellule sélectionnée n'est ni en première ligne ni en première colonne
                        ChangeCellValue Sel.Range.Cells(1)      'modifier la valeur de la cellule
                        Cancel = True                           'annuler l'affichage du menu "clic-droit"
                    End If
                End If
            End If
        End If
    End If
End Sub
 
'modifier la valeur d'une cellule
Private Sub ChangeCellValue(p_o_cell As Word.Cell)
    Select Case Left(p_o_cell.Range.Text, Len(p_o_cell.Range.Text) - 2)
        Case vbNullString
            p_o_cell.Shading.BackgroundPatternColor = &HFF8080      'violet
            p_o_cell.Range.Text = "ECA"
        Case "ECA"
            p_o_cell.Shading.BackgroundPatternColor = &H80FF80      'vert
            p_o_cell.Range.Text = "A"
        Case "A"
            p_o_cell.Shading.BackgroundPatternColorIndex = 0        'défault
            p_o_cell.Range.Text = vbNullString
    End Select
End Sub

Tu trouveras l'exemple ci-joint.
Cette solution fonctionne bien sur une utilisation classique de Word, mais peut-être ne fonctionnera-t-elle pas en mode tactile sur ta tablette.

A+

07/09/2024, 15h02
Xtr3m

Bonjour mromain,

Je te remercie une nouvelle fois pour ton aide et j'ai bien compris ton explication.

Malheureusement les fichiers au format docm ou xlsm ne peuvent etre lu sur une version mobile d'office que ce soit Android ou IOS.
Il me semble que c'est possible mais seulement sur les tablettes de Microsoft ou tu n'installes pas une version mobile d'office.

Il va donc falloir que je regarde ailleurs que sur Word pouf faire la même chose.

A+
30/09/2024, 21h34
Xtr3m

1 pièce(s) jointe(s)

Salut,

J'ai à nouveau besoin d'aide ;)
Il est vrai que je n'agis pas sur des CommandButton mais des CheckBox dans mon fichier joint mais c'est le fichier que j'avais sous la main et le principe est le même pour les 2 je pense non ?

Une partie du code est en place mais je sèche pour "intercepter" le type de contrôle qui est coché/décoché et agir en fonction de son nom.

Pouvez vous m'aider s'il vous plait ?

Pièce jointe 659936

1 pièce(s) jointe(s)

Bonjour Xtr3m, le forum,

Vu que ton besoin a un peu changé par rapport à ta demande initiale, tu trouveras ci-joint une autre approche.
Celle-ci se base sur le module de classe Cls_ControlsEvents dont le rôle est de "centraliser et renvoyer" les évènements Change des CheckBox et OptionButton du document.

Ainsi, pour ton nouveau problème où tu veux appliquer tel ou tel traitement en fonction du numéro de la CheckBox, il suffit d'adapter cette partie du code :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 'code qui se déclenche dès qu'un CheckBox change Private Sub oControlsEvents_CheckBoxChange(CheckBox As MSForms.CheckBox) Dim numCheckBox As Long 'récupérer le numéro de la CheckBox numCheckBox = Replace(CheckBox.Name, "CheckBox", vbNullString) If (numCheckBox >= 1) And (numCheckBox <= 8) Then 'mettre ici le code pour traiter les "CheckBox 1 à 8" CheckBox.Caption = IIf(CheckBox.Value, Format(Now, "mm/yyyy"), vbNullString) ElseIf (numCheckBox >= 9) And (numCheckBox <= 16) Then 'mettre ici le code pour traiter les "CheckBox 9 à 16" CheckBox.ForeColor = IIf(CheckBox.Value, 255, 0) End If End Sub
A+