dsquery group avec attributs

Version imprimable

08/06/2021, 08h45
SylvainM

dsquery group avec attributs
Bonjour à tous,

Je souhaite exporter la liste des membres d'un groupe AD.
Je viens d'y parvenir avec cette commande :
Code:

1 2 dsquery group -name "groupname" | dsget group -members > C:\memberlist.txt
Voici le contenu de mon memberlist.txt :
Code:

1 2 "CN=NOM1\, Prénom1 (identifiant1),OU=GRP01,OU=Utilisateurs,DC=DOMAINE,DC=fr" "CN=NOM2\, Prénom2 (identifiant2),OU=GRP01,OU=Utilisateurs,DC=DOMAINE,DC=fr"
Mais j'aimerais avoir tous les attributs des membres (e-mail, téléphone, ...), avec pour objectif ultime de créer des vcard pour import dans répertoire téléphonique.

Est-il possible d'ajouter des attributs à l'export des membres d'un groupe AD ?

Merci pour vos conseils et votre indulgence ! ;)

Sylvain M.
08/06/2021, 10h57
barnabe0057

Bonjour,

Je n'ai pas testé mais voilà comment je vois les choses :

Code:

dsget group "groupname" -members | dsget user -dn -samid -sid -upn -fn -mi -ln -display -empid -desc -office -tel -email -hometel -pager -mobile -fax -iptel -webpg -title -dept -company -mgr -hmdir -hmdrv -profile -loscr -mustchpwd -canchpwd -pwdneverexpires -disabled -acctexpires -reversiblepwd > C:\memberlist.txt

Merci pour ton aide, Barnabe :)

Malheureusement, voici la réponse que j'obtiens :
Code:

1 2 3 dsget a échoué*: Le format de la valeur de «*Objet cible pour cette commande*» est incorrect. Entrez dsget /? pour afficher l’aide.dsget a échoué*: «*Objet cible pour cette commande*» est manquant. Entrez dsget /? pour afficher l’aide.
Je continue de chercher, mais tu verras peut-être plus vite que moi le pb et/ou la solution :)

08/06/2021, 11h19
SylvainM

C'est bon : je viens de trouver !!

Code:

dsquery group -name "groupname" | dsget group -members | dsget user -dn -samid -sid -upn -fn -mi -ln -display -empid -desc -office -tel -email -hometel -pager -mobile -fax -iptel -webpg -title -dept -company -mgr -hmdir -hmdrv -profile -loscr -mustchpwd -canchpwd -pwdneverexpires -disabled -acctexpires -reversiblepwd > C:\memberlist.txt

Il suffisait d’enchaîner les deux !

MERCI !!! :D
08/06/2021, 11h20
barnabe0057

Ok super ! N'oublie pas de passer le sujet en "résolu"
08/06/2021, 11h46
SylvainM

Citation:

N'oublie pas de passer le sujet en "résolu"

C'est fait !

Mais je me permets quand même une petite question "bonus" : le résultat de l'export est en texte, sans délimiteurs (CSV avec séparateur ; ou TAB).
Est-ce possible de passer le résultat avec un séparateur ?
08/06/2021, 11h56
barnabe0057

Non je ne vois pas d'option pour le faire.

Si tu me donnes quelques lignes de ton fichier je peux peut-être trouver une solution.
08/06/2021, 12h24
SylvainM

OK, je te l'envoie en MP.
Merci à toi :D
08/06/2021, 13h23
barnabe0057

J'ai peut-être trouvé une solution via l'utilitaire nommé CSVDE, je te laisse tester : https://serverfault.com/questions/43...miliar-with-ds
08/06/2021, 14h36
SylvainM

Citation:

Envoyé par barnabe0057

J'ai peut-être trouvé une solution via l'utilitaire nommé CSVDE

Merci ! :D
C'est vrai que ça a l'air bien plus efficace pour mon besoin.

Par contre, j'ai bien réussi à filtrer par un attribut (-r "(&(objectClass=user)(title=Titre*))" ), mais pas à récupérer les membres d'un groupe comme je le faisais avec dsquery/dsget (dsget group -members)

Si tu as une idée ?

Non je n'ai pas d'idée.

Pour en revenir à dsquery / dsget j'ai pensé à une méthode "bourrin" qui consiste à récupérer chaque attribut séparément puis à construire ton propre .csv

Dans cette optique j'ai concocté ce script, mais je ne peux pas le tester donc je compte sur toi pour les retours d'infos :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 @echo off setlocal enableextensions enabledelayedexpansion type nul > C:\groupe.csv for f "delims=" %%P in ('dsquery group -name "nom_groupe" ^| dsget group -members') do call :attributs "%%~P" pause exit :attributs set "ligne_csv=" for %%A in (dn samid sid fn mi ln display empid desc office tel email hometel pager mobile title dept company) do ( set "valeur=" for f "skip=1 delims=" %%E in ('dsget user "%~1" -%%A') do if not defined valeur (set "valeur=%%E") set "ligne_csv=!ligne_csv!;!valeur!" ) echo.!ligne_csv:~1!;>> C:\groupe.csv goto :eof
N'oublie pas de modifier le nom du groupe dans le premier FOR.

Je ne m'attends pas à ce que ça fonctionne parfaitement du premier coup, mais si on s'y met à 2 on va vite arriver au résultat attendu.

08/06/2021, 16h35
SylvainM

Merci Barnabe !

Malheureusement, le fichier C:\groupe.csv est bien créé, mais vide...
Et comme je ne vois pas ce qui se passe, je ne sais pas trop pourquoi...

Si je veux voir le déroulé, je peux enlever @echo off, c'est bien ça ?

PS. : j'ai tenté, mais je ne vois toujours pas le déroulé des opérations quand je l’exécute (depuis un .BAT).

Ok on va déjà tester la première partie :
Code:

1 2 3 4 5 6 7 8 9 @echo off setlocal enableextensions enabledelayedexpansion type nul > C:\groupe.csv for f "delims=" %%P in ('dsquery group -name "nom_groupe" ^| dsget group -members') do echo call :attributs "%%~P" pause exit
Qu'obtiens-tu comme sortie ? Répond en MP si c'est confidentiel.

08/06/2021, 18h45
SylvainM

Citation:

Qu'obtiens-tu comme sortie ?

Rien de confidentiel... puisque le fichier "groupe.csv" est vide (0Ko)... :aie:
08/06/2021, 18h48
barnabe0057

Ah excuse-moi je voulais dire qu'obtiens-tu dans la console. Pas dans le fichier.
08/06/2021, 18h52
SylvainM

Ne te moque pas de moi ... :aie:
Je ne sais pas comment récupérer le contenu de la console : j'execute le BAT, mais directement depuis l'explorateur...
Pour avoir la console, tu me conseilles quel utilitaire(s) ?
08/06/2021, 18h57
barnabe0057

Je n'oserais pas :D

Tu le lances depuis l'explorateur, c'est parfait.

Vu que j'ai mis une commande PAUSE à la fin du script, normalement la fenêtre noire devrait rester ouverte, ce n'est pas le cas ?
09/06/2021, 12h01
SylvainM

Bonjour Barnabé, et désolé pour le délai de réponse (d'ailleurs, ne t'en étonne pas par la suite, je suis sur plein d'autres sujets en même temps !)

Citation:

Vu que j'ai mis une commande PAUSE à la fin du script, normalement la fenêtre noire devrait rester ouverte, ce n'est pas le cas ?

Etrangement, en effet, ce n'est pas le cas !?

J'ai supprimé le exit de la fin, mais idem, la fenêtre DOS se ferme, le fichier est créé, mais vide...

:aie:

Bonjour, je viens de repérer une faute de frappe qui explique pourquoi la fenêtre ne reste pas ouverte, voilà la correction :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
setlocal enableextensions enabledelayedexpansion
 
type nul > C:\groupe.csv
 
for /f "delims=" %%P in ('dsquery group -name "nom_groupe" ^| dsget group -members') do call :attributs "%%~P"
 
pause
exit
 
:attributs
 
set "ligne_csv="
 
for %%A in (dn samid sid fn mi ln display empid desc office tel email hometel pager mobile title dept company) do (
 
	set "valeur="
	for /f "skip=1 delims=" %%E in ('dsget user "%~1" -%%A') do if not defined valeur (set "valeur=%%E")
	set "ligne_csv=!ligne_csv!;!valeur!"
 
)
 
echo.!ligne_csv:~1!;>> C:\groupe.csv
 
goto :eof

N'oublie pas de modifier le nom du groupe dans le premier FOR.

Si tu n'obtiens toujours rien, il faudra tester la première partie pour commencer :

Code:

1
2
3
4
5
6
7
8
9
@echo off
setlocal enableextensions enabledelayedexpansion
 
type nul > C:\groupe.csv
 
for /f "delims=" %%P in ('dsquery group -name "nom_groupe" ^| dsget group -members') do echo %%P
 
pause
exit

09/06/2021, 12h22
SylvainM

Je viens de tester les 2 codes.
Le 1er créé le fichier CSV vide, et reste bloqué sur un écran noir.
Le 2nd affiche les membres dans la fenêtre DOS (tous les DN du groupe), créé le fichier CSV, mais vide lui aussi.
Merci pour ton aide, mais de mon côté je ne peux pas vraiment identifier le PB.
Tu as des conseils sur une console pour exécuter les BAT ?
09/06/2021, 12h30
barnabe0057

Je ne l'utilise plus depuis longtemps mais si tu veux une console tu peux utiliser Powerbatch

Ok donc la première partie fonctionne.
Maintenant on va essayer de tester l'autre partie.

Si tu prends au hasard un des résultats renvoyés par la première partie que tu insères dans cette commande :

Code:

dsget user "résultat de la 1ère partie" -email

Est-ce que tu obtiens bien un email en sortie ?

Voila ce que j'ai tenté et le résultat :

Code:

1
2
3
dsget user "CN=NOMMAJUSCULE\\, Prenom (id_ldap),OU=TRUC,OU=Utilisateurs,DC=DOMAINE,DC=fr" -email
dsget a échoué*: Le format de la valeur de «*Objet cible pour cette commande*» est incorrect.
Entrez dsget /? pour afficher l’aide.

09/06/2021, 15h52
barnabe0057

Super on a trouvé l'erreur, reste plus qu'à trouver comment faire marcher cette commande.
Il faut que tu essaies en modifiant le DN jusqu'à ce que ça fonctionne.

edit : j'ai trouvé le bon format pour indiquer le DN : "CN=Mike Danseglio,CN=users,dc=ms,dc=tld"
Il faut juste que j'arrive à transformer la partie gauche du DN puis je reviens vers toi.
09/06/2021, 16h23
SylvainM

Citation:

Il faut juste que j'arrive à transformer la partie gauche du DN puis je reviens vers toi.

MERCI !!! :D

Pour info, dans mon cas, j'ai 4 DC (Domain Component) :

Code:

DC=SOUS-SOUS-DOMAINE,DC=SOUS-DOMAINE,DC=DOMAINE,DC=fr

J'ai fini de modifier le script, je te laisse procéder au crash test ;)

Tu peux exécuter le script tel quel, il n'y a rien à modifier :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
@echo off
setlocal enableextensions enabledelayedexpansion
 
type nul > C:\groupe.csv
 
:saisie
set "groupe="
echo. & set /p groupe="Veuillez indiquer le nom du groupe à traiter : "
if not defined groupe (goto :saisie)
 
for /f "delims=" %%P in ('dsquery group -name "%groupe%" ^| dsget group -members') do call :attributs "%%~P"
 
echo. & pause
exit
 
:attributs
 
call :conversion %1
echo. & echo ^>^>^>^>^> Extraction des attributs de !prenom! !nom! en cours ...
set "ligne_csv="
 
for %%A in (dn samid sid fn mi ln display empid desc office tel email hometel pager mobile title dept company) do (
 
	set "valeur="
	for /f "skip=1 delims=" %%E in ('dsget user "CN=!prenom! !nom!,!OU_domaine!" -%%A') do if not defined valeur (set "valeur=%%E")
	set "ligne_csv=!ligne_csv!;!valeur!"
 
)
 
echo.!ligne_csv:~1!;>> C:\groupe.csv
goto :eof
 
:conversion
 
set "nom="
set "partie2="
set "OU_domaine="
set "prenom="
set "DN="
 
for /f "tokens=1,2,* delims=," %%A in (%1) do (
 
	set "nom=%%A"
	set "nom=!nom:~3!"
	set "nom=!nom:\=!"
	set "partie2=%%B"
	set "OU_domaine=%%C"
 
)
 
for /f "tokens=1 delims=( " %%A in ("!partie2!") do (
 
	set "prenom=%%A"
	set "prenom=!prenom: =!"
 
)
goto :eof

09/06/2021, 16h58
SylvainM

1 pièce(s) jointe(s)
Voici le résultat :
Pièce jointe 599488
Remplacer le trait rouge par "Prénom NOM"

Contenu du CSV (autant de ligne que de membres du groupe) :
Code:

1 2 3 4 5 6 ;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;
09/06/2021, 17h07
barnabe0057

Ok cette commande va nous faire transpirer jusqu'au bout :aie:

Ca donne quoi si tu essaies manuellement juste la commande DSGET USER :
dsget user "CN=Prénom NOM,OU=Utilisateurs,DC=SOUS-SOUS-DOMAINE,DC=SOUS-DOMAINE,DC=DOMAINE,DC=fr"
14/06/2021, 10h55
SylvainM
Désolé pour le délai, comme je te le disais, plein d'autres sujets plus urgents à traiter...

Citation:

Ca donne quoi si tu essaies manuellement juste la commande DSGET USER :
dsget user "CN=Prénom NOM,OU=Utilisateurs,DC=SOUS-SOUS-DOMAINE,DC=SOUS-DOMAINE,DC=DOMAINE,DC=fr"

Voici la réponse :
Code:

1 2 3 dsget a échoué*: Le format de la valeur de «*Objet cible pour cette commande*» e st incorrect. Entrez dsget /? pour afficher l'aide.
Je suis désolé de te faire perdre du temps sur ce problème, d'autant plus que la commande avec CSVDE est quasiment arrivée à répondre à ma demande.
J'ai contourné l'impossibilité de récupérer les membres du groupe, par un filtrage sur un autre critère qui me donne bien en CSV les personnes dont j'ai besoin.

Sâchant que l'objectif final est d'écrire un fichier Vcard VCF (https://fr.wikipedia.org/wiki/VCard) de ces contacts, et que ça va pas être si facile pour moi, je me dis que le code que tu as commencé pourrait directement écrire le VCF plutôt que de passer par l'intermédiaire du CSV ?

Mais peut-être que ce script a déjà été réalisé ? (pas encore trouvé, mais ça m'étonnerait d'être le seul avec ce besoin)

Pour information, concernant la partie "conversion CSV > VCF", je suis parti sur l'option de le faire via
- un import en BDD (SQLite) car le SQL est le seul langage que le maitrise (étant en réalité géomaticien ;) )
- une requête SQL pour convertir les noms des attributs LDAP en champs "Google Contact"
- un import CSV (avec champs modifiés) dans Google Contacts puis export en VCARD (VCF) via la fonction disponible de Google Contacts

Bien sûr, il serait plus satisfaisant de le faire directement sans passer par des outils tiers (SQLite et encore plus Google !), mais ça marche bien et c'est "répétable" rapidement pour moi.

Voici ma requête de conversion, pour info :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 SELECT displayName as 'Name', givenName as 'Given Name', sn as 'Family Name', personalTitle as 'Name Prefix', l as 'Location', '* Professionnel' as 'E-mail 1 - Type', mail as 'E-mail 1 - Value', sAMAccountName as 'IM 1 - Value', 'Mobile' as 'Phone 1 - Type', mobile as 'Phone 1 - Value', 'Work' as 'Phone 2 - Type', telephoneNumber as 'Phone 2 - Value', 'Professionnel' as 'Address 1 - Type', extensionAttribute6 as 'Address 1 - Formatted', 'Ma Structure' as 'Organization 1 - Name', title as 'Organization 1 - Title', department as 'Organization 1 - Department' FROM csvde_ldap_export

Bonjour,

Excellent tu as trouvé une solution, même si ce n'est pas l'idéal.

Ca n'a pas l'air sorcier de fabriquer un fichier Vcard à partir des informations récupérées dans l'AD, encore faudrait-il que j'arrive à faire fonctionner cette foutue commande.
J'ai une dernière idée, est-ce que tu pourrais tester ceci :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@echo off
setlocal enableextensions enabledelayedexpansion
 
type nul > C:\groupe.csv
 
:saisie
set "groupe="
echo. & set /p groupe="Veuillez indiquer le nom du groupe à traiter : "
if not defined groupe (goto :saisie)
 
for /f "delims=" %%P in ('dsquery group -name "%groupe%" ^| dsget group -members') do call :attributs "%%~P"
 
echo. & pause
exit
 
:attributs
 
echo. & echo ^>^>^>^>^> Extraction des attributs en cours ...
echo.
set "ligne_csv="
 
for %%A in (dn samid sid fn mi ln display empid desc office tel email hometel pager mobile title dept company) do (
 
	set "valeur="
	for /f "skip=1 delims=" %%E in ('echo %1^| dsget user -%%A') do if not defined valeur (set "valeur=%%E")
	set "ligne_csv=!ligne_csv!;!valeur!"
 
)
 
echo.!ligne_csv:~1!;>> C:\groupe.csv
goto :eof

Fuseau horaire GMT +2. Il est actuellement 16h40.