The process cannot access the file because it is being used by another process.

Version imprimable

Bonjour.

je n'arrive pas à debuguer ce court script :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
@echo off
 
set logs="logs_tests.txt"
if exist %logs% (del %logs%)
 
call :FONCTION_TIME  >> %logs%
echo Debut du test - %JOUR%/%MOIS%/%ANNEE% %HEURE%:%MINUT% >> %logs%
 
 
if "%1"=="" (goto ERROR_PARAM) else (set "civilite=%1")
 
echo "A1" >> %logs%
 
if "%civilite%"=="Bonjour" 
	(echo "%civilite%" >> %logs%) 
else 
	(echo "Tu pourrais dire bonjour" >> %logs%)
 
echo Fin du test - %JOUR%/%MOIS%/%ANNEE% %HEURE%:%MINUT% >> %logs%
 
goto END
 
:FONCTION_TIME
rem Constitution de la date d execution
rem  Il faut faire attention a la valeur de tokens (elle est a 1 pour win. serveur2003 et a 2 pour win 2000)
for /f "tokens=1" %%i in ('date /t') do set DATEJ=%%i
set DATEJ=%DATEJ:/=%
set JOUR=%DATEJ:~0,2%
set MOIS=%DATEJ:~2,2%
set ANNEE=%DATEJ:~4,4%
rem Constitution de l'heure et minute d execution
for /f "tokens=1" %%i in ('time /t') do set TIMEJ=%%i
set TIMEJ=%TIMEJ:/=%
set HEURE=%TIMEJ:~0,2%
set MINUT=%TIMEJ:~3,2%
 
:ERROR_PARAM
ECHO "Parametre attendu : ProduitLogicielVersion" >> %logs%
goto END
 
:END
call :FONCTION_TIME
echo Fin du packaging - %JOUR%/%MOIS%/%ANNEE% %HEURE%:%MINUT% >> %logs%
rem on affiche le fichier de log dans la console
exit /B 0

La console m'affiche :

Citation:

The process cannot access the file because it is being used by another process.

Et le fichier de log logs_tests.txt ne contient que :

Citation:

Terminate batch job (Y/N)?

Pouvez vous m'aider SVP ?

09/07/2021, 18h21
barnabe0057

Bonjour,

J'ai l'impression que ta fonction :FONCTION_TIME tourne en boucle à cause du call dans le label :END
10/07/2021, 10h23
69Pierre
Bonjour barnabe.

effectivement, il y a une fonction qui boucle.

Comment l'arrêter sans la supprimer ?

J'ai en plus un syntaxe incorrecte à ce niveau :
Code:

1 2 3 4 if "%civilite%==Bonjour" (echo "%civilite%" >> %logs%) else (echo "Tu pourrais dire bonjour" >> %logs%)

Essaie comme ça :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
@echo off
setlocal enabledelayedexpansion
 
set logs="logs_tests.txt"
if exist %logs% (del %logs%)
 
call :FONCTION_TIME >> %logs%
echo Debut du test - !JJMMAAAA! !HHMM! >> %logs%
 
if "%~1"=="" (goto ERROR_PARAM) else (set "civilite=%~1")
 
echo "A1" >> %logs%
 
(if /i "!civilite!"=="Bonjour" (echo "!civilite!") else (echo "Tu pourrais dire bonjour")) >> %logs%
 
echo Fin du test - !JJMMAAAA! !HHMM! >> %logs%
 
goto END
 
:ERROR_PARAM
ECHO "Parametre attendu : ProduitLogicielVersion" >> %logs%
 
:END
call :FONCTION_TIME
echo Fin du packaging - !JJMMAAAA! !HHMM! >> %logs%
rem on affiche le fichier de log dans la console
exit /B 0
 
:FONCTION_TIME
 
rem Constitution de la date d execution
for /f "tokens=1-2" %%i in ('date /t') do if not "%%j"=="" (set "JJMMAAAA=%%j") else (set "JJMMAAAA=%%i")
 
rem Constitution de l'heure et minute d execution
for /f "tokens=1" %%i in ('time /t') do set "HHMM=%%i"
set "HHMM=!HHMM:/=:!"
 
GOTO :EOF

10/07/2021, 18h07
69Pierre

Tu m'épates.

Tu peux me donner quelques explications sur ce qui marchait mal et pourquoi ça marche maintenant STP ?
10/07/2021, 18h39
barnabe0057

Comme déjà dit, le gros point noir était la fonction qui se baladait en plein milieu du script, sans commande pour en sortir (goto :eof ou bien exit), avec une combinaison bizarre de call et goto qui formaient une boucle infinie.

Une fois les legos remis dans l'ordre, j'ai fait quelques optimisations sans grande importance à part peut-être au niveau de la variable civilite et %1, connais-tu la différence entre %1 et %~1 ?
10/07/2021, 18h54
69Pierre

Citation:

Envoyé par barnabe0057

Comme déjà dit, le gros point noir était la fonction qui se baladait en plein milieu du script, sans commande pour en sortir (goto :eof ou bien exit), avec une combinaison bizarre de call et goto qui formaient une boucle infinie.

Une fois les legos remis dans l'ordre, j'ai fait quelques optimisations sans grande importance à part peut-être au niveau de la variable civilite et %1, connais-tu la différence entre %1 et %~1 ?

Je vais voir pour les lego en comparant.

pour la différence entre %1 et %~1, non, je ne connais pas la différence. %~1 enlève peut être des caractères comme "" ou des espaces avant ou après l'expression à évaluer ?
10/07/2021, 19h15
barnabe0057

Exactement, %~1 enlève d'éventuelles double-quotes. Vu qu'on ne peut pas toujours savoir à l'avance si %1 en contiendra, pour rester maître du jeu il vaut mieux préférer %~1 ou "%~1" à %1, ça évite le scénario où l'on se retrouve avec 2 paires de double-quotes qui font planter le script.
10/07/2021, 19h20
69Pierre

Et bien merci et bonne fin de week-end.
10/07/2021, 19h53
barnabe0057

Merci pareillement.