Fonction CHERCHE avec plusieurs "texte_cherché"

Version imprimable

08/09/2022, 12h20
jpg75014

Fonction CHERCHE avec plusieurs "texte_cherché"

Bonjour,

Je voudrais pouvoir trouver le texte PCE ou BT ou KG dans une cellule.

J'utilise la fonction CHERCHE :

Code:

=CHERCHE("PCE";A1)

mais en existe-t-il une autre qui permet plus d'arguments (si possible sans passer par une macro).

Merci beaucoup pour votre aide.

JPG
08/09/2022, 12h29
Invité

Peut-être avec une condition :

Code:

SIERREUR(RECHERCHE("PCE";A:A);RECHERCHE("BT";A:A))
08/09/2022, 12h54
Raccourcix

Bonjour

Code:

=OU(ESTNUM(CHERCHE({"PCE";"BT";"KG"};A1)))

renverra VRAI s'il trouve un des trois termes PCE, BT ou KG dans la cellule et FAUX si aucun n'est présent

Stéphane
08/09/2022, 15h08
jpg75014

Merci pour cette réponse, c'est possible d'obtenir la position de PCE ou BT ou KG ?
08/09/2022, 16h42
Raccourcix

1 pièce(s) jointe(s)

Oui, bien sûr

par exemple avec

Code:

=JOINDRE.TEXTE(CAR(10);;{"PCE";"BT";"KG"}&": "&SIERREUR(CHERCHE({"PCE";"BT";"KG"};A1);"NA"))

le JOINDRE.TEXTE(CAR(10) permet d'aller à la ligne
le SIERREUR permet d'afficher NA si le texte n'est pas trouvé

Pièce jointe 625088

Stéphane
08/09/2022, 16h52
Raccourcix
Un autre exemple pour identifier la première des trois chaines dans le texte et sa position
l'usage de LET permet d'éviter l'usage à trois reprises de la même fonction
Code:

1 2 3 4 =LET( liste;{"PCE";"BT";"KG"}; position;CHERCHE(liste;A1); SIERREUR(INDEX(liste&": "&position;EQUIV(MIN(SIERREUR(position;""));position));"Aucun"))
ou avec RECHERCHEX pour éviter le SIERREUR(INDEX...;EQUIV...) et une définition de la liste des textes cherchés
Code:

1 2 3 4 =LET( liste;{"PCE";"BT";"KG"}; position;CHERCHE(liste;A1); RECHERCHEX(MIN(SIERREUR(position;""));position;liste&": "&position;"Aucun"))
Stéphane
08/09/2022, 17h12
jpg75014

Merci pour toutes ces réponses, mais je ne parviens pas à identifier l'argument qui me renvoie 20 pour PCE (dans le résultat de votre exemple).
Sachant que dans mon cas, je n'aurai jamais les 3 (PCE, BT ou KG) dans A1 c'est soit l'un soit l'autre (il s'agit d'une unité qui est soit Pièce, soit Kilo...)
08/09/2022, 17h38
Raccourcix

C'est la fonction CHERCHE qui renvoie la position de "PCE" dans le texte
08/09/2022, 18h04
Raccourcix

J'ai répondu dans le cas général avec potentiellement beaucoup de texte cherché, mais si que 3 possible, voici une formule avec 3 CHERCHE imbriqué

Code:

=SIERREUR("PCE : "&CHERCHE("PCE";A1);SIERREUR("KG : "&CHERCHE("KG";A1);SIERREUR("BT : "&CHERCHE("BT";A1);"Aucun")))

Stéphane
08/09/2022, 18h18
jpg75014

Non mais j'aimais bien la formule avec les {} mais elle occupe autant de cellules que d'arguments, lorsque je saisis en B1

Code:

=SIERREUR(CHERCHE({"PCE";"BT";"KG"};A1);"NA")

la formule se propage sur B2 et B3 également (et si je colle en dessous, j'obtiens #EPARS!)

Et c'est juste pour mon post que je n'ai cité que 3 arguments, mais il y en a beaucoup plus. Seulement seul l'un d'entre eux apparaîtra dans la cellule A1

Merci encore
08/09/2022, 18h49
Raccourcix
Quelque chose comme
Code:

1 2 3 4 =LET( liste;{"PCE";"BT";"KG"}; position;CHERCHE(liste;A1); RECHERCHEX(VRAI;ESTNUM(position);liste&": "&position;"Aucun"))
c'est normal pour les cellules B2 et B3, c'est une fonction matricielle. D'où le JOINDRE.TEXTE que je proposais initialement ou ici le RECHERCHEX qui va récupérer la première valeur numérique

Stéphane
09/09/2022, 09h03
Raccourcix

Citation:

Envoyé par jpg75014

...

Et c'est juste pour mon post que je n'ai cité que 3 arguments, mais il y en a beaucoup plus. Seulement seul l'un d'entre eux apparaîtra dans la cellule A1 ...

Bonjour
En complément, plutôt que de stocker la liste {"PCE";"BT";"KG"} dans la formule le mieux est de la mettre dans un tableau et de faire référence à ce tableau dans la formule Tableau[Colonne]
Il sera ainsi facile d'ajouter un élément à la liste.

Stéphane
09/09/2022, 09h53
jpg75014

Citation:

Envoyé par Raccourcix

Bonjour
En complément, plutôt que de stocker la liste {"PCE";"BT";"KG"} dans la formule le mieux est de la mettre dans un tableau et de faire référence à ce tableau dans la formule Tableau[Colonne]
Il sera ainsi facile d'ajouter un élément à la liste.

Stéphane

Vous pourriez me montrer un exemple svp ? Avec CHERCHE ?
09/09/2022, 11h31
Raccourcix

1 pièce(s) jointe(s)

Par exemple en cellule E5

Code:

=RECHERCHEX(VRAI;ESTNUM(CHERCHE(Liste_Unité[Unité];A5));Liste_Unité[Unité];"aucun")

pour récupérer l'unité présente dans la cellule A5 d'après la liste des unités qui est stockée ailleurs dans le classeur

Pièce jointe 625139

le LET proposé précédemment est pour éviter de faire appel plusieurs fois à la même fonction

Stéphane
09/09/2022, 17h10
jpg75014

Merci beaucoup, c'est parfait