Vérifier si le VPN est utilisé

Bonjour le Forum,

J'ai un code qui permet de savoir si le VPN est actif mais pour qu'il fonctionne il faut le nom du VPN, mais je ne le trouve pas, j'ai essayé plusieurs noms que j'ai pris dans les processus en cours Windows ou sur Reseau mais sans succès.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
  Private Sub CheckVPN()
        Dim nics As NetworkInterface() = NetworkInterface.GetAllNetworkInterfaces
        Dim isVpnExist As Boolean = nics.AsEnumerable().Any(Function(x) x.Name = "Cisco AnyConnect ")
        If isVpnExist Then
            ' vpn exist do something
            MsgBox("VPN Actif")
        Else
 
            ' vpn is not exist do something
            MsgBox("No VPN")
        End If
    End Sub

Merci pour votre aide.

Bonjour,

Tu peux utiliser les objets et requêtes WMI afin d'obtenir les informations sur ta carte réseau virtuelle :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
  Public Function IsNetworkAvailableFromWMI()
        If Not NetworkInterface.GetIsNetworkAvailable() Then Return False
        Using objMC As ManagementClass = New ManagementClass("Win32_NetworkAdapter")
            Dim objMOC As ManagementObjectCollection = objMC.GetInstances()
 
            For Each objMO As ManagementObject In objMOC
                If objMO("NetEnabled") Then
                    Try
                        If objMO("Description").ToLower.Contains("virtual") OrElse objMO("Name").ToLower.Contains("virtual") Then
                            If objMO("Manufacturer").ToLower.Contains("cisco") Then
                                MsgBox(objMO("Description") & vbNewLine & objMO("Name"))
                                Return True
                            End If
                        End If
                    Catch ex As Exception
                        MsgBox("Exception : " & ex.Message)
                    End Try
                End If
            Next
        End Using
        Return False
    End Function

So tu veux utiliser la classe NetworkInterface alors tu peux essayer de faire comme ceci mais s'il existe plus d'une carte réseau virtuelle alors ca risque de poser problème :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
  Public Function IsNetworkAvailable() As Boolean
        If Not NetworkInterface.GetIsNetworkAvailable() Then Return False
        For Each ni As NetworkInterface In NetworkInterface.GetAllNetworkInterfaces()
            If ni.OperationalStatus = OperationalStatus.Up Then
                If (ni.NetworkInterfaceType <> NetworkInterfaceType.Loopback) Then
                    If ni.Description.ToLower.Contains("virtual") OrElse ni.Name.ToLower.Contains("virtual") Then
                        MsgBox(ni.Description & vbNewLine & ni.Name)
                        Return True
                    End If
                End If
            End If
        Next
 
        Return False
    End Function

L'outil portable WMICodeCreator permet de lister les classes afin d'obtenir les propriétés disponibles : https://www.microsoft.com/en-us/down...s.aspx?id=8572

Bon codage++

Bonjour Wallace1,

Merci grâce à vous j'ai pu trouver ma carte réseau VPN.

Au Top!!