Imprimer X fois la page Y d'un pdf

Version imprimable

02/04/2022, 13h21
matthieu_bermond

Imprimer X fois la page Y d'un pdf

Bonjour, je suis enseignant et j'ai un fichier pdf en français pour ma classe. Le fichier fait 5 pages. La première page est pour les plus fort, la deuxième pour les un peu moins fort et ainsi de suite.
Je souhaiterai en un coup imprimer 5 fois la page 1, 6 fois la page 2, 7 fois la page 3, 4 fois la page 4. Est-ce possible?
Comment puis-je faire?

pour le moment, j'ouvre adobe, je lance l'impression 5 fois de la page 1. Puis, je relance une nouvelle impression 6 fois la page 2.... Mais je trouve que ça me prend bcp de temps pour pas grand chose.

Merci.

Matthieu Bermond
02/04/2022, 14h07
vttman

1 pièce(s) jointe(s)

Bonjour,

Basiquement
Un coup d'excel ou libre office etc.
Pièce jointe 616636
Puis un copier coller de la concaténation (C5), un café et c'est réglé !

Bon maintenant pour les solutions plus sophistiquées, wait & see ;)
02/04/2022, 14h41
matthieu_bermond

Bonjour,

j'avais pensé à cette solution mais sur la photocopieuse de l'école, ça marche pas. Quand je met 1,1,1,1,1, ça imprime qu'une fois la page 1 au lieu de 5 fois.

Mais merci :)
02/04/2022, 16h56
vttman

Bonjour,
Alors il faudrait savoir le logiciel utilisé : Acrobat Reader, Foxit ou autres ...
02/04/2022, 17h05
matthieu_bermond

Alors, c'est le gestionnaire d'impression qui s'ouvre avec microsoft edge.
J'essayerai ta méthode avec le gestionnaire d'impression de windows 11.

Citation:

Envoyé par vttman

Bonjour,
Alors il faudrait savoir le logiciel utilisé : Acrobat Reader, Foxit ou autres ...
02/04/2022, 17h16
vttman

Ok ... Acrobat Reader ça marcherait je pense.
Il faudrait enregistrer le pdf en local puis l'ouvrir avec Acrobat Reader
Sinon tester le lecteur de pdf sous Chrome, Firefox, Opera, etc. sait-on jamais ...
02/04/2022, 17h18
matthieu_bermond

Merci. Je vais essayer la semaine prochaine. En attendant, si quelqu'un a un batch qui permet de faire ça plus proprement, je suis preneur :)

Citation:

Envoyé par vttman

Ok ... Acrobat Reader ça marcherait je pense.
Il faudrait enregistrer le pdf en local puis l'ouvrir avec Acrobat Reader
Sinon tester le lecteur de pdf sous Chrome, Firefox, Opera, etc. sait-on jamais ...

Bonjour,

J'ai un batch à te proposer, cependant l'invite de commandes ne permet pas nativement d'imprimer un pdf.
Par conséquent tu devras installer 2 logiciels pour que mon script fonctionne comme attendu, les voici :

- PDFtk Server (version gratuite) : https://www.pdflabs.com/tools/pdftk-server/

- Foxit PDF Reader : https://www.foxit.com/fr/pdf-reader/

Voilà le script .bat :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
@echo off
mode con cols=140 lines=35
setlocal enableextensions enabledelayedexpansion
ver | find "10.0." >nul && chcp 65001 >nul || chcp 1252 >nul
color 0F
 
set "pages=1 1 1 1 1 2 2 2 2 2 2 3 3 3 3 3 3 3 4 4 4 4"
 
: ----------------------------------------------------
: on vérifie la présence du fichier à traiter
: ----------------------------------------------------
 
if "%~1"=="" (
	echo. & echo Merci de glisser-deposer votre fichier PDF sur le fichier BAT
	echo. & pause
	exit /b 1
)
if not "%~x1"==".pdf" (exit /b 1)
title %~1
 
: -----------------------------------------------------------------
: on construit un nouveau fichier à partir des pages désirées
: -----------------------------------------------------------------
 
pdftk "%~1" cat %pages% output out1.pdf
 
: ----------------------------------------------------
: on liste les imprimantes installées
: ----------------------------------------------------
 
set index=0
for /f "skip=1 tokens=2,3 delims=," %%A in ('wmic printer get Name^,PortName^,PrinterStatus /format:csv ^| findstr /r "^[A-Za-z0-9]" ^| findstr /i /v "AnyDesk Microsoft Fax Onenote"') do (
    set /a index+=1
    set "printer[!index!]=%%A"
    set "port[!index!]=%%B"
)
 
if !index! EQU 0 (
    echo. & echo ==^>^> Aucune imprimante n'a ete detectee
    echo. & pause
    exit / b 1
)
 
: ----------------------------------------------------
: on sélectionne une imprimante
: ----------------------------------------------------
 
:choixImprimante
 
for /L %%G in (1,1,!index!) do echo. & echo.##### [%%G] !printer[%%G]! ("!port[%%G]!")
 
echo. & set "choix="
set /p choix="Veuillez selectionner une imprimante (via son numero) : "
if not defined choix (cls & goto :choixImprimante)
set "choix=%choix: =%"
if not defined printer[%choix%] (cls & goto :choixImprimante)
 
: ----------------------------------------------------------
: on imprime le nouveau fichier via Foxit PDF Reader
: ----------------------------------------------------------
 
echo. & echo.
echo. & echo ==^>^> Fichier en cours de transmission vers l'imprimante "!printer[%choix%]!" ...
echo. & echo ==^>^> Veuillez patienter quelques instants ...
echo. & echo.
 
"%ProgramFiles(x86)%\Foxit Software\Foxit PDF Reader\FoxitPDFReader.exe" /t out1.pdf "!printer[%choix%]!"
 
echo. & echo ==^>^> Fin de la transmission
echo. & echo ==^>^> L'impression va commencer dans quelques instants ...
echo. & echo. & echo. & pause
exit

Pour exécuter le script il faut faire glisser ton fichier pdf sur le fichier batch.