Traitement multilignes dans une cellule

Version imprimable

26/01/2023, 10h24
edgarrd

Traitement multilignes dans une cellule

Hello à tous,

Tout d'abord bonne année à ceux à qui je ne l'aurais pas souhaité !

J'aurais besoin de vos lumières (une fois de plus haha). Je dispose d'un fichier excel composé de la façon suivante:
En cellule A1:
- Appeler client,
- Relancer Client,
- Contrôle factures.

En cellule B1:
- terminée,
- en cours,
- terminée.

Je ne parviens pas à coder quelque chose en VBA me permettant de faire:
Si en cellule B1, l'action terminée est en Ligne 1 alors la supprimé ET supprimé l'action correspondante en A1.
Ce qui dans l'exemple ci-dessus donnerait le résultat suivant:
Cellule A1:
- Relancer client;

Cellule B1:
- en cours.

A cet instant j'ai juste un code qui me permets d'identifier la ligne ou se trouver l'action terminé, mais je n'arrive pas à coder le "rends-toi en cellule A1 et ligne identifié et supprime cette ligne...

Si vous avez une astuce je suis preneur.

Merci et bonne journée.
Edgard

Bonjour,

Lorsque vous supprimez des lignes d'une plage identifiée, il faut commencer par la fin sinon vous allez dans le mur. Je propose la solution suivante (je pars du principe qu'il y a un en-tête de colonne et que les données commencents à la plage A2, sinon, ajustez.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 Sub supr_lignes_fin() With ThisWorkbook.Sheets("base") 'nom de la feuille à mettre ici à la place de base Dim x As Integer ' ou Long s'il y a vraiment bcp de lignes ' Step -1 indique qu'il doit compter à l'envers ' .end(xldown) renvoie à la dernière ligne de la plage ; .row renvoie le numéro de la ligne For x = .Range("A1").End(xlDown).Row To 2 Step -1 '2 s'il y a un en-tête de colonne, sinon 1 If .Range("B" & x) = "terminée" Then .Range("B" & x).EntireRow.Delete Next End With End Sub
Cordialement,

26/01/2023, 11h36
ONTAYG

Bonjour,

Je ne vais répondre à ta question, mais je te déconseille le multi-ligne dans une cellule Excel, c'est peut-être joli, mais pour du traitement c'est une horreur.

Je vais quand même te donner une piste.

Fait un split avec le - comme séparateur de ce qu'il y a dans la cellule, cela te crée un tableau de données et tu peux avoir la position de chaque élément. Ainsi tu pourras faire des tests.

ONTAYG

1 pièce(s) jointe(s)

Bonjour Lulah,
Je pense que ton code ne fonctionnera malheureusement pas (j'ai pas testé).
En effet, il y'a potentiellement 3 lignes dans la même cellule de ce que j'ai compris.
A priori donne quelque chose de ce goût là :

Pièce jointe 633187

Sinon il aurait été très bien dans le cas où il n'y aurait pas eu 3 lignes dans la même cellule :)
Citation:
Envoyé par Lulah
Bonjour,

Lorsque vous supprimez des lignes d'une plage identifiée, il faut commencer par la fin sinon vous allez dans le mur. Je propose la solution suivante (je pars du principe qu'il y a un en-tête de colonne et que les données commencents à la plage A2, sinon, ajustez.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 Sub supr_lignes_fin() With ThisWorkbook.Sheets("base") 'nom de la feuille à mettre ici à la place de base Dim x As Integer ' ou Long s'il y a vraiment bcp de lignes ' Step -1 indique qu'il doit compter à l'envers ' .end(xldown) renvoie à la dernière ligne de la plage ; .row renvoie le numéro de la ligne For x = .Range("A1").End(xlDown).Row To 2 Step -1 '2 s'il y a un en-tête de colonne, sinon 1 If .Range("B" & x) = "terminée" Then .Range("B" & x).EntireRow.Delete Next End With End Sub
Cordialement,

26/01/2023, 15h42
Flopai

Bonjour Edgarrd,
Je suis curieux de savoir comment tu as identifié la ligne ou ton action terminée se trouve dans la cellule?
Peux-tu m'indiquer comment tu as procédé ça pourra m'être utile un jour ?

Merci d'avance :)

Citation:

Envoyé par edgarrd

A cet instant j'ai juste un code qui me permets d'identifier la ligne ou se trouver l'action terminé, mais je n'arrive pas à coder le "rends-toi en cellule A1 et ligne identifié et supprime cette ligne...

Edgard
26/01/2023, 15h43
edgarrd

Hello,

Merci à tous pour votre précieux retour !

@ONTAYG: Oui, je sais, c'est une horreur de travailler avec ce genre de fichier mais pour l'instant le risque opérationnel lié à une modification dans ce sens est trop important.

@Lulah: yes; code testé et ne fonctionne pas car la problématique est que la date est comme @flopai l'a présenté...

Pour info, pour localiser la ligne à laquelle se trouve l'action "complete", j'ai utilisé la fonction split (critère de retour à la ligne avec vbLf) avec Lbunds and Ubunds et lenght.

Le code en détail est le suivant:

s = split(range("B2", vbLf)
maxc = 20 'pour les caractères
maxi = 20 'pour les interlinges

for i = Lbound(s) to Ubund(s)
if len(s(i)) < maxc then

maxi = i

msgbox "La phare la plus longue est :" & s(maxc) & vbLf & "en ligne : " & maxi +IIf(Lbunds(s)+ 0,1,0) & "nb caractères " & maxc

En fait ce code récupère l'emplacement du mot (ou la phrase) ayant le plus petit nombre de caractère.

Merci
26/01/2023, 16h13
Lulah

Citation:

Envoyé par Flopai

Bonjour Lulah,
Je pense que ton code ne fonctionnera malheureusement pas (j'ai pas testé).
En effet, il y'a potentiellement 3 lignes dans la même cellule de ce que j'ai compris.
A priori donne quelque chose de ce goût là :

Pièce jointe 633187

Sinon il aurait été très bien dans le cas où il n'y aurait pas eu 3 lignes dans la même cellule :)

Bonjour,

Oui autant pour moi je n'avais pas bien compris la problématique de départ! Merci pour la correction.
26/01/2023, 17h21
edgarrd

Aucun souci, c'est déjà cool d'avoir essayé de m'aider:D
27/01/2023, 10h29
edgarrd

Hello,

Rahhh j'y arrive pas...Un petit coup de pouce svp :oops:

Merci

1 pièce(s) jointe(s)

Salut Edgarrd,

Citation:

Envoyé par edgarrd

Hello,

Le code en détail est le suivant:

s = split(range("B2", vbLf)
maxc = 20 'pour les caractères
maxi = 20 'pour les interlinges

for i = Lbound(s) to Ubund(s)
if len(s(i)) < maxc then

maxi = i

Merci pour le code.
J'ai noté quelques erreurs de syntaxe, impossible à compiler en l'état.
J'ai fait quelques modifications (i.e : Ubund => Ubound)
Je ne suis pas certains d'avoir compris si tu souhaites supprimer l'ensemble de la ligne si le couple "Appeler client" / "terminée" sont alignée dans les "sous-lignes" des colonnes A & B d'une même ligne.
Si c'est le cas et que ta syntaxe est rigoureusement la même je pense que c'est faisable.
Très concrètement, ce que je crois comprendre c'est que tu souhaites supprimer la ligne ou apparait "OK" dans la colonne C de ma capture d'écran infra.
Est-ce bien ça?
Si c'est bien le cas je pense que tu peux adapter le code que tu trouvera plus bas pour qu'il supprime la ligne au lieu d'écrire "Ok" ou "Ko" dans la colonne C.

Pièce jointe 633228
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 Option Base 0 Sub Test() Dim s As Variant Dim t As Variant Columns(3).ClearContents For i = 1 To 3 s = Split(Range("B" & i), vbLf) t = Split(Range("A" & i), vbLf) If (s(0) = "- terminée," And t(0) = "- Appeler client,") Then Range("C" & i).Value = "OK" Else: Range("C" & i).Value = "KO" End If Next i End Sub
En espérant que ça puisse aider.
Bien à toi

27/01/2023, 14h38
edgarrd

Bonjour Flopai,

Merci beaucoup pour ton retour. Oui désolé, j'ai écris le bout de code de mémoire et ne me suis pas relu :/
Pour reprendre ta capture d'écran, je veux que l'action relatif à son statut soit supprimé, si l'action est bien terminé. En résumé, dans ton encadré rouge il faudrait que le texte en rouge disparaisse totalement.
Tu penses que c'est jouable ?

Merci :)

Salut,

Pour faire simple, balance tes "lignes" dans des collection, c'est autrement plus simple à manipuler que des tableaux.
Et histoire que ce soit lisible et intelligible, on se fait des fonctions utilitaire:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Public Sub Test()
    Dim Wb As Excel.Workbook
    Set Wb = ThisWorkbook
 
    Dim Ws As Excel.Worksheet
    Set Ws = Wb.Worksheets("Feuil1")
 
    Dim Actions As Collection
    Set Actions = SplitCell(Ws.Range("A1"))
 
    Dim Status As Collection
    Set Status = SplitCell(Ws.Range("B1"))
 
    Dim i As Long
    For i = Actions.Count To 1 Step -1
        If (InStr(Status(i), "terminée") > 0) Then
            Actions.Remove i
            Status.Remove i
        End If
    Next
 
    Ws.Range("A1").Value = CollectionToString(Actions)
    Ws.Range("B1").Value = CollectionToString(Status)
End Sub
 
Private Function SplitCell(ByRef Rng As Excel.Range) As Collection
    Dim Data() As String
    Data = Split(Rng.Value, vbLf)
 
    Set SplitCell = ArrayToCollection(Data)
End Function
 
Private Function ArrayToCollection(ByRef Data As Variant) As Collection
    Dim Retour As Collection
    Set Retour = New Collection
 
    Dim i As Long
    For i = LBound(Data) To UBound(Data)
        Retour.Add Data(i)
    Next
    Set ArrayToCollection = Retour
End Function
 
Private Function CollectionToString(ByRef col As Collection) As String
    Dim Data As String
    Dim i As Long
    For i = 1 To col.Count
        Data = Data & col(i)
        If (i < col.Count) Then
            Data = Data & vbCrLf
        End If
    Next
    CollectionToString = Data
End Function

30/01/2023, 08h34
edgarrd

Hello,

Comment vous dire...Ca marche !
Je vais peut-être paraître ennuyeux mais pourrais-tu m'éclairer sur le code. Faire copier/coller c'est bien mais comprendre le code c'est mieux :oops:

Merci à Deedodlith pour son coup de lumière & à tous les autres pour votre aide (Flopai, Lulah, ONTAYG).

Belle semaine à tous
30/01/2023, 13h58
deedolith

Les fonctions parlent d'elle même:
SplitCell divise une châine en lignes et les retourne sous forme de collection.
ArrayToCollection transforme un tableau en collection.
CollectionToString concatène le contenu d'une collection en chaîne.

Quand à la fonction test, elle fait exactement ce que tu demandes:
Récupère le contenu des cellules sous forme de collection.
Retire les lignes indésirables.
Met à jour les cellules.

Exécute en pas à pas, et inspecte le contenu des variables avec des espions.
30/01/2023, 14h32
edgarrd

Merci beaucoup pour le retour.
Je vais tenter de modifier le code pour que ce dernier s'applique à la colonne A et B en entier :)
31/01/2023, 12h12
edgarrd

Hello à tous

@deedolith: le code fonctionne parfaitement à l'exception près que je constate un petit décallage à chaque fois dans la celulle. As-tu aussi constaté cela (exemple, si je fais plusieurs execution de macro à la suite, mon texte à gauche fini au milieu de la cellule).

Merci beaucoup.
01/02/2023, 00h23
deedolith

Je split sur vbLf et concatène sur vbCrLf,
ca doit être à cause de ca.