Caractères interdits dans nom de fichier

Version imprimable

20/08/2022, 15h54
retraite83

Caractères interdits dans nom de fichier

Bonjour

Je viens d'être confronté pour la 1ere fois avec un pb que vous avez forcément eu un jour ou l'autre.

Un utilisateur a saisi un caractère interdit dans le nom d'un fichier. Comme j'utilise ce nom pour créer le fichier...

J'ai bien identifier les 10 caractères interdits par Windows mais aucune solution trouvée sur internet ne me satisfait

Je veux détecter le problème après la saisie et informer l'utilisateur par un Msgbox dans ma macro avant la création du fichier et donc le plantage

Question subsidiaire : je suis en Windows 10 mais quelques PC vont être changés et du coup seront en Windows 11. A votre connaissance les caractères interdits sont-ils les mêmes ?

Merci

J'ai finalement trouvé une solution qui semble convenir, avez-vous mieux ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
sub ctrlNom
Dim lngI As Long, valid As Boolean
lngI = lngI + InStr(&H1, nomFich, "\")
lngI = lngI + InStr(&H1, nomFich, "/")
lngI = lngI + InStr(&H1, nomFich, ":")
lngI = lngI + InStr(&H1, nomFich, "*")
lngI = lngI + InStr(&H1, nomFich, "?")
lngI = lngI + InStr(&H1, nomFich, "<")
lngI = lngI + InStr(&H1, nomFich, ">")
lngI = lngI + InStr(&H1, nomFich, "|")
lngI = lngI + InStr(&H1, nomFich, Chr$(&H22)) ' Caractère "
If lngI = &H0 Then
Else
    MsgBox "ko"
    Exit Sub
End If
end sub

Bonjour,
Pour ma part, j'utilise une fonction qui remplace les mauvais caractères par d'autres mais si vous voulez absolument un message pour signaler que le nom est incorrect voici une autre solution
La fonction IsFileNameCorrect renvoie FALSE ou TRUE s'il le nom contient un caractère qui n'est pas accepté par Windows
Dans cette fonction, je ne gère pas les noms de fichiers interdits comme CON, PRN, AUX, NUL, COM1, COM2, COM3, COM4, COM5, COM6, COM7, COM8, COM9, LPT1, LPT2, LPT3, LPT4, LPT5, LPT6, LPT7, LPT8 et LPT9.
Code:

1 2 3 4 5 6 7 8 9 10 11 Function IsFileNameCorrect(Name As String) As Boolean Dim ProhibitedCharacters As String Dim Flag As Boolean Dim c As Byte ProhibitedCharacters = "\/:*?<>|" & Chr(34) ' \/:*?<>|" Do While Flag = False And c < Len(ProhibitedCharacters) c = c + 1 Flag = InStr(Name, Mid(ProhibitedCharacters, c, 1)) Loop IsFileNameCorrect = Not Flag End Function
Exemple d'une procédure qui l'invoque
Code:

1 2 3 4 5 6 Sub TestIsFileNameCorrect() Const FileName As String = "monfichier ?" If Not IsFileNameCorrect(FileName) Then MsgBox "le nom de fichier " & FileName & " contient des caractères ", vbCritical End If End Sub

Hello,
on peut aussi utiliser les expressions régulières pour tester les caractères interdits :

Code:

1
2
3
4
5
6
7
8
Function ValidFileName(FileName As String) As Boolean
'PURPOSE: Determine If A Given File Name Is Valid
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault
  With CreateObject("VBScript.RegExp")
    .Pattern = "[\\/:\*\?""<>\|\[\]]"
    ValidFileName = Not .Test(FileName)
  End With
End Function

Ami calmant, J.P

Hello,
Citation:
Code:

1 2 3 4 5 6 7 8 Function ValidFileName(FileName As String) As Boolean 'PURPOSE: Determine If A Given File Name Is Valid 'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault With CreateObject("VBScript.RegExp") .Pattern = "[\\/:\*\?""<>\|\[\]]" ValidFileName = Not .Test(FileName) End With End Function
Parfait cette fonction, exactement ce que je cherchais, mais comment peut on renvoyer le caractère qui pose problème quand c'est le cas ?
Idealement =>

renvoyer null si tout est OK
sinon renvoyer le caractère problématique

Je ne pige rien aux expressions régulières :(

Merci de vos idées
@+

1 pièce(s) jointe(s)

Hello,
l'utilisation d'expressions régulières n'est pas adaptée pour ce que tu veux faire.
Voici une solution qui va montrer quels sont les mauvais caractères dans le nom du fichier.
On utilise une zone de texte pour pouvoir colorer les lettres :
Le code :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Sub Bouton1_Cliquer() Dim ProhibitedCharacters As String Dim Name As String, i As Integer With ActiveSheet.Shapes("ZoneTexte1") Name = .TextFrame.Characters.text ProhibitedCharacters = "\/:*?<>|" & Chr(34) ' \/:*?<>|" For i = 1 To Len(Name) If InStr(1, ProhibitedCharacters, Mid(Name, i, 1)) Then .TextFrame2.TextRange.Characters(i, 1).Font.Fill.ForeColor.RGB = RGB(255, 0, 0) Else .TextFrame2.TextRange.Characters(i, 1).Font.Fill.ForeColor.RGB = RGB(0, 0, 0) End If Next i End With End Sub
Voici ce que cela donne :
Pièce jointe 661683

Ami calmant, J.P

13/11/2024, 21h46
bartimeus35

:merci::merci:

Hello,

Ben finalement on peut utiliser aussi les expressions régulières pour afficher les caractères illégaux du nom du fichier :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub VérifierNomFichier()
Dim Name As String, i As Integer, regex As Object, matches As Object, match
Name = "Nom:DE?fichier<Pourri.txt"
'Name = "Fichier.txt"
Debug.Print "==== Caractères illégaux trouvés dans " & Name & "===="
Set regex = CreateObject("VBScript.RegExp")
regex.Global = True
regex.pattern = "[\\/:\*\?""<>\|\[\]]"
Set matches = regex.Execute(Name)
If matches.Count = 0 Then
    Debug.Print "Fichier OK"
    Set matches = Nothing: Set regex = Nothing
    Exit Sub
End If
For Each match In matches
    Debug.Print match & " -> Place : " & match.FirstIndex + 1
Next
Set matches = Nothing: Set regex = Nothing
End Sub

Résultat :

Citation:

==== Caractères illégaux trouvés dans Nom:DE?fichier<Pourri.txt====
: -> Place : 4
? -> Place : 7
< -> Place : 15

Ami calmant, J.P

1 pièce(s) jointe(s)

bonsoir
y a pas un raccourci normalement pourle pattern des caractères spéciaux(tous sans exception)
du genre ça

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Sub test()
    MsgBox replacecharspé("toto:mange;des""bannanes;avvec[le\nez")
End Sub
 
Function replacecharspé(txt)
    With CreateObject("VBScript.RegExp")
        .Global = True
        '.IgnoreCase = True
        .Pattern = "[^\w]"
        replacecharspé = .Replace(CStr(txt), " ")
    End With
End Function

Pièce jointe 661790

15/11/2024, 20h42
tototiti2008

Pas du tout je m'insurge :mrgreen:
15/11/2024, 20h44
patmeziere

1 pièce(s) jointe(s)

Pièce jointe 661791
15/11/2024, 22h07
Valtrase

Re,
Là c'est clair que c'est tous sans exception... :lol:

Test :

Code:

MsgBox replacecharspé("toto:mange;des""bannanes.avvec[le\nez")