Excel VBA : Etat imprimante

Version imprimable

16/10/2020, 14h18
Zeabon

Excel VBA : Etat imprimante

Bonjour à tous,

J'ai un soucis sur une macro VBA (Office 365) et ne trouve pas de solution malgrés les différents postes consultés.

J'ai une imprimante, dédié aux étiquettes, installée sur le PC.
J'ai un fichier excel qui rassemble toutes les informations, les rentres dans un template Word et lance l'impression de l'étiquette. Jusque là, tout va bien.

Mon problème c'est que lorsque l'imprimante est débranché, ma macro continue de lancer les impressions sur l'imprimante et donc me crée une liste d'attente.
(ce qui me fait imprimer des étiquettes inutiles lorsque je la rebranche)

Je souhaites "détecter" lorsque mon imprimante n'est pas branché/hors service afin de pouvoir le signaler à l'utilisateur et ne pas créer de file d'attente.

J'ai essayé de détecté un code d'erreur, mais comme l'imprimante existe et seulement l'état est déconnecté, il n'y a pas d'erreur.

Pour info : le nom de l'imprimante est connue, elle est branché en USB.

J'espère avoir été suffisamment clair.

Merci d'avance,
Zeabon

Bonjour

Je n'ai pas trouvé la solution

ceci peut peut être être un début de réponse.
Code:

1 2 3 4 5 6 7 Private Sub Workbook_BeforePrint(Cancel As Boolean) Reponse = MsgBox("L'imprimante est-elle allumée et alimentée en papier ?", vbYesNo) If Reponse = vbNo Then Cancel = True 'Code pour imprimer End Sub
Le texte pouvant être adapté a l'utilisateur.

Option précisant l'imprimante sélectionnée

Code:

1
2
3
4
5
6
7
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Reponse = MsgBox("L'imprimante sélectionnée est : " & Application.ActivePrinter & Chr(10) & " est-elle allumée et alimentée en papier ?", vbYesNo)
If Reponse = vbNo Then Cancel = True
 
'Code pour imprimer
 
End Sub

hello,
tu peux utiliser une requête WMI sur l'objet Win32_Printer pour savoir si ton imprimante est OffLine.
Voici un bout de code qui renvoie le nom de l'imprimante par défaut puis liste toutes les imprimantes en affichant si elles sont hors tension.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub testprinter() 
    Dim strPrinter
    strPrinter = Application.ActivePrinter
    Debug.Print "Imprimante par défaut : "; strPrinter
    Debug.Print "==========================================="
    Dim objWMIService
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Dim colPrinters
    Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer")
    Dim objPrinter
    For Each objPrinter In colPrinters
        Debug.Print objPrinter.Name
        Debug.Print objPrinter.WorkOffline
        Debug.Print "==========================================="
    Next
End Sub

Si tu ne veux voir que l'état de l'imprimante par défaut :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Sub testprinter() 
    Dim objWMIService
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Dim colPrinters
    Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer Where Default = True ")
    Dim objPrinter
    For Each objPrinter In colPrinters
        Debug.Print objPrinter.Name
        Debug.Print objPrinter.WorkOffline
        Debug.Print "==========================================="
    Next
End Sub

Ami calmant, J.P

19/10/2020, 08h50
Zeabon

Bonjour a_diard,

Je vois ce que tu veux faire mais mon objectif c'est d'automatiser.
je ne veux pas laisser le choix à l'utilisateur et ajouté des fenêtres de validation à chaque fois (j'en ai déjà plein à côté).
Et au pire, ils ont un bouton de réimpression de disponible.
Merci à toi pour ton aide.

Bonjour Jurassic pork,

Je ne connaissait pas les requêtes WMI. Je regarde ça.

Je serais plus tenté par l'état de l'imprimante par défaut :
- Je mets l'imprimante en par défaut
- Si erreur<> 0 => Imprimante non installé sur le pc
- Sinon test si Offline avec ton code
- Impression si tout est OK.

Je reviens vers vous dès que j'ai testé.

Merci à vous.

Zeabon

Re-bonjour à tous,

Je viens de tester la solution de jurrasic pork et tout marche nickel.

Je donne la partie de test (comme expliqué dans le mail précédent) pour ce que ça intéresse :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
    On Error Resume Next
    err.Clear
    ImprNow = Imp_Label.ActivePrinter
    Imp_Label.ActivePrinter = "TSC TC310"
    If err <> 0 Then
        Msg = MsgBox("Imprimante d'étiquette non installé. Veuillez contacter le service informatique pour faire l'installation.", , "Impression impossible")
    Else
        Dim objWMIService
        Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
        Dim colPrinters
        Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer Where Default = True ")
        Dim objPrinter
        For Each objPrinter In colPrinters
            If objPrinter.WorkOffline = False Then
                Imp_Label.Run ("Label.docm'!Impression.Impr")
            Else
                Msg = MsgBox("Imprimante d'étiquette non connecté.", , "Impression impossible")
            End If
        Next
    End If
    Imp_Label.ActivePrinter = ImprNow

Merci à vous.

Zeabon