Creations Fichiers + Dossier

Version imprimable

17/02/2021, 14h49
xstevenetx

Creations Fichiers + Dossier

Bonjour,

Je vous sollicite encore pour une petite demande.

J'aimerais un .bat qui, avec un .txt contenant des adresses IP (une adresse par ligne), et 4 fichiers .php différent.
Me crée 4 dossiers (Acces, Misealheure, Reboot et Screen), puis dans chaque dossier il me prend un fichier .php spécifique et me le copie X fois qu’il y a d'adresse IP avec comme nom les adresses IP.

Exemple :
Acces.php
Misealheure.php
IP.txt -> 192.168.0.1
192.168.0.2

Quand je lance le .bat il me crée :

Dossier Acces -> 192.168.0.1.php = Identique a Acces.php
192.168.0.2.php = Identique a Acces.php

Dossier Misealheure -> 192.168.0.1.php = Identique a Misealheure.php
192.168.0.2.php = Identique a Misealheure.php

J’espère avoir été clair.

Merci beaucoup

Bonjour,

Ca devrait répondre à ta demande :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
@echo off
ver | find "10.0." >nul && chcp 65001 >nul || chcp 28591 >nul
color 0A
mode con cols=100
setlocal enableextensions disabledelayedexpansion
 
if "A%~1A"=="AA" (exit /b 1) else (set ressources=%~1)
 
set "ip=%ressources%\IP.txt"
set "destination=%ressources%\Modèles générés par script"
 
cd /d %ressources% || exit /b 1
 
if not exist "%ip%" (
 
	echo. & echo !!! Le fichier ^>^>^> %ip% ^<^<^< est manquant !!!
	timeout /t 10
	exit /b 1
 
)
 
for %%A in (*.php) do call :generator "%destination%\%%~nA" "%%~fA"
 
echo. & echo. & pause
exit
 
:generator
 
if not exist %1 (mkdir %1)
echo. & echo. & echo ^>^>^>^>^> %~1 & echo.
 
for /f "usebackq tokens=*" %%E in ("IP.txt") do (
 
	xcopy %2 "%~1\" /y /q >nul
	ren "%~1\%~nx2" "%%E.php"  && echo ### %%E.php ^>^>^> OK
 
)
 
goto :eof

Ca fonctionne toujours sur le principe du glisser-déposer.

17/02/2021, 22h02
xstevenetx

Parfait!!!

C'est exactement se que je cherchais.

Merci beaucoup