coller texte d'une page web en mémoire dans la cellule de droite de mon champs modifié en VBA

Version imprimable

28/12/2021, 18h36
bibimtl2x

coller texte d'une page web en mémoire dans la cellule de droite de mon champs modifié en VBA

Bonjour, voilà, sur chaque ligne de mon fichier Excel, j’ai dans la colonne « B » un menu déroulant, je voudrais qu’à chaque fois que je modifie ce menu déroulant en « B » le texte en mémoire (qui est du texte copie d’une page web) ce copie dans le champs de la colonne « A » en format texte sur la meme ligne que mon champ « B » que je viens de modifier,,
Je sais que je dois faire une macro sur ma page « sur modification » mais je ne sais pas quoi metre pour faire référence au texte en mémoire, et encore moins faire référence au chams « A » qui change selon ou est la ligne de mon champs « B » qui a été modifié ☹
Et mon texte de ma page web est sur qq ligne, mais il doit apparaître que dans mon champs « A » donc vraiement copie en texte pure, comme si je faisais un double clik dans mon champs « A » avant de le copier..
Ce que je fais en ce moment manuel :
Une fois mon texte copie du web, je modifie mon champs « B » exemple b233, et en suite double clik dans A233 pour ensuite y copie le texte.
Je fais ça pour b233.b234, b235.. etc

Merci e votre aide 😊
30/12/2021, 22h25
Qwazerty

Salut

Je ne pense pas avoir saisi ce que tu souhaites faire exactement.
J'imagine que par "en mémoire" tu veux dire dans le presse papier (suite à un Copier - Ctrl+C), si c'est le cas, tu peux regarder du coté de l'objet DataObject, qui permet de récupérer le contenu du PressePapier (ClipBoard).

Si ce texte n'est pas très volumineux, plutôt que de te diriger vers des macro qui vont te rendre dépendant des gens du forum, pourquoi ne pas le coller dans une cellule, puis à l'aide de formule excel extraire les données dont tu as besoin en fonction de ta colonne A?
Peux-tu poster un contenu type de ce qui est stocké dans le presse papier?

++
Qwaz
31/12/2021, 01h11
bibimtl2x

merci de la réponse,

J'imagine que par "en mémoire" tu veux dire dans le presse papier (suite à un Copier - Ctrl+C) > oui a partir d'une page web

Une fois le texte dans la cellule de la colonne "A" des formules dans les cellule c,d,f extrait l'information nécessaire, c'est déjà ca, mais le but c'est de rendre la partie "collé" dans la cellule "A" transparente pour mes usagers, donc en choisissant la date dans "B" , le texte ( qui vient d'être mis en mémoire à partir du site web) se copiait dans la colonne "A" (presque cachée) et l'information se diffuse dans les colonne C,D,F automatiquement

j'espère que c'est plus claire, merci de votre temps :)
31/12/2021, 08h05
Qwazerty
Salut

Citation:

Envoyé par bibimtl2x

... mais le but c'est de rendre la partie "collé" dans la cellule "A" transparente pour mes usagers, donc en choisissant la date dans "B" , le texte ( qui vient d'être mis en mémoire à partir du site web) se copiait dans la colonne "A" (presque cachée) et l'information se diffuse dans les colonne C,D,F automatiquement

"se copiait" ou se copierait? C'est ce que tu cherche à faire c'est ça?

Ce que je pense comprendre:
Votre fichier contiens plusieurs lignes
Sur la ligne vide suivante, il sélectionne une date
[Les données contenus dans le presse papier sont placées dans la cellule A de cette ligne]
Le contenu de la cellule A est décomposée via des formules dans les colonnes C,D,F de cette même ligne

Pour la prise en compte de la modification de la cellule en B
Il faut regarder dans le code VBA de la feuille et utiliser l’événement Worksheet_Change (dans la fenêtre de code, dans les listes déroulantes en haut il faut choisir Worksheet et Change)
Dans cette section de code, il vous faut
1. Identifier si la cellule modifiée est bien en colonne B (utilisation de la fonction Intersect())
2. Récupérer les données dans le presse papier (utilisation du DataObject - Récupération Clipboard)
N'hésitez pas à poster votre code pour que l'on puisse vous aider à le modifier s'il ne fait pas ce que vous souhaitez. En faisant quelques recherches sur les mots clef en gras vous devriez trouver pas mal d'exemples ici ou là sur le net.

++
Qwaz
31/12/2021, 21h20
bibimtl2x
Bonjour, oui c'est ca :) , pour l'automatisation sur modification ca pas de probleme, mais c'est pour avoir acces a ce qui est en mémoire, et lui dire de le copier dans la case "A" la même ligne que le "B" que je viens de changer, ce qui est en mémoire que je sais pas, jamais utilisé les DataObject :(

merci encore

j'ai juste ca comme code:
Code:

1 2 3 4 5 6 Private Sub Worksheet_Change(ByVal Target As Range) If Not Application.Intersect(Target, Range("B:B")) Is Nothing Then 'Call End If End Sub
01/01/2022, 09h36
Qwazerty

Bonjour

Dans ces cas là, votre navigateur est votre ami :).
La recherche "VBA DataClip Clipboard" vous donnera dans les 1ers résultats (si le moteur de recherche est correct) un lien vers les bases de connaissances Microsoft.
Je trouve leur système de recherche pas terrible, passer par un moteur de recherche aide bien...

Ainsi, vous aurez un exemple détaillé ici

Je pense que ça ne pose pas de difficulté particulière à mettre en œuvre, si j'ai bien compris vous copiez du contenu "à la main", donc le format de celui-ci sera textuel mais n'hésitez pas si besoin.

Sachez aussi qu'il est possible d'automatisé de la récupération de contenu sur des pages web. Une des possibilité est développée dans le tutoriel suivant
Bien sûr dans votre cas, il faut que la date, saisie actuellement en B, puisse être reliée au données du site.

++
Qwaz
04/01/2022, 20h06
bibimtl2x

un grand merci, mais serieux, je crois que je ne suis vraiment pas assez avancé, je comprend rien a l'exemple du site.. :( juste le départ comment faire copie du clipboard a A1 exemple. j'y arrive meme pas.. j'ai l'impression de vous faire perdre votre temps :( désolé

Salut

Pas grave, leurs exemples sont parfois un peu déroutants surtout que celui fourni nécessite de travailler sur un Userform... ce qui n'est pas votre cas.

Voilà un exemple de code à affiner

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim ClipBoardData As DataObject
Dim StrClip As String
 
    'On vérifie que la cellule modifiée se trouve dans la colonne B
    If Not Application.Intersect(Target, Range("B:B")) Is Nothing Then
        'On déclare une nouvelle instance DataObject
        Set ClipBoardData = New DataObject
        'On charge le contenu du ClipBord
        ClipBoardData.GetFromClipboard
        'On récupère le contenu text du clipboard
        StrClip = ClipBoardData.GetText(1) 'Le 1 correspond à un contenu textuel
        'On pointe la cellule de la colonne A qui se trouve sur la même ligne que la cellule modifiée
        'Et on y place la valeur extrait du Clipboard
        Target.Offset(ColumnOffset:=-1).Value = StrClip
  End If
 
End Sub

++
Qwaz

04/01/2022, 23h34
bibimtl2x

1 pièce(s) jointe(s)

Pièce jointe 611256

j'ai ce message d'erreur la ( voir pièce jointe) dès que je change dans la colonne "b", j'ai merdé encore c'est ca? lol

j'ai ajouté votre texte dans le VBA de l'onglet

merci
05/01/2022, 06h53
Qwazerty

Salut

Ah mince j'ai utiliser un de mes classeur ouvert pour tester le code... il faut que le référence Microsoft Forms 2.0 Object Library soit activé.
Pour se faire, il faut que tu ailles dans le menu Outils de VBA, puis Références, puis tu coche la case qui va bien dans la liste.

++
Qwaz
05/01/2022, 16h47
bibimtl2x

Citation:

Envoyé par Qwazerty

Salut

Ah mince j'ai utiliser un de mes classeur ouvert pour tester le code... il faut que le référence Microsoft Forms 2.0 Object Library soit activé.
Pour se faire, il faut que tu ailles dans le menu Outils de VBA, puis Références, puis tu coche la case qui va bien dans la liste.

++
Qwaz

ok, mais petite question, si j'active cette fonction et que j'envois mon fichier a un autre persone, est-ce qu'elle va etre activité automatiquement dans son Excel car activité dans le classeur , ou toute les personnes qui vont utiliser mon fichier devront l'activité manuellement?

merci :)

hello,

Citation:

Envoyé par bibimtl2x

ok, mais petite question, si j'active cette fonction et que j'envois mon fichier a un autre persone, est-ce qu'elle va etre activité automatiquement dans son Excel car activité dans le classeur , ou toute les personnes qui vont utiliser mon fichier devront l'activité manuellement?

merci :)

Il y a toujours possibilité d'utiliser ce qu'on appelle du Late Binding. Dans ce cas on est plus obligé de cocher la référence dans Outils/Références. Voici un exemple pour le DataObject (L' ID classe (CLSID) pour le Microsoft Forms 2.0 DataObject est “1C3B4210-F441-11CE-B9EA-00AA006B1A69”) :
Code:

1 2 3 4 5 6 7 8 9 Sub TestClipboard() Dim StrClip Dim ClipBoardData As Object Set ClipBoardData = CreateObject("New:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}") ClipBoardData.GetFromClipboard 'On récupère le contenu text du clipboard StrClip = ClipBoardData.GetText(1) 'L Debug.Print StrClip End Sub
Mais dans ce cas on travaille un peu "en aveugle" car on a pas la complétion de l'objet ClipBoardData dans l'éditeur de code.

Ami calmant, J.P

05/01/2022, 20h42
Qwazerty

Salut

Je plussoie la réponse de jurassic pork, et en complément je dirais que pour avoir le bénéfice des deux, tu peux travailler sur ton fichier en earlybinding (en activant la réf), ça permet d'avoir l’autocomplétion du code... Puis avant de transmettre le fichier modifier en Late Binding (modifier le As New DataObject en As Object et activer la ligne
Set ClipBoardData = CreateObject("New:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}") qui sera mise en commentaire lorsque tu développes ton fichier en Early Binding.

Je crois qu'il existe une solution pour le faire semi automatiquement en utilisant un paramètre de fichier et les #If...#Else... #End if.

++
Qwaz

mais là mon code c'est quoi? J'ai essayé ça, mais j'ai juste des erreurs. Et j'ai essayé juste le nouveau code et ça fait rien du tout :(

merci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
Dim StrClip As String
 
    'On vérifie que la cellule modifiée se trouve dans la colonne B
    If Not Application.Intersect(Target, Range("B:B")) Is Nothing Then
       Sub TestClipboard()
Dim StrClip
Dim ClipBoardData As Object
Set ClipBoardData = CreateObject("New:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
ClipBoardData.GetFromClipboard
'On récupère le contenu text du clipboard
StrClip = ClipBoardData.GetText(1) 'L
Debug.Print StrClip
End Sub
  End If
 
End Sub

Salut

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_Change(ByVal Target As Range)
Dim ClipBoardData As Object 'DataObject
Dim StrClip As String
 
    'On vérifie que la cellule modifiée se trouve dans la colonne B
    If Not Application.Intersect(Target, Range("B:B")) Is Nothing Then
        'On déclare une nouvelle instance DataObject
        'Set ClipBoardData = New DataObject
        Set ClipBoardData = CreateObject("New:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
        'On charge le contenu du ClipBord
        ClipBoardData.GetFromClipboard
        'On récupère le contenu text du clipboard
        StrClip = ClipBoardData.GetText(1) 'Le 1 correspond à un contenu textuel
        'On pointe la cellule de la colonne A qui se trouve sur la même ligne que la cellule modifiée
        'Et on y place la valeur extrait du Clipboard
        Target.Offset(ColumnOffset:=-1).Value = StrClip
  End If
 
End Sub

A placer dans le code de ta feuille.

++
Qwaz

07/01/2022, 21h00
bibimtl2x

je ne peux que me prosterner devant un tel savoir! :) un gros merci.. :) Ça semble marcher #1:) merci!!!!!