aide vba ouverture fichiers

Version imprimable

26/04/2024, 15h34
abc59

1 pièce(s) jointe(s)

aide vba ouverture fichiers

Bonjour

Je suis novice sur VBA et malgré les nombreuses heures à regarder les tutos et forum, je ne trouve pas ce dont j'ai besoin.

Je voudrais une macro pour ouvrir différents fichiers selon le critère de la colonne A = oui

donc si A = oui, il ouvre le fichier sinon il ne l'ouvre pas.

en B, c'est le chemin complet du fichier ( un concatener des autres cellules).
à partir de H c'est mon chemin découpé car il y a la date qui est en variable.

Savez vous comment je peux faire cela svp ?
je vais avoir en tout 50 fichiers paramétrés pour s'ouvrir

Merci par avance pour votre aide.

Pièce jointe 653859
27/04/2024, 17h53
Valtrase

Bonjour,
J'ai vu passer un post ou la demande n'était pas identique à celle-ci, Une plage était filtrée, les classeurs changeaient de non, et le chemin était différent.
Il est primordial de ne faire qu'une demande. Pour le bien de tous.
27/04/2024, 18h10
abc59

Citation:

Envoyé par Valtrase

Bonjour,
J'ai vu passer un post ou la demande n'était pas identique à celle-ci, Une plage était filtrée, les classeurs changeaient de non, et le chemin était différent.
Il est primordial de ne faire qu'une demande. Pour le bien de tous.

Bonjour
Je suis désolée mais je ne comprends pas votre message
Je demande de l aide car je ne trouve pas et vous me dites qu il y a déjà un autre message sur le sujet.
Si tel est le cas pouvez vous me donner le lien? Car pour ma part je ne l’ai pas vu et ce n est pas moi qui est mis 2 posts sur le même sujet.
27/04/2024, 18h19
Valtrase

Citation:

Je demande de l aide car je ne trouve pas et vous me dites qu il y a déjà un autre message sur le sujet.

C'est de vous cela non ?

https://www.developpez.net/forums/d2165380/logiciels/microsoft-office/excel/macros-vba-excel/aide-vba-lien-fichier-macro/

Là je me prépare pour une soirée détente , je regarde cela dès que possible. :lol:
27/04/2024, 18h56
abc59

Citation:

Envoyé par Valtrase

C'est de vous cela non ?

https://www.developpez.net/forums/d2165380/logiciels/microsoft-office/excel/macros-vba-excel/aide-vba-lien-fichier-macro/

Là je me prépare pour une soirée détente , je regarde cela dès que possible. :lol:

Oui cependant ce n est pas du tout la meme question.
Après peut être que c’est la même réponse … si tel est le cas je ne le sais pas d avance 😊

Bonjour à tous,
Peut-être avec quelque chose comme cela :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Private Sub ExportDatas(Optional ByVal SheetName As String, Optional ByVal Column As String, Optional ByRef Workbook As Excel.Workbook)
    If Workbook Is Nothing Then Set Workbook = ThisWorkbook
    If Column = vbNullString Then Column = "A"
    If SheetName = vbNullString Then SheetName = "Feuil1"
 
    On Error GoTo Catch
    Application.ScreenUpdating = False
 
    With Workbook
        Dim itemRange As Excel.Range
        For Each itemRange In .Worksheets(SheetName).Range(Column & "1:" & Column & .Worksheets(SheetName).Range(Column & Application.Rows.Count).End(xlUp).Row)
            If StrComp(itemRange.Value, "oui", vbTextCompare) = 0 Then
                If Dir(itemRange.Offset(0, 1).Value, vbNormal) > vbNullString Then
                    Dim itemWorkbook As Excel.Workbook
                    Set itemWorkbook = Workbooks.Open(itemRange.Offset(0, 1).Value)
                    With itemWorkbook
                        .Windows(1).Visible = False
                        'Todo " Faire quelque-chose."
                        Debug.Print .Worksheets("Feuil1").Range("A1").Value
                        .Close SaveChanges:=False
                        Set itemWorkbook = Nothing
                        Dim importCounter As Long
                        importCounter = importCounter + 1
                    End With
                Else
                    Debug.Print "Le fichier : " & itemRange.Offset(0, 1).Value & " est introuvable !"
                End If
            End If
        Next itemRange
        Debug.Print "-------------"
        Debug.Print "Importation terminée : " & importCounter & " Classeur" & IIf(importCounter > 1, "s ont été importés.", " a été importés.")
 
    End With
 
Catch:
    If Err.Number > 0 Then
    'Todo "Faire quelque chose."
        Debug.Print "Oupss... Nous avons rencontré une erreur : " & Err.Description
    End If
    Application.ScreenUpdating = True
End Sub

Pour l'appel avec les options par défaut : Ce classeur, Feuil1, colonne "A" :

Code:

1
2
3
Public Sub TestOuvrirClasseur()
       ExportDatas
End Sub

Avec un classeur ouvert et recherche sur la feuille 2 par exemple :

Code:

1
2
3
Public Sub TestOuvrirClasseur()
    ExportDatas "Feuil2", "B", Workbooks("Exemple1.xlsx")
End Sub

Ce n'est qu'un exemple et il doit être adapter à votre situation.
Dans le second exemple le classeur Exemple1 doit-être ouvert.