Paramétrer la numérotation

Version imprimable

Bonsoir.

J'ai un script qui me sert à renommer en masse des fichiers. Je l'ai paramétré pour le choix de l'extension et le nouveau nom.

Mais je n'arrive pas à le faire pour la numérotation sauf si je dois éditer le batch.

Par défaut, la numérotation s'affiche ainsi:

Fichier 001.txt --> File 001.txt

voici le script:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 @echo off & setlocal echo. set /p ext=Taper l'extension (sans le point) des fichiers … renommer ^>^> echo. set /p name=Taper le nouveau nom suivi d'un espace ou d'un tiret ^>^> set "ext=%ext%" & set "Count=1000" for /f "tokens=*" %%a in ( 'dir/b/on/a-d *.%ext%^|findstr/ie "[0-9]\.%ext%"2^>nul') do ( set/a "Count +=1"&&call :ReNum %%Count:~-3%% %%~xa "%%~na") goto :eof :ReNum if not exist File%1%2 ren "%~3%2" "%name%"%1%2
Pour modifier la numérotation, je dois changer 2 valeurs ici en rouge

Count=1000 et Count:~-3 ce qui affiche 001

Count=100 et Count:~-2 ce qui affiche 01

Count=10 et Count:~-1 ce qui affiche 1

Je peux aller jusqu'à 000000001 car la limite est à 9 chiffres [0-9]

Question.

De quelle façon dois-je procéder pour paramétrer la numérotation directement dans la console, comme je le fais pour l'extension et le nom ?

Merci de bien vouloir me guider.

11/12/2020, 08h23
ericlm128
Je ne comprend pas trop ce que tu veux faire ou obtenir

Citation:

Count=1000 et Count:~-3 ce qui affiche 001

Ceci n'a jamais affiché 001
Code:

1 2 3 set "Count=1000" echo %Count:~-3% 000
EDIT : Effectivement il y a un +1

C'est ça que tu veux ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
@echo off
setlocal ENABLEDELAYEDEXPANSION
 
set /p "ext=Taper l'extension (sans le point) des fichiers … renommer ^>^>"
set /p "name=Taper le nouveau nom suivi d'un espace ou d'un tiret ^>^> "
set /p "nbr=Taper le nombre de chiffre pour le compteur ^>^> "
 
set /a Count=0
for /f "tokens=*" %%a in ('dir /b /on /a-d "*.%ext%"^|findstr /ie "[0-9]\.%ext%" 2^>nul') do (
	set /a Count+=1
	set countnbr=00000000000000000000000!Count!
	set countnbr=!countnbr:~-%nbr%!
	if not exist "%name%!countnbr!.%ext%" ren "%%~xna" "%name%!countnbr!.%ext%"
)
 
pause

11/12/2020, 09h55
tease

Bonjour ericlm128

Effectivement, c'est ce que je veux. Mille mercis et bonne journée.
11/12/2020, 16h05
tease

Bonjour

Ce script de ericlm128 m'est très utile vu que je peux renommer des fichiers et insérer des numéros.

Cependant je voudrais ajouter dans ce script un autre paramètre: le choix du début de la numérotation.

J'ai des centaines de dossiers, dans chaque dossier il y a des milliers de fichiers que je dois renommer et numéroter.

Dans le 1er dossier, grâce à ce script, j'ai pu renommer les fichiers de 00001 jusqu'à 38457. Je colle ce script (1 Ko) dans le 2ème dossier, mais au lieu de numéroter les fichiers à partir de 00001, je voudrais avoir la possibilité de taper 38458 pour que la numérotation commence à 38458. C'est pour avoir une suite.

Je sais qu'il existe des logiciels qui font cela mais je ne veux rien installer.

Merci de bien vouloir m'aider.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
@echo off
setlocal ENABLEDELAYEDEXPANSION
 
set /p "ext=Taper l'extension (sans le point) des fichiers … renommer ^>^> "
set /p "name=Taper le nouveau nom suivi d'un espace ou d'un tiret ^>^> "
set /p "nbr=Taper le nombre de chiffre pour le compteur ^>^> "
set /p "Count=Taper le nombre de depart pour le compteur ^>^> "
 
for /f "tokens=*" %%a in ('dir /b /on /a-d "*.%ext%"^|findstr /ie "[0-9]\.%ext%" 2^>nul') do (
	set countnbr=00000000000000000000000!Count!
	set countnbr=!countnbr:~-%nbr%!
	if not exist "%name%!countnbr!.%ext%" ren "%%~xna" "%name%!countnbr!.%ext%"
	set /a Count+=1
)
 
pause

12/12/2020, 10h03
tease

Bonjour ericlm128

Encore une fois, mille mercis pour ton aide précieuse et bonne journée.