Liste de recherche VBA

Version imprimable

Voir 40 message(s) de cette discussion en une page

04/10/2022, 20h54
VincentCA

1 pièce(s) jointe(s)

Liste de recherche VBA

Bonjour,

Novice en macro et code VBA, je souhaiterais un peu d'aide sur ce forum.
Dans la feuille de calcul en PJ, la colonne A représente la valeur a rechercher.
La colonne B est la valeur attitrée a la valeur recherchée.
En dessous les affections de chaque valeur attitrée.
Exemple eck = box 1 si valeur recherchée aaaaa

Est il possible avec un code VBA de créer une fenêtre où l'on viendrai flasher un code barre. Celui ci serait reconnu a sa même valeur de la colonne A. Puis en fonction de la valeur attitrée en B, renverra un message box "box numéro..."

Merci de votre aide,

1 pièce(s) jointe(s)

Bonjour vincent, la forum
flasher un code dépasse mes connaissance
mais un simple recherche avec VBA tu peux procéder ainsi :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test()
 Dim Code As Range, magasin As Range, y As Range, F1 As Worksheet
 Dim CodeArechercher As String
   Set F1 = Sheets("Feuille 1")
   Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row)
   Set magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row)
   CodeArechercher = InputBox("Indiquez le code de l'article à rechercher", "saisir un Code", "saisir un code svp") '
   Set c = Code.Find(CodeArechercher, LookIn:=xlValues, lookat:=xlWhole)
If Not c Is Nothing Then
Article = F1.Cells(c.Row, 2)
Set CodeMagasin = magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole)
MsgBox F1.Cells(CodeMagasin.Row, 5)
End If
End Sub

j'espère que ça t'aide à avancer dans ton projet

05/10/2022, 18h35
VincentCA

Merci pour cette réponse rapide et efficace.
Après réflexion et test, serait il possible de s'acquitter des validations en appuyant sur Entrée.
Exemple :
Après avoir appuyé sur GO, nous saisissons un code. Pouvons nous supprimons le OK avec une TAB. Puis à l'apparition du message box n°, ne pas appuyer sur OK mais une temporisation du message 3s par exemple ?

2 pièce(s) jointe(s)

Hello,

Citation:

Envoyé par VincentCA

Est il possible avec un code VBA de créer une fenêtre où l'on viendrai flasher un code barre.

Avec une "douchette" ?
Pour réaliser ce que tu veux faire, un formulaire serait plus adéquat :
voici ce que je te propose :
Un formulaire qui :

Reçoit le code barre dans un champ texte
Quand dans ce champ on reçoit un caractère de fin (ex 13 = Return, ce qu'une douchette doit pouvoir faire) la recherche est effectuée dans le classeur.
Le résultat est affiché dans le champ de Box. Si la recherche est infructueuse c'est aussi indiqué dans le champ Box
Une temporisation réglable permet de maintenir le contenu des champs pendant un certain nombre de secondes. Ensuite les champs sont effacés et le focus est mis sur le champ de code barre pour permettre la saisie suivante.
Un bouton permet d'effacer le contenu des champs.

Voici le code du formulaire qui reprend une partie du code de BENNASR :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 Private Sub CodeBarre_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer) If KeyCode = vbKeyReturn Then If CodeBarre.Text <> "" Then Recherche (CodeBarre.Text) End If End If End Sub Sub Recherche(CodeARechercher As String) Dim Code As Range, Magasin As Range, F1 As Worksheet, c As Range, m As Range Set F1 = Sheets("Feuille 1") Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row) Set Magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row) Set c = Code.Find(CodeARechercher, LookIn:=xlValues, lookat:=xlWhole) If Not c Is Nothing Then Article = c.Cells.Offset(0, 1) Set m = Magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole) If Not m Is Nothing Then Box.Text = m.Cells.Offset(0, 1) Delai CInt(Tempo.Text) Box.Text = "" CodeBarre.Text = "" CodeBarre.SetFocus Else Box.Text = "Magasin non trouvé" End If Else Box.Text = "Code non trouvé" End If End Sub Private Sub CmdRAZ_Click() CodeBarre.Text = "" Box.Text = "" End Sub
L'utilisation de plages nommées serait préférable pour éviter d'être obligé de modifier le code en cas de changement d'implantation des données dans le classeur.

Voici le code du module Basic où il y a la macro d'ouverture du formulaire et une procédure de temporisation.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 #If VBA7 Then Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) #Else Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) #End If Sub test() UserForm1.Show End Sub Sub Delai(s As Integer) Dim TimeOut As Single TimeOut = Timer + s Do While Timer < TimeOut DoEvents Sleep 10 ' tempo de 10 ms pour éviter charge CPU excessive Loop End Sub
Pièce jointe 626739

En pièce jointe le classeur de test.

Ami calmant, J.P

06/10/2022, 20h47
VincentCA

Rhooo merci beaucoup pour cette superbe avancée.
J'ai testé aujourd'hui et ça fonctionne plutôt bien.

"Le résultat est affiché dans le champ de Box. Si la recherche est infructueuse c'est aussi indiqué dans le champ Box" =>serait il possible que tout comme un résultat conforme, ça renvoie automatiquement à la lecture d'un nouveau code après temporisation (dans les cas magasin ou code non trouvé).

En colonne C, est il possible de mentionner le résultat de la box trouvée après chaque recherche ?

Merci encore énormément

Hello,

Citation:

Envoyé par VincentCA

"Le résultat est affiché dans le champ de Box. Si la recherche est infructueuse c'est aussi indiqué dans le champ Box" =>serait il possible que tout comme un résultat conforme, ça renvoie automatiquement à la lecture d'un nouveau code après temporisation (dans les cas magasin ou code non trouvé).
En colonne C, est il possible de mentionner le résultat de la box trouvée après chaque recherche ?

ce code devrait faire l'affaire :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Recherche(CodeARechercher As String)
 Dim Code As Range, Magasin As Range, F1 As Worksheet, c As Range, m As Range
   Set F1 = Sheets("Feuille 1")
   Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row)
   Set Magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row)
   Set c = Code.Find(CodeARechercher, LookIn:=xlValues, lookat:=xlWhole)
   If Not c Is Nothing Then
        Article = c.Cells.Offset(0, 1)
        Set m = Magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole)
        If Not m Is Nothing Then
            Box.Text = m.Cells.Offset(0, 1)
            c.Cells.Offset(0, 2) = m.Cells.Offset(0, 1)
        Else
            Box.Text = "Magasin non trouvé"
        End If
   Else
        Box.Text = "Code non trouvé"
   End If
   Delai CInt(Tempo.Text)
   Box.Text = ""
   CodeBarre.Text = ""
   CodeBarre.SetFocus
End Sub

Ami calmant, J.P

12/10/2022, 20h28
VincentCA

Bonsoir,
Une fois de plus, merci pour cette précieuse aide.
Serait il possible de faire évoluer le code afin que le numéro de la box s'affiche en grand (j'entends par là, la quasi totalité de l'écran) laissant juste un peu de place pour le réglage de la temporisation et la lecture du code barre.
En utilisant le mode zoom du code formulaire, j'ai pu agrandir la fenêtre mais je n'arrive pas à modifier la taille du texte à l'intérieur de la box.
Sinon, tout marche vraiment nikel.

Autre question, serait il possible sur une deuxième feuille de charger un fichier txt (qui s'ouvre sur bloc note) à partir d'une macro pour charger direct le fichier ? Puis la feuille 1 récupérerait les données nécessaire sur les colonne A et B pour faire fonctionner la macro go

Merci, merci
Bonne soirée.
13/10/2022, 07h20
jurassic pork

Hello,

Citation:

Envoyé par VincentCA

Serait il possible de faire évoluer le code afin que le numéro de la box s'affiche en grand (j'entends par là, la quasi totalité de l'écran) laissant juste un peu de place pour le réglage de la temporisation et la lecture du code barre.

Le mieux c'est d'afficher le contenu du champ Box dans une autre fenêtre de dialogue (en mode non modal). Pourquoi sur la quasi totalité de l'écran, ça fait très gros ? . C'est pour lire à distance ? Le périphérique est une tablette ?
Dans le cas où l'on utilise une deuxième fenêtre de dialogue : où placer la première (en haut en bas à droite à gauche en dessous ? ou fenêtre semi transparente ? )

Citation:

Envoyé par VincentCA

Autre question, serait il possible sur une deuxième feuille de charger un fichier txt (qui s'ouvre sur bloc note) à partir d'une macro pour charger direct le fichier ? Puis la feuille 1 récupérerait les données nécessaire sur les colonne A et B pour faire fonctionner la macro go

:cristal: Je ne comprends pas trop -> qu'y a t il dans le fichier texte ?

Ami calmant, J.P
13/10/2022, 16h28
VincentCA

1 pièce(s) jointe(s)

Citation:

Envoyé par jurassic pork

Hello,

Le mieux c'est d'afficher le contenu du champ Box dans une autre fenêtre de dialogue (en mode non modal). Pourquoi sur la quasi totalité de l'écran, ça fait très gros ? . C'est pour lire à distance ? Le périphérique est une tablette ?
Dans le cas où l'on utilise une deuxième fenêtre de dialogue : où placer la première (en haut en bas à droite à gauche en dessous ? ou fenêtre semi transparente ? )

Peut être pas la quasi totalité de l'écran mais un chiffre en très gros. L'idée est que sur un écran de PC, je visualise bien le numéro lorsque je flashe le code barre. Pourquoi pas un nouvel affichage rien que pour le numéro. Pas de tablette, juste un PC avec un écran mais le technicien n'est pas forcément proche de l'écran d'où une police de taille importante..
La meilleure possibilité est de placer la premiere fenetre de dialogue en haut à gauche et le numero sur la partie droite en assez gros.

:cristal: Je ne comprends pas trop -> qu'y a t il dans le fichier texte ? C'est un fichier texte avec des informations extraites à partir d'un logiciel d'entreprise. Je réalise une extraction sur mon logiciel d'entreprise que j'enregistre dans un fichier puis jusqu'à présent j'ouvre ce .txt avec bloc note. Je selectionne tout que je colle dans une feuille 2 sous excel. Puis je récupere les infos que je souhaite en colonne A et B de la feuille 1 à partir de la feuille et exécute le macro. L'idée c'est un bouton macro pour charger directement le txt et le copier automatique sur feuille 2. J'ai du anonymiser mon txt mais l'exemple est pareil. En PJ

MERCI

Ami calmant, J.P
14/10/2022, 15h17
VincentCA

Bonjour,

Quand je me relis, je sais pas trop si j'ai été clair, j'espère que oui !!!

Hello,
ton fichier texte est du type csv délimité TAB. Avec le code suivant tu devrais pouvoir l'importer dans la feuille Feuille 2 à partir de la cellule A1 du classeur actif :
Code:

1 2 3 4 5 6 7 8 9 Sub CSV_Import() Dim ws As Worksheet, strFile As String Set ws = ActiveWorkbook.Sheets("Feuille 2") 'set to current worksheet name With ws.QueryTables.Add(Connection:="TEXT;" & "D:\temp\Classeur1.txt", Destination:=ws.Range("A1")) .TextFileParseType = xlDelimited .TextFileCommaDelimiter = True .Refresh End With End Sub
Ami calmant, J.P

14/10/2022, 16h54
VincentCA

Il est donc possible de créer un bouton "charger les données_ et d'y affecter le code ci dessus pour charger les donnees a partir d'un fichier txt présent dans un dossier.
Le classeur doit il être dans le même répertoire dossier que le fichier .txt ?
16/10/2022, 22h51
VincentCA

Tout marche comme sur des roulettes, merci à tous pour votre précieuse aide dans la réalisation de cet outil.
Dernier détail, l'affichage de la double fenêtre pour un affichage plus gros du numéro de la box ?
Une idée ?

MERCI MERCI
17/10/2022, 10h48
jurassic pork

Hello,

Citation:

Envoyé par VincentCA

Dernier détail, l'affichage de la double fenêtre pour un affichage plus gros du numéro de la box ?

Il faut créer un deuxième formulaire (Userform) avec comme nom AffBox par exemple, mettre un label dedans avec une grosse police. Il faut l'afficher en mode non modal (.show 0) quand on affiche le formulaire principal. Il faut qu'il soit disposer en dessous ou au dessus du formulaire principal pour ne pas le recouvrir (jouer sur la propriété Top). Quand on affiche quelque chose dans le champ box, il faut aussi l'afficher dans le label de ce nouveau formulaire. Quand on ferme le formulaire principal, il faut décharger le formulaire (unload)
Ami calmant, J.P
17/10/2022, 12h02
VincentCA

Merci pour ces orientations.
Je doute pouvoir y arriver seul à coder mais je vais essayer sur la base du premier.
Ma plus grosse problématique, relier le premier au deuxième

1 pièce(s) jointe(s)

hello,
voici le code du premier formulaire sachant que le deuxième formulaire s'appelle AffBox avec un label LbBox

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
 
Private Sub UserForm_Initialize()
   AffBox.Show 0
End Sub
 
Private Sub CodeBarre_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
   If KeyCode = vbKeyReturn Then
           If CodeBarre.Text <> "" Then
              Recherche (CodeBarre.Text)
           End If
    End If
End Sub
 
Sub Recherche(CodeARechercher As String)
 Dim Code As Range, Magasin As Range, F1 As Worksheet, c As Range, m As Range
   Set F1 = Sheets("Feuille 1")
   Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row)
   Set Magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row)
   Set c = Code.Find(CodeARechercher, LookIn:=xlValues, lookat:=xlWhole)
   If Not c Is Nothing Then
        Article = c.Cells.Offset(0, 1)
        Set m = Magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole)
        If Not m Is Nothing Then
            Box.Text = m.Cells.Offset(0, 1)
            c.Cells.Offset(0, 2) = m.Cells.Offset(0, 1)
        Else
            Box.Text = "Magasin non trouvé"
        End If
   Else
        Box.Text = "Code non trouvé"
   End If
   AffBox.LbBox.Caption = Box.Text
   Delai CInt(Tempo.Text)
   Box.Text = ""
   AffBox.LbBox.Caption = Box.Text
   CodeBarre.Text = ""
   CodeBarre.SetFocus
End Sub
Private Sub CmdRAZ_Click()
CodeBarre.Text = ""
Box.Text = ""
AffBox.LbBox.Caption = ""
End Sub
 
Private Sub UserForm_Terminate()
Unload AffBox
End Sub

En pièce jointe le formulaire AffBox (taille de police , largeur hauteur à ajuster)

Ami calmant, J.P

18/10/2022, 12h08
VincentCA

Bonjour à tout le monde,

Encore une fois, il s'agit d'un code qui donne entière satisfaction et qui me permet de faire évoluer positivement mon macro.

Serait-il possible désormais que le numéro de la box qui s'affiche en label sur le formulaire aff box fasse l'objet d'une fonction "text to speech" pour dicter de façon optionnelle le résultat de la recherche ?

Merci beaucoup de votre aide,
Vincent
18/10/2022, 12h26
jurassic pork
Hello,

Citation:

Envoyé par VincentCA

Serait-il possible désormais que le numéro de la box qui s'affiche en label sur le formulaire aff box fasse l'objet d'une fonction "text to speech" pour dicter de façon optionnelle le résultat de la recherche ?

c'est tout simple il suffit d'utiliser la procédure Application.Speech.Speak
Exemple :
Code:

1 2 3 AffBox.LbBox.Caption = Box.Text Application.Speech.Speak Box.Text
Ami calmant, J.P
21/11/2022, 22h25
VincentCA

1 pièce(s) jointe(s)

Bonsoir et merci pour votre collaboration.
Je souhaiterais faire évoluer le macro d'une nouvelle fonctionnalité.
En colonne C des dates.
Lorsque je vais flasher les codes de la colonne A, les valeurs de la B s'afficheront telles le macro déjà codé.
Pourriez vous m'aider à faire évoluer mon code de telle sorte que lorsque nous changeons de date, un message s'affiche et stipule attention "changement de date". Si la date de la deuxième valeur et la même que la première, alors aucun message, et lorsque une nouvelle date apparaît, le message apparaît...

Merci merci
21/04/2023, 08h40
VincentCA

Bonjour tout le monde,
Je me permet de relancer mon post pour bénéficier d'une aide pour faire évoluer le fichier.

Serait il possible que la box qui s'affiche dans la fenêtre soit de la police (couleur) que la cellule magasin correspondante.
Ex si la cellule a une police en bleu, que box s'écrive en bleue. Si rouge, en rouge ?

Merci de votre aide,
Bonne journée

Voir 40 message(s) de cette discussion en une page