concatener données dans combobox

Version imprimable

Bonjour,
j'aimerais concatener 2 colonnes d'une feuille Excel dans une combobox.

Je remplis ma combo de cette façon
Code dans ThisWorkbook
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Private Sub Workbook_activate() Dim wksChoixFact As Worksheet Dim cboSociete As MSForms.ComboBox Set wksChoixFact = Worksheets("Créationfacture") wksChoixFact.Activate Set cboSociete = wksChoixFact.OLEObjects("cboSociete").Object With cboSociete .Clear .List = Worksheets("Société").Range("C2:C24").Value .ListIndex = 0 End With End Sub
Comment concatener les 2 colonnes de la feuille dans .list
Merci d'avance

FikoU

05/08/2024, 14h27
BENNASR

solution d'un autodidacte
une colonne supplémentaire (cachée si nécessaire) ou tu concatène tes deux colonnes avec une espace au milieu et tu alimente ton combo depuis cette nouvelle colonne

Salut, tu pourrais créer un array et y stocker les valeurs concaténées, ensuite, tu affectes ces valeurs à .List.

[EDIT]
Comme j'avais un peu de temps et que je sais que l'utilisation de tableau n'est pas toujours évidente, je t'ai écrit la macro suivante:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Workbook_activate()
    Dim wksChoixFact As Worksheet
    Dim cboSociete As MSForms.ComboBox
    Dim wsSociete As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim combinedValues() As String
 
    Set wksChoixFact = Worksheets("Créationfacture")
    Set wsSociete = Worksheets("Société")
 
    wksChoixFact.Activate
 
    ' Déterminer le nombre de lignes non vides dans la colonne A
    lastRow = wsSociete.Cells(wsSociete.Rows.Count, "A").End(xlUp).Row
 
    ' Redimensionner le tableau des valeurs combinées
    ReDim combinedValues(1 To lastRow - 1)
 
    ' Concaténer les valeurs des colonnes A et B dans le tableau
    For i = 2 To lastRow
        combinedValues(i - 1) = wsSociete.Cells(i, 1).Value & " - " & wsSociete.Cells(i, 2).Value
    Next i
 
    ' Assigner les valeurs combinées à la combobox
    Set cboSociete = wksChoixFact.OLEObjects("cboSociete").Object
    With cboSociete
        .Clear
        .List = combinedValues
        .ListIndex = 0
    End With
End Sub

06/08/2024, 11h20
fikou

Bonjour,
Super merci,
Existe il un évenement sur le combo pour récupérer la valeur la ligne sélectionné ?

Merci
FikoU
06/08/2024, 12h13
Franc

Tu utilises la propriété .Value du combobox.
06/08/2024, 15h05
fikou

Oui bien sur, j'ai posté trop vite je cherchais au mauvais endroit.
Evenement "click" de la feuille concernée
Merci beaucoup tout est ok
FikoU