Message erreur lister des fichier txt dans un dossier

Version imprimable

Bonjour,

j'arrive pas comprendre pourquoi, il m'affiche une message erreur en listent des fichiers textes dans un dossier?

Citation:

_____________________________________
lecture du fichier text
_____________________________________

1: 0.txt
2: 1.txt
3: 10.txt
4: 2.txt
5: 3.txt
6: 4.txt
7: 5.txt
8: 6.txt
9: 7.txt
10: 8.txt
11: 9.txt
_____________________________________
Erreur*: Les choix en double ne sont pas autorisés.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 cls echo _____________________________________ echo lecture du fichier texte echo _____________________________________ echo. set "$c=1" set "$l=" FOR /F "delims=" %%f in ('dir /S /B %$path%') do ( set FILEPATH=%%~nxf set $array[!$c!]="%%~dpnxf" echo !$c!: !FILEPATH! set $l=!$l!!$c! set /a $c+=1 ) echo _____________________________________ choice /c !$l! pause
je voudrais savoir comment corriger ce problème du message erreur en listent les fichiers textes? Merci d'avance

03/09/2021, 18h52
ericlm128
C'est la commande choice, la liste des choix que tu lui passe est invalide.
Le choix 10 n'est pas valide et est interprété comme 2 choix le 1 et le 0 que tu as déjà définit.
Code:

1 2 Les caractères de choix valides sont : a-z, A-Z, 0-9 et les valeurs ASCII de 128 à 254.

Bonjour,

ericlm128 merci d'avoir répondu à ma question. je viens trouver la solution à mon problème avec quelque recherche :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
ECHO OFF
setlocal enabledelayedexpansion
Title compter key
mode 100,25 & color 0A
set "$path=KeyFile\*.txt"
dir %$path% >nul 2>nul && goto:start || goto:Erreur
:Erreur
echo il y a pas de fichier text dans le dossier KeyFile.
Pause
exit
:start
cls
echo _____________________________________
echo     lecture du fichier text         
echo _____________________________________
echo.
set "allchoices=0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set "count=0"
FOR /F "delims=" %%f  in ('dir /S /B %$path%') do (
	set FILEPATH=%%~nxf
	call echo %%allchoices:~!count!,1%%: !FILEPATH!
	set /a count+=1
	set $array[!count!]="%%~dpnxf"
)
set "$l=!allchoices:~0,%count%!"
echo _________________________________________________
choice /c %$l% /m "Veuillez choisir un chiffre ou une lettre :"
call:traitement !$array[%errorlevel%]!
exit/b
 
:traitement
cls
echo Traitement de =^> "%~1"
pause
goto start

Merci encore ericlm128.