Macro "Control nom capteurs"

Version imprimable

03/05/2023, 00h00
Max-du-56

1 pièce(s) jointe(s)

Macro "Control nom capteurs"

Bonjour,

Je vous solicite car j'ai cette problématique (Photo en pièce jointe):

une colonne A comprenant des noms d'outils EL1, EL2 et EL3
une colonne B comprenant le(s) capteur(s) de l'outil
En principe, le capteur comprend le nom de l'outil présent à sa gauche (ex:l'outil EL3 dispose de 4 capteurs BR_EL, CR_EL3, ZAC_EL3 & ZA_EL3)

J'ai surligné en jaune 3 capteurs n'ayant pas de nom adéquat. Il me faudrait une macro qui indique en colonne C si le nom est OK où NOK.

Pourriez-vous m'aider ? J'espère avoir été le plus clair possible.

Merci d'avance.

Pièce jointe 638170

Salut, voici une macro qui fait le job:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Verification()
    Dim lastRow As Long
    lastRow = Cells(Rows.Count, "A").End(xlUp).Row ' Trouver la dernière ligne de la colonne A
    Dim i As Long
    For i = 2 To lastRow ' Boucler sur toutes les lignes de la colonne A à partir de la ligne 2
        If Not IsEmpty(Cells(i, "A")) Then ' Vérifier que la cellule en colonne A n'est pas vide
            Dim valeur As String
            valeur = Cells(i, "A").Value ' Récupérer la valeur de la cellule en colonne A
            Dim j As Long
            For j = 0 To 3 ' Boucler sur les 4 cellules en colonne B à côté de la cellule en colonne A
                Dim cell As Range
                Set cell = Cells(i + j, "B")
                If cell.Value Like "*" & valeur Then ' Vérifier si la valeur de la cellule en colonne B se termine par la valeur de la cellule en colonne A
                    cell.Offset(0, 1).Value = "OK" ' Afficher "OK" dans la cellule en colonne C à côté de la cellule en colonne B
                Else
                    cell.Offset(0, 1).Value = "NOK" ' Afficher "NOK" dans la cellule en colonne C à côté de la cellule en colonne B
                End If
            Next j
        End If
    Next i
End Sub

03/05/2023, 06h45
Philippe Tulliez

Bonjour,
Vous avez oublié de préciser si les cellules de la colonne A étaient fusionnées ou si certaines étaient vides ce qui change complètement la manière d'aborder le code

Hello,
A noter qu'en VBA on peut avoir la valeur d'une cellule fusionnée en utilisant MergeArea.Cells(1,1) qui va chercher la valeur dans la première cellule des cellules fusionnées.
Ainsi le code de Franc peut se réduire à :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 Sub Verification2() Dim i As Long, lastRow As Long Dim NomOutil As String, CapteurOutil As String lastRow = Cells(Rows.Count, "B").End(xlUp).row For i = 2 To lastRow NomOutil = Range("A" & CStr(i)).MergeArea.Cells(1, 1).Value CapteurOutil = Range("B" & CStr(i)).Value If CapteurOutil Like "*" & NomOutil Then Range("C" & CStr(i)).Value = "OK" Else Range("C" & CStr(i)).Value = "NOK" End If Next i End Sub
A noter que je vais chercher la dernière ligne dans la colonne B car dans la colonne A avec les cellules fusionnées elle est fausse.
L'utilisation de cellules fusionnées n'est pas une bonne chose car elle peut empêcher l'emploi de formules qui aurait pu être dans le cas présent quelque chose comme :

Citation:

=ESTNUM(CHERCHE(A2;B2;NBCAR(B2)-NBCAR(A2)+1))

Ami calmant, J.P

Bonjour,
Personnellement, j'utilise la propriété CurrentRegion pour connaître la plage de cellules à traiter
Mon approche était celle-ci au cas où l'une des cellules de la colonne A ne serait pas fusionnée contrairement aux autres.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub T()
  Dim rng As Range
  Dim r As Long
  Dim v1 As String, v2 As String
  Set rng = ActiveSheet.Range("A1").CurrentRegion
  With rng
    For r = 2 To .Rows.Count
     If .Cells(r, 1).MergeCells Then
        v1 = .Cells(r, 1).MergeArea.Cells(1, 1).Value
      Else
        v1 = .Cells(r, 1).Value
     End If
      v2 = .Cells(r, 2).Value
     .Cells(r, 3).Value = IIf(Right(v2, Len(v1)) <> v1, "NOK", "OK")
    Next
    Set rng = Nothing
  End With
End Sub

03/05/2023, 10h07
Max-du-56

Bonjour à tous,

Tout d'abord, merci pour votre aide :bravo:

J'ai utilisé la solution de Franc.

Les cellules de la colonnes A étaient bien fusionnées.

Bonne journée à tous :)
03/05/2023, 10h52
jurassic pork

Citation:

Envoyé par Max-du-56

J'ai utilisé la solution de Franc.

Attention la solution de Franc ne fonctionne pas si il n'y pas exactement 4 lignes capteur par outil.
03/05/2023, 11h16
Max-du-56

Effectivement, la solution de franc ne contrôle que 4 cellules.

A partir de la cinquième cellule de la colonne B, le contrôle n'est plus fait.

Afin de le pas perdre trop de temps, j'ai augmenté l'index afin de contrôler jusqu'à 16 cellules par élément.

ça n'est pas une bonne solution pérenne mais cela convient pour l'unique fichier que j'ai à contrôler.
03/05/2023, 11h23
jurassic pork

Ma solution et la solution à Philippe qui est encore plus universelle fonctionnent quelque soit le nombre de lignes de capteur par outil ( au moins 1 quand même)
03/05/2023, 21h28
Valtrase

Salut le fil,
Et avec une formule en C2 que tu recopie vers le bas

Code:

=SI(DROITE(B2;NBCAR(B2)-TROUVE("_";B2))=$A$1;"Ok";"No OK")