[XL-365] Combobox VBA - Filtrer commerciaux Agence sélectionnée

1 pièce(s) jointe(s)

Combobox VBA - Filtrer commerciaux Agence sélectionnée

Bonjour,

Je me suis embrouiller dans l'avancement de mon projet et je bloque :

J'ai un formulaire avec une combobox qui affiche la liste de mes commerciaux

J'aimerai ajouter une deuxième combobox qui m'affiche la liste de mes agences et que quand je choisis une agence , la combobox des commerciaux affiche seulement les commerciaux de l'agence choisie.

J'ai regardé du côté des filtres mais je n'y arrive pas .

Un âme charitable pour me donner une piste de réflexion ou me montrer la démarche à suivre à l'aide de mon petit fichier

Merci à vous :)

Pièce jointe 597432

Citation:

Envoyé par Warnex75

Bonjour,

Si j'avais à faire cela, je transformerais votre table en tableau structuré (TableDesCommerciaux) et j'ajouterais une table des agences (TableDesAgences).
J'ajouterais une colonne Nom prénom qui sera utilisée dans le userform. Perso, je préfère utiliser une ListBox plutôt qu'une ComboBox.
Les deux tables sont triées.

Pièce jointe 597445

Dans un module standard :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Option Explicit
 
Public AireNomPrenom As Range, AireAgence As Range
 
Sub LancerLeUserform()
 
   Set AireNomPrenom = Range("TableDesCommerciaux[Nom prénom]")
   Set AireAgence = Range("TableDesCommerciaux[Agence]")
 
 
    With UserForm1
         .ComboBoxAgence.List = Range("TableDesAgences").Value
         .Show
    End With
 
   Set AireNomPrenom = Nothing
   Set AireAgence = Nothing
 
End Sub

Dans le module du Userform :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
 
Option Explicit
 
Private Sub ComboBoxAgence_Change()
 
Dim I As Integer
 
    Me.ComboBoxCommerciaux.Clear
    Me.ListBoxCommerciaux.Clear
 
   For I = 1 To AireNomPrenom.Count
       With AireNomPrenom(I)
            If AireAgence(I) = Me.ComboBoxAgence Then
               ComboBoxCommerciaux.AddItem AireNomPrenom(I)
               ListBoxCommerciaux.AddItem AireNomPrenom(I)
            End If
       End With
   Next I
 
End Sub
 
Private Sub ComboBoxCommerciaux_Change()
 
Dim I As Integer
 
   For I = 1 To AireNomPrenom.Count
       With AireNomPrenom(I)
            If .Value = ComboBoxCommerciaux.Value Then
               Me.LabelMatricule = AireNomPrenom(I).Offset(0, 1)
               Me.LabelNom = AireNomPrenom(I).Offset(0, 2)
               Me.LabelPrenom = AireNomPrenom(I).Offset(0, 3)
            End If
       End With
   Next I
 
 
 
End Sub
 
Private Sub ListBoxCommerciaux_Click()
 
Dim I As Integer
 
   For I = 1 To AireNomPrenom.Count
       With AireNomPrenom(I)
            If .Value = Me.ListBoxCommerciaux.Value Then
               Me.LabelMatricule = AireNomPrenom(I).Offset(0, 1)
               Me.LabelNom = AireNomPrenom(I).Offset(0, 2)
               Me.LabelPrenom = AireNomPrenom(I).Offset(0, 3)
            End If
       End With
   Next I
 
End Sub

Dans le module de l'onglet Feuil1 :

Code:

1
2
3
4
5
6
 
Option Explicit
 
Private Sub BoutonLancer_Click()
        LancerLeUserform
End Sub

Merci Eric tout fonctionne, bonne journée à vous.