autocomplétion avec combobox

Version imprimable

15/10/2021, 16h59
pagololo

1 pièce(s) jointe(s)

autocomplétion avec combobox

Bonjour, cela fait plusieurs semaines que je galère pour trouver le bon code VBA.
je suis novice en programmation VBA.
Je m 'explique. J'ai sur la feuil1 deux listes(une de chanteurs et l'autre de chansons), je vous rassure c'est juste pour l'exemple :lol:, et je souhaite utiliser ces 2 listes séparées en menu déroulant dans la feuil2 dans 2 colonnes qui ne se suivent pas et le tout en autocomplétion.
J'avais pourtant bien commencer en trouvant comment créer une combobox avec un code bva. Mais cela ne fonctionne qu'avec une seule liste. Dès que j'essaie de créer une 2nde Combobox, je me retrouve avec un message d'erreur sur la macro.
J'ai vu qu'effectivement on ne peut créer qu un Selection Change par feuille.
Je suis tombé sur le site de Boisgontier qui propose des menus déroulants avec combobox. J'avais pensé avoir enfin trouvé, mais le problème c'est que cela ne fonctionne que si les menus déroulants se trouvent l'un à côté de l'autre(ex=colonne A et B ou B et C....).
J'espère avoir été assez clair.
Si quelqu’un à une idée??
Merci.
Je vous joins le fichier...

1 pièce(s) jointe(s)

Bonjour,

Un début de solution, adaptée du code donné par Boisgontierj:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Option Explicit
 
'--- adapté de http://boisgontierj.free.fr/
 
Dim a()
Dim kR As Long
 
'--- suppose que tous les tableaux ont une ligne de titres en ligne n°1
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Target.Row > 1 And (Target.Column = 2 Or Target.Column = 6) Then
        If Target.Column = 2 Then
            a = Worksheets("Feuil1").Range("zChanteurs").Value
        Else
            a = Worksheets("Feuil1").Range("zChansons").Value
        End If
        Me.ComboBox1.List = a
        Me.ComboBox1.Height = Target.Height + 2
        Me.ComboBox1.Width = Target.Width + 15
        Me.ComboBox1.Top = Target.Top
        Me.ComboBox1.Left = Target.Left
        Me.ComboBox1 = Target
        Me.ComboBox1.Visible = True
        Me.ComboBox1.Activate
    Else
        Me.ComboBox1.Visible = False
    End If
End Sub
 
Private Sub ComboBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Me.ComboBox1.List = a
    Me.ComboBox1.Activate
    Me.ComboBox1.DropDown
End Sub
 
Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If Shift = 2 Then                   '--- touche Ctrl
        kR = ActiveCell.Row - 1         '--- n° ligne dans tableau
        If KeyCode = 109 Then           '--- touche  -
            '--- supprime ligne du tableau sur frappe de Ctrl -
            On Error Resume Next        '--- erreur si hors tableau
            Selection.ListObject.ListRows(kR).Delete
            Me.ComboBox1 = ActiveCell.Value
        ElseIf KeyCode = 107 Then       '--- touche  +
            '--- ajoute ligne au tableau sur frappe de Ctrl +
            On Error Resume Next        '--- erreur si hors tableau
            Selection.ListObject.ListRows.Add (kR)
        End If
    Else
        ActiveCell.Value = Me.ComboBox1
        If KeyCode = 13 Then            '--- touche Entrée
            ActiveCell.Offset(1).Select
        End If
    End If
End Sub

A mon avis cette solution n'est cependant pas optimale. A adapter, et voir à l'usage.
Cordialement.

20/10/2021, 15h53
pagololo

Bonjour, déjà, merci beaucoup de vous intéresser à mon problème.
Je jette un œil, et je vous donne mon retour.
Merci
20/10/2021, 16h36
pagololo

Je viens de tester la macro sur le fichier original, et ça marche nickel!!!
Super !!! Merci beaucoup!!