Erreur d´exécution dans Macro utilisant VB script SAP

Version imprimable

Bonjour á tous,

Je rencontre une erreur récurrente en utilisant des lignes de code VBscript SAP dans une macros Excel:

- Pour résumer, je lance une transaction SAP que j´exporte ensuite en .XLSX, afin de manipuler les données et les exporter avant de finalement refermer l´export généré sans sauvegarder (cf. code ci-dessous).

Mon problème est le suivant: le code continue de se lancer avant l´ouverture de l´export et ce, même dans le cas oú j´ajoute une ligne du genre

Code:

Application.Wait Now + TimeValue("00:00:10")

.

Le morceau de code correspondant est le suivant :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 'Export to Excel Session.findById("wnd[0]/mbar/menu[0]/menu[3]/menu[1]").Select Session.findById("wnd[1]/usr/ctxtDY_PATH").Text = Folder Session.findById("wnd[1]/usr/ctxtDY_FILENAME").Text = "ExportMLR.XLSX" On Error Resume Next Session.findById("wnd[1]/tbar[0]/btn[0]").press Session.findById("wnd[1]/tbar[0]/btn[11]").press On Error GoTo 0 Application.Wait Now + TimeValue("00:00:10") 'Paste DCE ActiveSheet.Range("A2:D2").Select Range(Selection, Selection.End(xlDown)).Select Selection.Copy Workbooks("Daily cost Extension Check.xlsm").Sheets("DCE").Activate Range("A2").Select ActiveSheet.Paste
Je voudrais que le morceau de code á partir de ´Paste DCE soit effectué sur le fichier Excel généré via SAP. Auriez-vous une solution ne nécessitant pas de revoir la logique d´export des données ??

Merci par avance pour votre précieuse aide :)

Salut

Si j'ai bien compris, ton fichier exporté s'appelle "ExportMLR.XLSX". Si c'est bien ça et que ce fichier est ouvert via SAP dans la même session d'excel que le fichier contenant la macro.
Tu peux essayer quelques choses comme ça, à adapté, code non testé.
Le code est commenté mais n'hésite pas si besoin d'infos.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Dim WbExport As Workbook
Dim iLoop As Integer
 
    'On patiente le temps que le classeur soit généré
    Do
        On Error Resume Next
            'On pointe le classeur exporté par SAP
            Set WbExport = Application.Workbooks("ExportMLR.XLSX")
        On Error GoTo 0
        'Si aucun classeur n'est pointé, on patiente 10s
        If WbExport Is Nothing Then Application.Wait Now + TimeValue("00:00:10")
        'On comptabilise le nombre de boucle (pour éviter de rester dans une boucle infini en cas de non ouverture du fichier ou d'ouverture de celui-ci dans une autre session d'excel...)
        iLoop = iLoop + 1
    'On regarde si on à déjà fait 30 boucle (30*10s = 300s = 5 mins... à toi d'adapter, c'est peut-être un peu long)
    Loop Until iLoop = 30 Or Not WbExport Is Nothing
 
    'On vérifie que le classeur a bien été pointé
    If Not WbExport Is Nothing Then
        'On copie les données 'Paste DCE
        'Ici je ne suis pas sûr que tu obtiennes le résultat escompté...
        'Le End sur un groupe de cellules contenues sur plusieurs colonnes ne tient compte que de la dernière colonne à priori)
        With WbExport.ActiveSheet
            .Range(.Range("A2:D2"), .Range("A2:D2").End(xlDown)).Copy Workbooks("Daily cost Extension Check.xlsm").Sheets("DCE").Range("A2")
        End With
    Else
        'On prévient qu'il y a un soucis
        MsgBox "Le fichier exporté n'a pas été trouvé dans cette session d'Excel", vbExclamation, "Fichier introuvable"
 
        'Il serait possible de modifier le message précédent pour demander à l'utilisateur s'il veut pointer manuellement le fichier exporter (via un box open file, mais il faut que l'utilisateur connaisse sont emplacement)
        'Ou si tu connais l'emplacement, ce qui est probable, tu pourrait lancer le fichier (en lecture seul). Voir même extraite les données via ODBC sans ouvrir le fichier. 
    End If

++
Qwaz

28/04/2022, 17h40
Tiblar92

Merci pour l´astuce ! Je viens d´essayer en intégrant tes lignes de codes (adaptées à mon cas) avec la logique de LOOP pour attendre que le fichier soit généré cependant cela n´a pas l´air de solutionner mon probléme.... si je le fais hors macros l´export s´ouvre en 2sec... et si je presse escape, l´export apparait également quand je sors de la macros....

Je pense que le soucis viens de la communication entre SAP et Excel et du fait que je passe de l´un á l´autre... mais je ne vois vraiment pas comment solutionner.. En effet, dés que je reprends la main l´export apparait.

Je laisse le sujet ouvert au cas oú :)

Merci d´avance pour votre aide
28/04/2022, 19h14
Qwazerty

Salut

Essai d'ajouter la ligne

Code:

Do events

dans la boucle Do Loop

++
Qwaz

Toujours pas malheureusement ! Mais merci bien :D encore une fonction que j´apprends !

Ce que je ne comprends pas c´est que le code suivant fonctionne bien tout seul (car ne manipule que SAP) et le fichier Excel issue de SAP s´ouvre aprés quelques secondes.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub ExportMDFR78()
 
    Chemin = ThisWorkbook.Path
 
    'Connection to SAP
    Set rotEntry = GetObject("SAPGUI")
    Set App = rotEntry.GetScriptingEngine
    Set Connection = App.Children(0)
    Set session = Connection.Children(0)
 
    'T-Code opening
    session.findById("wnd[0]/tbar[0]/okcd").Text = "/nY_GD2_82000306"
    session.findById("wnd[0]").sendVKey 0
 
    'Parameters selection
    session.findById("wnd[0]/usr/ctxtS_BUKRS-LOW").Text = "FR78"
    session.findById("wnd[0]/usr/ctxtS_BKLAS-LOW").Text = "Z100"
    session.findById("wnd[0]/usr/ctxtS_MMSTA-LOW").Text = "Z3"
 
    session.findById("wnd[0]/usr/btn%_S_MTART_%_APP_%-VALU_PUSH").press
    session.findById("wnd[1]/usr/tabsTAB_STRIP/tabpSIVA/ssubSCREEN_HEADER:SAPLALDB:3010/tblSAPLALDBSINGLE/ctxtRSCSEL_255-SLOW_I[1,0]").Text = "HALB"
    session.findById("wnd[1]/usr/tabsTAB_STRIP/tabpSIVA/ssubSCREEN_HEADER:SAPLALDB:3010/tblSAPLALDBSINGLE/ctxtRSCSEL_255-SLOW_I[1,1]").Text = "FERT"
    session.findById("wnd[1]/tbar[0]/btn[8]").press
 
    'Execute
    session.findById("wnd[0]/tbar[1]/btn[8]").press
 
    'Export to Excel
    session.findById("wnd[0]/mbar/menu[0]/menu[3]/menu[1]").Select
 
    session.findById("wnd[1]/usr/ctxtDY_PATH").Text = Chemin
    session.findById("wnd[1]/usr/ctxtDY_FILENAME").Text = "Materials_FR78.XLSX"
 
    On Error Resume Next
    session.findById("wnd[1]/tbar[0]/btn[0]").press
    session.findById("wnd[1]/tbar[0]/btn[11]").press
    On Error GoTo 0
 
 
 
End Sub

Quand je souhaite rajouter du code á la suite en sélectionnant par exemple le classeur généré "Materials_FR78.XLSX" cela me donne une "ERREUR 9 - Subscript out of range", et lorsque je debug le fichier s´ouvre finalement mais du coup la macros stops...

J´essaye de trouver des sujets liés sur Google sans succés :(

Salut

L’exécution d'une macro est exclusive. Je veux dire par là que si une macro s'exécute, une autre ne peut pas se lancer (excepté si la 1ère fait appelle à la seconde bien sûr).

Donc si tu exécutes une macro et que SAP a besoin d'en exécuter une pour organiser le fichier exporté, c'est sans doute ça qui pose problème.

Tu pourrais peut-être faire un essai en utilisant la fonction OnTime. Elle permet de programmer l'exécution d'un procédure (autre nom pour macro).
En gros tu scindes ton code en 2 parties
1ère/ Tu manipules SAP pour faire ton extraction. Puis tu programmes l'exécution 30s après de la seconde partie (que tu places dans une 2ème macro) via OnTime
2ème/ Tu traites les données exportées.

En code littérale (non testé) ça donnerait un truc comme ça
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Sub Macro1() 'Manipulation de SAP '... Code 'Programmation déclenchement Macro2 Application.OnTime Date + 30s, "Macro2" End sub Sub Macro2() 'Manipulation du Fichier Export 'Code... End Sub
ça n'est pas une solution que je qualifierais d'élégante mais elle permettra peut-être de mieux définir le problème.

++
Qwaz

03/05/2022, 17h57
Tiblar92

Merci beaucoup !!

Je galérais avec la function

Code:

Application.Wait Now + TimeValue("00:00:10")

, mais qui ne fait pas sortir de la première routine. Ta solution a l'air de fonctionner comme il faut, puisqu´elle permet une pause entre les 2 routines, et pas de debug pour le moment...je vais tester avec des exports plus gros et il faudra á mon avis adapter le timing, mais dans l´ensemble je dirais que le probléme est résolu.

Bien cordialement :)
03/05/2022, 19h03
Qwazerty

Salut

Avec plaisir :)

Le bon réflexe dans ces situation, c'est de faire une recherche (Curseur sur le mot clé Wait et F1 ou alors via un moteur de recherche). Souvent les 1er lien fourni pointent vers la base de connaissance de M$. Et tu obtiens ça.

Et notamment ceci

Citation:

Envoyé par Section Remarque

La méthode Attendre suspend toute activité de Microsoft Excel et peut vous empêcher d'effectuer d'autres opérations sur votre ordinateur aussi longtemps que que Attendre reste effective. Toutefois, l’arrière-plan traite afin que l’impression et le recalcul continuent.

Ce qui explique tes soucis.

++
Qwaz