[REQ] macro excel pour nommer ou actualiser les plages de données

Version imprimable

03/11/2022, 11h10
fbaux

1 pièce(s) jointe(s)

[REQ] macro excel pour nommer ou actualiser les plages de données

Bonjour à tous,
j'aimerai nommer ou actualiser des noms de plages via une macro dans un onglet dédié 'range_namer'
dans cet onglet 'range_namer' :
1er colonne range
2nd colonne range_name

range range_name
Feuil1!B25:W25 Feuil1!A1
Feuil1!B25:W26 Feuil1!A2
Feuil1!B25:W27 Feuil1!A3
Feuil1!B25:W28 Feuil1!A4
Feuil1!B25:W29 Feuil1!A5
Feuil1!B25:W30 Feuil1!A6
Feuil1!B25:W31 Feuil1!A7
Feuil1!B25:W32 Feuil1!A8
Feuil1!B25:W33 Feuil1!A9

les plages en ligne sont créées ou actualisées suivant cet inventaire sur cet onglet :-)

Est-ce possible?

En vous remerciant d'avance
03/11/2022, 11h30
deedolith

Salut,

Ce n'est pas clair.
Ce que contient la colonne range_name ressemble plus à des référence de cellule que des nom, ce qui apporte de la confusion (dangereux).

De plus, récupérer des nom, et mettre à jour des noms, ce n'est pas du tout la même chose, dans ce cas, il te faudra 2 fonctions.

Que souhaites-tu faire exactement ?
03/11/2022, 13h20
fbaux

Bonjour deedolith, merci pour votre réponse,
je clarifie,
dans la 2nde colonne range_name, on trouve une adresse de cellule, le contenu de cette cellule est le nom de la plage (définie dans la colonne1)
valeur de Feuil1!A1 ex toto donne son nom à la plage Feuil1!B25:W25
=>toto est Feuil1!B25:W25.

mon besoin :
- je crée cette cartographie (via cet inventaire) est les plages de noms sont créées via la macro. (non créé si existante)

si c'est plus simple, on peut avoir une 2nd fonction pour supprimer toutes les plages et les recréer (peut être plus simple que mettre à jour un plage existante)

Merci d'avance

1 pièce(s) jointe(s)

Bonjour
la bonne méthode est souvent de commencer par faire à la main en enregistrant une macro pour récupérer les bons objets etc. Ça donne :
Code:

1 2 3 4 5 6 'création du nom "toto" sur Feuil1!A1 ActiveWorkbook.Names.Add Name:="toto", RefersToR1C1:="=Feuil1!R1C1" 'modification du nom "toto" vers Feuil1!A2 ActiveWorkbook.Names("toto").RefersToR1C1 = "=Feuil1!R2C1" 'suppression du nom toto ActiveWorkbook.Names("toto").Delete
Vu ce que tu as commencé à faire ça sera plus simple d'utiliser RefersTo plutôt que FefersToR1C1

Pièce jointe 628313

Reste à adapter au contexte et mettre autour la boucle qui va bien pour lire ton paramétrage. Tu as besoin d'aide aussi là dessus ?

1 pièce(s) jointe(s)

@Tête de chat:
Ça c'est la méthode sous-débutant, et le résultat est complétement pourri !! (ta première erreur s'appelle ActiveWorkbook)
Au mieux, ça peut servir d'inspiration (et encore, à prendre avec des pincettes).

@fbaux:
Voici le code que tu recherches, j'ai commencé par ajouter un tableau structuré, c'est plus facile à manipuler qu'une plage de cellules arbitraires:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
Option Explicit
 
Public Sub SetRangeNames()
    Dim Wb As Excel.Workbook
    Set Wb = ThisWorkbook
 
    Dim Ws As Excel.Worksheet
    Set Ws = Wb.Worksheets("range namer")
 
    Dim RangeNames As Excel.Range
    Set RangeNames = Ws.Range("RangeNames")
 
    Dim Row As Excel.Range
    For Each Row In RangeNames.Rows
        Dim Name As String
        Name = Row.Cells(2).Value
 
        Dim RefersTo As String
        RefersTo = Row.Cells(1)
 
        On Error GoTo Error
        If Not (ExistInCollection(Name, Wb.Names)) Then
            Wb.Names.Add Name:=Name, RefersTo:=RefersTo
        Else
            Wb.Names(Name).RefersTo = RefersTo
        End If
        On Error GoTo 0
    Next
Exit Sub
Error:
    Row.Cells(2).Select
    MsgBox Err.Description, vbOKOnly + vbCritical, "Erreur d'execution"
End Sub
 
Public Function ExistInCollection(ByVal Key As String, ByRef Col As Object) As Boolean
    ExistInCollection = ExistInCollectionByVal(Key, Col) Or ExistInCollectionByRef(Key, Col)
End Function
 
Private Function ExistInCollectionByVal(ByVal Key As String, ByRef Col As Object) As Boolean
On Error GoTo Error
    Dim Item As Variant
    Item = Col(Key)
    ExistInCollectionByVal = True
Exit Function
Error:
    ExistInCollectionByVal = False
End Function
 
Private Function ExistInCollectionByRef(ByVal Key As String, ByRef Col As Object) As Boolean
On Error GoTo Error
    Dim Item As Variant
    Set Item = Col(Key)
    ExistInCollectionByRef = True
Exit Function
Error:
    ExistInCollectionByRef = False
End Function

Et ci joint le classeur complet:
Pièce jointe 628319
Il ne te reste plus qu'à appeler la macro, et Il y a une surprise (je te laisse la découvrir).

03/11/2022, 15h16
Tête de chat

@deedolith

Citation:

Ça c'est la méthode sous-débutant, et le résultat est complétement pourri

??? je t'ai fait du mal dans une vie antérieure à l'insu de mon plein gré ? :weird:

J'essayais d'amener fbaux progressivement vers la solution, mais si tu préfères lui donner du poisson plutôt que lui apprendre à pêcher :)

Alors de sous-débutant à sous-débutant, je crois que tu as zappé que la colonne 1 contient l'adresse du nom et pas le nom, sauf erreur de ma part (mais en tant que sous-débutant je plaide l'indulgence) ton code ne gère pas la modification comme demandé, la gestion d'erreur ne donne ni la ligne ni l'erreur (préférer un on error resume, et par exemple porter l'erreur en colonne 3 et continuer l'exécution) et j'en passe... :mouarf:

Du coup je te laisse corriger tranquillement.
03/11/2022, 16h15
deedolith

@Tête de chat:
Tu as mal interprété, c'est la méthode que je fustige, pas la personne.

Relis le code posté, la colonne 1 est assignée à la variable RefersTo, la colonne 2 est assigné à la variable Nom (comme attendu).

La modification est gérée, relis le code encore une fois.

La cellule en erreur (si besoin) est sélectionnée, ce qui donne une première indication de la source du problème.
Une description de l'erreur est affichée (via MsgBox), ce qui donne une seconde indication.
Ajouter des indications supplémentaires en altérant le contenu de la feuille n'est pas demandé par l'OP.
Indiquer le N° de la ligne de code requiert de numéroter chaque ligne, ce qui est détrimentaire pour la maintenance (personne n'aime tout renuméroter suite au moindre ajout ou suppression).

Au final, il reste quoi à corriger ?

Ma réponse n'est pas pédagogique, je l'admet.
Quelque chose me dit que le niveau de l'OP est très faible, son premier réflexe devrait être de lire un bon tutoriel sur VBA, dans le cas contraire, il aurait fourni un code source (même maladroit).
Amener l'OP vers la solution, c'est très louable, encore faut-il le faire correctement, l'utilisation de ActiveWindow, ActiveWorkbook, ActiveSheet, ActiveCell, ActiveChart, ActivePrinter ou Selection est dangereuse. Sauf contexte particulier, les macros VBA ne doivent pas y avoir recours.

Quand à ton niveau, je ne le connais pas, tu ne connais pas le mien non plus.
Je ne t'ai pas jugé, je te prie de ne pas me juger.
04/11/2022, 21h06
fbaux

merci

Merci à tous les 2 j'apprécie beaucoup votre aide c'est super sympa.
05/11/2022, 08h44
Invité

Salut deedolith

Citation:

Envoyé par deedolith

@Tête de chat:
Tu as mal interprété, c'est la méthode que je fustige

Juste pou savoir, tu as commencé comment toi 🤔 tu n'as jamais utilisé l'enregistreur de macros... 😱😂
tu dois avoir un cerveau surdimensionné (ou peut-être un égo)
05/11/2022, 10h11
deedolith

Citation:

Envoyé par BrunoM45

Juste pou savoir, tu as commencé comment toi 🤔 tu n'as jamais utilisé l'enregistreur de macros... 😱😂

Comme source d'inspiration uniquement (c'est ce que j'ai mentionné plus haut).
Je n'ai jamais fait confiance à l'enregistreur de macro.

Citation:

Envoyé par BrunoM45

tu dois avoir un cerveau surdimensionné (ou peut-être un égo)

Tu ne sembles pas au courant, il existe des boutiques qui vendent de curieux objets multicouche. On y apprend plein de trucs quand on les ouvres.
L'un d'entre eux était intitulé Visual Basic 6.