Sauvegarder et récupérer les données d'un DataGridView

Version imprimable

Bonjour le Forum,

Je souhaite remplir mon DataGridview en récupèrent les données enregistrer dans un fichier text, actuellement seul le code qui sauvegarde les données fonctionne.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
     Dim writer As TextWriter = New StreamWriter("C:\Users\All Users\ABC.text")
 
            For i As Integer = 0 To DataGridView1.Rows.Count - 2 Step +1
 
                For j As Integer = 0 To DataGridView1.Columns.Count - 1 Step +1
 
                    writer.Write(vbTab & DataGridView1.Rows(i).Cells(j).Value.ToString() & vbTab & "|")
 
                Next
 
                writer.WriteLine("")
                writer.WriteLine("---------------------------------------------")
 
            Next
            writer.Close()
            MessageBox.Show("Data Exported")

et je bloque avec le code qui récupère les données pour remplir le DataGridView

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
   Dim lines() As String
            Dim vals() As String
 
            ' get lines from the text file
            lines = File.ReadAllLines("C:\Users\All Users\ABC.text")
 
            ' For i As Integer = 0 To lines.Length - 1 Step +1  ' lines
            For i As Integer = 0 To lines.Length - 2 Step +1  ' lines
                vals = lines(i).ToString().Split(CChar(("|")))
                Dim row(vals.Length - 1) As String
 
                For j As Integer = 0 To vals.Length - 1 Step +1  ' columns
 
                    row(j) = vals(j).Trim()
 
                Next j
 
                Table.Rows.Add(row)
 
            Next i

Je sollicite donc votre aide afin de corriger le code qui récupère les données, l'erreur est sur Table.Rows.Add(row)
Merci à vous.

Bonsoir,

Citation:

et je bloque avec le code qui récupère les données pour remplir le DataGridView

voila ce que j'utilise!

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
    Sub test()
        Const MyRep As String = "C:\Myrep\" 'on défini le répertoire qui deviendra la base de données
        Const MyFichier = "ABC.txt" 'on défini la table de la base de données
        Dim Shema As String = $"[{MyFichier}]
            Format= Delimited(|)"
        DataGridView1.DataSource = OpenFtxt(MyRep, $"Select  * From [{MyFichier.Replace(".", "#")}]", Shema, False)
    End Sub
    ''' <summary>
    ''' Permet de récupérer sou forme d'un Datatable le contenue d'un fichier texte
    ''' </summary>
    ''' <param name="folder">Répertoire ou ce trouve le ficher texte</param>
    ''' <param name="SQL">Requête de séléction à retourner sous forme de Datatable</param>
    ''' <param name="Shemat">permet de définire la structure du fichier</param>
    ''' <param name="Titre">Booléan qui détermine si la première ligne du fichier est l'entête de colonnes ou une donnée</param> 
    ''' <returns>retourn dune Datatable</returns>
    Private Function OpenFtxt(folder As String, SQL As String, Shema As String, Titre As Boolean) As DataTable
        '************************************************************************
        'on implémente le fichier schema.ini qui défini la structure du  ou les fichiers texte
        Dim objWriter As New System.IO.StreamWriter($"{folder}\schema.ini", False)
        objWriter.WriteLine(Shema)
        objWriter.Close()
        '**************************************************************************
        'on défini la connexion au répertoire pour le voir comme une base de données!
        Dim con As String = $"Provider=Microsoft.Jet.OLEDB.4.0;Data Source={folder};Extended Properties='text;HDR={If(Titre, "Yes", "No")};FMT=Delimited';"
        '*****************************************************************************
        Dim dt As New DataTable 'on déclare le datatable qui va contenire le résulta de la requête
        'on execute la requêteet on retourne le datatable
        Using Adp As New OleDbDataAdapter(SQL, con)
            Try
                Adp.Fill(dt)
                Return dt 'on retourne le datatable!
            Catch ex As Exception
                Return Nothing
            End Try
        End Using
        '*****************************************************************************
    End Function

03/04/2022, 14h12
Tempus01

Bonjour Thumb down,

Merci pour votre code, il fonctionne parfaitement.