Faire référence à un objet Attachment

Version imprimable

Bonjour aux membres de ce forum.
J'aurais souhaité que l'un des membres m'apporte une aide face à ma situation d'échec actuelle.

J'envisage l'utilisation des propriétés et méthodes de l'objet Attachment (ie : pièces jointes) pour manipuler des informations concernant les pièces jointes d'une table, notamment afin de compter le nombre de pièces jointes pour un enregistrement donné et pour lister le nom de fichier de chaque pièce-jointe.
Je butte sur l'écriture appropriée pour affecter l'objet à la variable objet.
Les pièces jointes sont stockées dans un champ unique "ImageJointe" de la table "Appellations".
Il convient de noter qu'en passant par le formulaire ouvert lié à cette table, j'accède facilement aux informations (les propriétés et méthode de l'objet Attachement me sont facilement accessibles). Cependant je souhaiterais accéder aux informations sans passer par le formulaire ouvert.
Je vous communique le code tester en laissant volontairement présents mes balbutiements.
merci à vous.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 Private Sub Commande46_Click() Dim maBD As Database, maT As Recordset Dim mesPJ As Attachment Set maBD = CurrentDb Set maT = maBD.OpenRecordset("Appellations") 'Recordset de type Table 'Set mesPJ = maT.Fields(8) 'Incompatibilité de type (Erreur 13) Set mesPJ = maT.Fields("ImageJointe") 'Incompatibilité de type (Erreur 13) maT.MoveFirst 'MsgBox maT.Fields(8).Name 'me donne bien le nom du champ soit "ImageJointe" ' ce champ est-il de type pièces-jointes ? 'If maT.Fields(8).Type = dbAttachment Then MsgBox "Ce champ est bien de type Pièces-Jointes" 'c'est OK MsgBox mesPJ.AttachmentCount 'Set mesPJ = maT![ImageJointe] ' non valide 'Set mesPJ = Me.ImagesJointes 'dans le formulaire, c'est OK 'Set mesPJ = maT.Fields("ImageJointe").Value 'dans la table, ce n'est pas fonctionnel 'Set mesPJ = maT.Fields("ImageJointe") 'dans la table, ce n'est pas fonctionnel 'MsgBox maT![Ordre] ' c'est OK 'a partir du formulaire ouvert, l'accès se fait facilement : 'Set mesPJ = Me.ImagesJointes 'MsgBox mesPJ.AttachmentCount 'MsgBox mesPJ.fileName(0) 'MsgBox mesPJ.fileName(1) 'MsgBox mesPJ.fileName(2) 'MsgBox mesPJ.fileName(3) 'With maT ' '.Index = "PrimaryKey" ' .Seek "=", 1 ' .Edit ' maT![Image 1] = mesPJ.fileName(0) ' maT![Image 2] = mesPJ.fileName(1) ' maT![Image 3] = mesPJ.fileName(2) ' maT![Image 4] = mesPJ.fileName(3) '.Update '.Close ' 'End With MsgBox "Action terminée !" Set maT = Nothing Set maBD = Nothing End Sub

Attachments

Vous pouvez vous inspirer de ceci:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub ListAttachments()
 
    Dim dbs As DAO.Database
    Dim rst As DAO.Recordset
    Dim rsA As DAO.Recordset2   'représente un enregistrement dans une table
    Dim fld As DAO.Field2       'représente une colonne dans une table
 
    'Définir la database, le recordset, et le champ "attachment"
    Set dbs = CurrentDb
    Set rst = dbs.OpenRecordset("tblAttachments")   '   "tblAttachments" est à remplacer par le nom de votre table ("Appellations" pour vous)
    Set fld = rst("Attachments")        '   "ImageJointe" pour vous
 
    'Parcourir la table
    Do While Not rst.EOF
        'Imprimer les 1ers éléments de la table (facultatif)
        Debug.Print rst("FirstName") & " " & rst("LastName")
        'Repérer l'enregistrement pour le champ des 'Attachments'
        Set rsA = fld.Value
        'Imprimer tous les "attachments" dans le champ
        Do While Not rsA.EOF
            Debug.Print , rsA("FileType"), rsA("FileName")
            'Au lieu de debug.print, on peut utiliser MsgBox
            'attachment suiant
            rsA.MoveNext
        Loop
        'enregistrement suivant
        rst.MoveNext
    Loop
 
    Set fld = Nothing
    rst.Close: Set rst = Nothing
    dbs.Close: Set dbs = Nothing
 
End Sub

27/03/2022, 20h41
ggvert

Je remercie vivement Zekraoui_Jakani de s'être intéressé à ce sujet et d'avoir pris le temps de me proposer une solution.
Cette solution a été testée.
Elle permet effectivement d'accéder "aux" pièces jointes.
Hélas, elle ne correspond pas véritablement à mon projet.
En effet, pour un enregistrement donné de la table, plusieurs pièces jointes sont référencées dans le même champ relatif aux pièces jointes.
Et, par la méthode proposée par Zekraoui_Jakani, l'accès n'est donné qu'à la première pièce jointe.

C'est pour cela que je souhaiterais utiliser les propriétés et méthodes de l'objet "Attachment" lequel permet notamment :
- de compter les pièces jointes du champ (pour cet enregistrement) : propriété AttachmentCount
- de nommer le fichier répondant à un numéro d'indexation de la collection des pièces jointes du champ (pour cet enregistrement) : propriété FileName

Mais comment déclarer les pièces jointes d'un enregistrement en tant qu'objet Attachment ?

Attachments

Le code ci-dessous donne (chez moi) toutes les infos nécessaires; j' y ai rajouté un compteur.
Au cas où, vous pouvez toujours poster copie de vote Dbase, en y mettant des infos fictives. Je verrai là ou ça coince.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub ListAttachments()
 
    Dim dbs As DAO.Database
    Dim rst As DAO.Recordset
    Dim rsA As DAO.Recordset2   'représente un enregistrement dans une table
    Dim fld As DAO.Field2       'représente une colonne dans une table
 
    'Définir la database, le recordset, et le champ "attachment"
    Set dbs = CurrentDb
    Set rst = dbs.OpenRecordset("Enfants")   '   "Enfants" est à remplacer par le nom de votre table ("Appellations" pour vous)
    Set fld = rst("Photo")        '   "ImageJointe" pour vous
 
    'Parcourir la table
    Do While Not rst.EOF
        'Imprimer les 1ers éléments de la table (facultatif)
        Debug.Print rst!nom & " " & rst!Prénom
        'Repérer l'enregistrement pour le champ des 'Attachments'
        Set rsA = fld.Value
        'Imprimer tous les "attachments" dans le champ
        Debug.Print , "Type", "Nom fichier", "       Nbr annexes"
        Do While Not rsA.EOF
            Debug.Print , rsA("FileType"), rsA("FileName"), rsA.RecordCount
            'Au lieu de debug.print, on peut utiliser MsgBox
            'attachment suivant
            rsA.MoveNext
        Loop
        'enregistrement suivant
        rst.MoveNext
    Loop
 
    Set fld = Nothing
    rst.Close: Set rst = Nothing
    dbs.Close: Set dbs = Nothing
 
End Sub

30/03/2022, 14h31
ggvert

Merci à Zekraoui_Jakani pour cette nouvelle réponse qui donne effectivement accès aux informations souhaitées.
Très sympa avec une présentation très pédagogique.
Bonne continuation et merci encore.
:D