VBA - Récupérer plusieurs n° dans une même cellule

Version imprimable

01/02/2024, 18h31
chloe.secli

VBA - Récupérer plusieurs n° dans une même cellule

Bonjour à tous,
J'ai des cellules avec plusieurs numéros à récupérer. Elles ne sont pas toutes normées pareil. Juste mon n° commence toujours par "3600" et fait 10 caractères.
Exemple :
R-3600045367/GT/0//3600086536/A2A/0
3600045368/UJR///360008653/XE/360008654

Ce que je veux ressortir :
3600045367
3600086536
3600045368
3600086532
3600086541

Je ne sais pas à l'avance combien de fois j'ai de n° à trouver dans ma cellule, ça peut aller de 1 à 10 numéros à trouver.
Et je souhaite afficher le résultat avec un n° par ligne dans un autre onglet.
J'arrive avec la formule "Substitute" à savoir cb de n° je dois aller chercher dans ma cellule.
(Len(cellule) - Len(cellule, "3600", ""))) / 4
Mais après je suis bloquée pour découper ma cellule et afficher chaque n° ligne par ligne. Auriez vous une idée svp ?
Merci d'avance à vous
01/02/2024, 20h13
78chris

Bonjour
Voir Split pour découper selon les / et ensuite exploiter le tableau résultant
01/02/2024, 20h22
Jean-Philippe André

Salut,

ta formule n'est pas bonne, car si tu as un code 3600003600, ca n'est qu'une seule valeur :)

une idée ici serait les expressions regulières.

https://cafeine.developpez.com/access/tutoriel/regexp/

Salut, si ça peut t'aider, voici une solution vba, adapte selon tes besoins.
Le code parcourt le contenu des cellules par groupe de 10 caractères, si le groupe est numérique et commence par "3600" alors il est extrait et recopié dans un autre onglet.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub ExtractNumbers()
    Dim rng As Range
    Dim cell As Range
    Dim i As Integer
    Dim j As Integer
    Dim ws As Worksheet
    Dim str As String
    Dim num As String
 
    ' Définir la plage de cellules à analyser
    Set rng = ThisWorkbook.Sheets("Feuil1").Range("A1:A10") ' à adapter selon vos besoins
 
    ' Créer un nouvel onglet pour afficher les résultats
    Set ws = ThisWorkbook.Sheets.Add(After:=ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count))
    ws.Name = "Résultats"
 
    i = 1
 
    ' Parcourir chaque cellule de la plage
    For Each cell In rng
        str = cell.Value
 
        ' Parcourir chaque groupe de 10 caractères dans la cellule
        For j = 1 To Len(str) - 9
            num = Mid(str, j, 10)
 
            ' Vérifier si le groupe de 10 caractères est un nombre et commence par "3600"
            If IsNumeric(num) And Left(num, 4) = "3600" Then
                ' Si oui, écrire le numéro dans le nouvel onglet
                ws.Cells(i, 1).Value = num
                i = i + 1
            End If
        Next j
    Next cell
End Sub

02/02/2024, 18h12
chloe.secli

Bonjour à tous, génial merci beaucoup pour vos réponses, j'ai pu adapter le code et répondre totalement au besoin.
Bon week end à tous