Macro executant plusieurs macros qui sont dans des fichiers differents

Version imprimable

09/04/2022, 07h56
Paul Etc.

Macro executant plusieurs macros qui sont dans des fichiers differents

Bonjour,
Pour faire simple, je voudrais reunir dans une macro 4 macros différentes qui se trouvent dans des fichiers différents :

VIRUS FRANCE.xlms'!FichierDatesurP
VIRUS WORLDOMETERS import.xlms'!Onglet
VIRUS SELECTION.xlms'!CopyLineS
VIRUS FRANCE.xlms'!saveSurC

Je lancerai cette nouvelle macro depuis le fichier VIRUS FRANCE.xlms

Quelle serait la syntaxe ?
Merci par avance

Je vous invite à lire la documentation sur l'exploitation du fichier personnel "Personal.xlsB"; ça peut vous aider à concevoir une solution.

Vous pouvez également vous inspirer du code ci-dessous pour traiter plusieurs fichiers, via macro.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Sub ExecuterMacroSur_Tout_unRepertoire()
On Error GoTo SortieSecours
 
    Dim NomRepertoire As String
    Dim Exl_App As Excel.Application
    Dim NomFichier As String
    Dim wb, currWb As Workbook
    Dim ws, currWs As Worksheet
    Dim j As Integer
    Dim fDialog As Object
 
    Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
    Set currWb = ActiveWorkbook
    Set currWs = ActiveSheet
 
    'Choisissez le répertoire contenant les fichiers à traiter
    fDialog.Title = "Choisissez un répertoire"
    fDialog.InitialFileName = currWb.Path
    If fDialog.Show = -1 Then
      NomRepertoire = fDialog.SelectedItems(1)
    End If
 
    'Ouvrez une session Excel la rendant invisible
    Set Exl_App = New Excel.Application:  Exl_App.Visible = False
 
    'Scruter tous les classeurs XL das ce répertoire
    NomFichier = Dir(NomRepertoire & "\*.xlsx")    '   "\*.*"
    Do While NomFichier <> ""
        'Afficher message sur la progression dans la barre du statut (utile car le 2è Excel est invisible)
        Application.StatusBar = "Fichier en cours de tratement = '" & NomRepertoire & "\" & NomFichier & "'"
 
        Set wb = Exl_App.Workbooks.Open(NomRepertoire & "\" & NomFichier)
        '...
        'Ajouter ici vos propres instructions
        '...
        wb.Close SaveChanges:=False 'on ferme le fichier traité sans l'enregistrer (à adapter si nécessaire)
        Debug.Print "Fichier traité " & NomRepertoire & "\" & NomFichier
        j = j + 1
        NomFichier = Dir()
    Loop
 
    Debug.Print "Nombre de fichiers traités = " & j
    Exl_App.Quit
    Set Exl_App = Nothing
 
    'Rétablir le statut par défaut et annoncer la fin du processus
    Application.StatusBar = ""
    MsgBox "L'execution des macros s'est terminée avec succès !", vbInformation, "Macros"
 
SortieSecours_Fin:
    Exit Sub
 
SortieSecours:
    MsgBox "Erreur dans le processus !; " & Err & " : " & Error, vbCritical, "Y a un Stuuud"
    Resume SortieSecours_Fin
End Sub

10/04/2022, 07h21
Paul Etc.

bisutage

Merci pour ces indications. Je ne sais comment utiliser la suggestion concernant le fichier PERSONAL. Car je cherchais une syntaxe. Tout comme l'exemple proposé me semble être un bizutage; un peu complexe pour moi, mais surtout, dans les deux cas, les orientations sont un peu loin de la question. Il ne s'agit pas de gérer plusieurs fichiers, mais enquiller des macros provenant de fichiers différents, et devant agir sur ces m^me fichiers
Merci quand m^me
10/04/2022, 12h21
Philippe Tulliez

Bonjour,
Je ne suis pas certain d'avoir compris votre demande et de plus comment voulez-vous que l'on vous aide. La seule chose que vous affichez c'est le nom de quatre classeurs
Ce que j'ai compris.
Vous avez une procédure (macro) dans chacun de vos classeurs et vous voudriez les rassembler dans un seul classeur.
Si c'est le cas, il suffit de faire une copie de chacune d'elles pour les coller dans le module du classeur où vous souhaitez les avoir réunies, à condition évidemment qu'elles n'aient pas le même nom.
10/04/2022, 17h52
Paul Etc.

elliptique

Bonsoir de Hanoi,
merci de vous être intéressé à la question. Je comprends que j'ai été trop elliptique.

J'ai quatre macro :
FichierDatesurP
Onglet
CopyLineS
saveSurC

qui chacune se trouve et travaille dans un seul fichier :
VIRUS FRANCE.xlms
VIRUS WORLDOMETERS import.xlms
VIRUS SELECTION.xlms
VIRUS FRANCE.xlms

j'ai ainsi 4 macros dont le nom complet est donc :
VIRUS FRANCE.xlms'!FichierDatesurP
VIRUS WORLDOMETERS import.xlms'!Onglet
VIRUS SELECTION.xlms'!CopyLineS
VIRUS FRANCE.xlms'!saveSurC

Pour l'instant, MANUELLEMENT, j'ouvre le premier fichier et je lance la macro correspondante, puis le second et sa macro, et ainsi de suite.
Je souhaite, après avoir ouvert les quatre fichiers, lancer une macro qui exécuterait chacune des quatre et fasse le travail a l'intérieur de son fichier.

J'ai composé une macro qui lance (type 'call') les quatre, mais le système ne travaille pas dans le bon fichier et fait n'importe quoi.
Dans cette macro, je ne sais pas lui dire de se positionner dans fichier correspondant à la macro.
Quand j' essaie de le faire; par exemple : ( ("VIRUS WORLDOMETERS import.xlsm").Activate ), ca plante

quelle serait la bonne syntaxe ?

J'espère avoir été plus clair

Bonne soirée

C'est exactement ce que fait le code que je vous ai proposé, à condition de l'adapter et le compléter

A la ligne "ajouter ici vos instructions", il faut y mettre "Call VIRUS FRANCE.xlms'!FichierDatesurP", par exemple.
Vous pouvez créer une boucle sur les 4 macros, du style:
Code:

1 2 3 4 For j = 1 to 4 ChoixMacro = Choose(j, "Fichier1.Macro1", "Fichier2.Macro2", "Fichier3.Macro3", "Fichier4.Macro4") '..... Faire ce que l'on veut ici, et passer à la macro suivante Next j
Je crois, on ne peut plus clair !

Bonjour,
Pour invoquer une procédure présente dans un autre classeur, vous avez la fonction Run. Par exemple Application.Run ("Classeur_1.xlsm!Main")

Dans les deux exemples ci-dessous, tous les classeurs sont dans le même répertoire

Exemple pour un fichier. La procédure invoquée dans Classeur_1.xlsm se nomme également Main
Code:

1 2 3 4 5 6 7 8 9 10 11 Sub Main() Const FileName As String = "Classeur_1.xlsm" Dim wkb As Workbook Dim PathName As String Dim t As Variant PathName = ThisWorkbook.Path & "\" Set wkb = Workbooks.Open(PathName & FileName) Application.Run wkb.Name & "!Main" wkb.Close savechanges:=False Set wkb = Nothing End Sub
Exemple avec deux classeurs ayant tous les deux une procédure nommée Main
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 Sub Main() Dim wkb As Workbook Dim PathName As String Dim t As Variant Dim f As Integer PathName = ThisWorkbook.Path & "\" t = Array("Classeur_1.xlsm", "Classeur_2.xlsm") For f = LBound(t) To UBound(t) Set wkb = Workbooks.Open(PathName & t(f)) Application.Run wkb.Name & "!Main" wkb.Close savechanges:=False Next Set wkb = Nothing End Sub
[EDIT]
Attention, si le nom d'un classeur contient des caractères espacés, il y a lieu d'entourer le nom de guillemets.
Soit pour la ligne 10 de mon 2ème exemple : Application.Run "'" & wkb.Name & "'!Main"

11/04/2022, 10h52
Paul Etc.

caracteres espacés

J'ai bien noté la necessité de traiter les espaces dans le nom des fichiers.
Pourriez vous me montrer un exemple avec

VIRUS WORLDOMETERS import.xlms'!Onglet

Je tourne en rond dans mes recherches et je bute
Merci
11/04/2022, 11h45
Philippe Tulliez

Bonjour,

Citation:

J'ai bien noté la necessité de traiter les espaces dans le nom des fichiers.
Pourriez vous me montrer un exemple avec
VIRUS WORLDOMETERS import.xlms'!Onglet

J'ai donné deux exemples et ai ajouté la syntaxe avec guillemets. N'est-ce pas suffisant ?

Soit vous placez les guillemets au moment de la lecture du nom des classeurs à traiter, comme dans la ligne 7 de mon second exemple

Code:

t = Array("'Classeur_1.xlsm'", "Classeur_2.xlsm")

soit dans la ligne 10 au moment de l'invocation, comme je l'ai indiqué dans mon message précédent

Code:

Application.Run "'" & wkb.Name & "'!Main"

Bonjour,
Il est possible également de prévoir le nom des procédures à invoquer dans la liste des classeurs à traiter.
Dans ce cas il y a lieu de modifier un peu le code

Exemple
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 Sub Main() Dim wkb As Workbook Dim PathName As String Dim FileName As String Dim t As Variant, m As Variant Dim f As Integer ' PathName = ThisWorkbook.Path & "\" t = Array("Classeur_1.xlsm!Main", "Classeur_2.xlsm!Main", "Classeur 3.xlsm!Main") For f = LBound(t) To UBound(t) FileName = Left(t(f), InStr(t(f), "!") - 1) Debug.Print FileName Set wkb = Workbooks.Open(PathName & FileName) m = Split(t(f), "!") Application.Run "'" & wkb.Name & "'!" & m(1) wkb.Close savechanges:=False Next Set wkb = Nothing End Sub
Dans votre cas, il y aura donc lieu de remplacer les constantes de la ligne 9 par

Code:

t = Array("VIRUS FRANCE.xlms!FichierDatesurP", "VIRUS WORLDOMETERS import.xlms!Onglet", "VIRUS SELECTION.xlms!CopyLineS", "VIRUS FRANCE.xlms!saveSurC")

15/04/2022, 12h57
Paul Etc.

Resolu

Merci, pour ces indications que j'ai pris du temps a assimiler (debutant).
Maintenant grace a vous ca fonctionne
Je ne sais pas ou cliquer pour dire que c'est resolu
Mille mercis