[XSLT] Création d'une table html

Bonjour,

j'ai un fichier xml contenant un nombre d'enregistrements variable.
Je veux mettre en forme tout cela en passant par un xsl.

Je cherche donc à créer une table avec des balises <br> et <td>.
Comme il y a beaucoup d'éléments je ne ne souhaite pas tout afficher sur une seule ligne ou sur un colonne.
Je voudrais que tous les 5 éléments, une nouvelle ligne soit créée.

Pour le moment je procède la façon suivante :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 <xsl:for-each select ="PIC"> <xsl:choose> <xsl:when test="position() mod 5 =1"> <tr><td>debut</td> </xsl:when> <xsl:when test="position() mod 5 =0"> <td>fin</td></tr> </xsl:when> <xsl:otherwise> <td>milieu</td> </xsl:otherwise> </xsl:choose> </xsl:for-each>
Mais j'ai l'erreur suivante :
Erreur d'analyse XML : balise ne correspondant pas. Attendu : </tr>.

Je comprend bien qu'il faut fermer la balise, mais moi je veux la fermer après avoir ajouté mes autres colonnes...

Une idée ?

Bonjour,

Citation:

Envoyé par LeGars

Une idée ?

Oui, t'inspirer de ceci... ;)

Merci, c'est exactement ce dont j'avais besoin!
Voici la solution que j'ai retenu :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
 
<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
   <xsl:output method="html"/>
 
   <xsl:variable name="M" select="3"/> 
   <xsl:variable name="C" select="3"/> 
 
	<xsl:template match="/">
		<xsl:variable name="nb_lignes" select="ceiling(count(//fichier) div ($M * $C))"/>
		<html>
		  <body>
		  	<table border="1">
		  	  <xsl:call-template name="ligne">
		  	  	<xsl:with-param name="nb_lignes" select="$nb_lignes"/>
		  	  </xsl:call-template>
		  	</table>
		  </body>
		</html>
	</xsl:template>
 
	<xsl:template name="ligne">
		<xsl:param name="cpt_ligne" select="1"/>
		<xsl:param name="nb_lignes"/>
		<tr>
			<xsl:call-template name="colonne">
				<xsl:with-param name="cpt_ligne" select="$cpt_ligne"/>
			</xsl:call-template>
		</tr>
		<xsl:if test="$cpt_ligne &lt; $nb_lignes">
			<xsl:call-template name="ligne">
		    	<xsl:with-param name="cpt_ligne" select="$cpt_ligne + 1"/>
    	    	<xsl:with-param name="nb_lignes" select="$nb_lignes"/>
		  	</xsl:call-template>
		</xsl:if>
	</xsl:template>
 
	<xsl:template name="colonne">
		<xsl:param name="cpt_col" select="1"/>
		<xsl:param name="cpt_ligne"/>
		<td>
			<xsl:call-template name="cellule">
				<xsl:with-param name="cpt_ligne" select="$cpt_ligne"/>
				<xsl:with-param name="cpt_col" select="$cpt_col"/>
			</xsl:call-template>
		</td>
		<xsl:if test="$cpt_col &lt; $C">
			<xsl:call-template name="colonne">
				<xsl:with-param name="cpt_col" select="$cpt_col + 1"/>
				<xsl:with-param name="cpt_ligne" select="$cpt_ligne"/>				
			</xsl:call-template>
		</xsl:if>
	</xsl:template>
 
	<xsl:template name="cellule">
		<xsl:param name="cpt_ligne"/>
		<xsl:param name="cpt_col"/>
		<xsl:param name="cpt_valeur" select="1"/>
		<xsl:value-of select="//fichier[position()= $M * $C * ($cpt_ligne - 1) + $M * ($cpt_col - 1) + $cpt_valeur]/@nom"/>
		<xsl:if test="$cpt_valeur &lt; $M">
			<xsl:call-template name="cellule">
				<xsl:with-param name="cpt_col" select="$cpt_col"/>
				<xsl:with-param name="cpt_ligne" select="$cpt_ligne"/>				
				<xsl:with-param name="cpt_valeur" select="$cpt_valeur + 1"/>
			</xsl:call-template>
		</xsl:if>
	</xsl:template>
 
</xsl:stylesheet>