problème d'exécution de macro

Version imprimable

Bonjour à tous

j'ai tenter de réaliser une macro permettant d’ouvrir ou fermer des onglets (60 environ) en fonctions du nom de l'onglet de chaque feuille.

ma macro fonctionne quand je la lance dans le module développeur / visual basic, par contre elle plante quand je l’exécute a partir d'un bouton de commande.j'ai une erreur d'execution '9': l'indice n'appartient pas à la sélection
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 Sub Display_V2() Dim ligne As Integer: Dim colonne_condition As Integer: Dim colonne_sheet As Integer Dim m As String Dim wsManager As Worksheet 'Paramétrer la feuille Set wsManager = ThisWorkbook.Sheets("00-Manager") 'Récupérer le nombre de lignes par feuille nbreLignesData = wsManager.Cells.Find("*", , , , , xlPrevious).Row colonne_sheet = 11 colonne_condition = 5 Application.Calculation = xlCalculationManual Application.ScreenUpdating = False For ligne = 26 To nbreLignesData m = Cells(ligne, colonne_sheet) If Cells(ligne, colonne_condition).Value = "ON" Then Worksheets(m).Visible = xlSheetVisible Else: Worksheets(m).Visible = xlSheetHidden End If Next ligne Application.Calculation = xlCalculationAutomatic Application.ScreenUpdating = True End Sub
Auriez des pistes ? Merci d'avance pour vos retours

05/10/2020, 14h18
Philippe Tulliez

Bonjour,
Pour pouvoir vous aider, merci de placer le code VBA entre les balises prévues à cet effet (croisillons (#) et de nous indiquer à quelle n° de ligne a lieu l'erreur que vous signalez
05/10/2020, 14h45
bertrand_b

l'anomalie apparait à la ligne 22 (Worksheets(m).Visible = xlSheetHidden)

Bonjour bertrand_b,

Voici , vite fait, comment je procéderais : sur base d'un tableau Structuré ( un minimum en 2020).

Je diviserai en 3 procédures, 1 procédure main (Sub testbertrand_b) et deux Functions (HideUnhideSheet & SheetExists (de Pierre F.))

En gros le fonctionnement , après paramétrages :

Pour chaque ligne du tableau de correspondance (ici nommé "Table1")
On vérifie si la feuille (nom = colonne colShName) existe ( Function SheetExists (de Pierre F.))
Si existe on applique la "visibilité" en fonction de la deuxième colonne (ColOnOff) via la function HideUnhideSheet

En fin de macro, msgbox d'erreur , si erreur il y a.

Les différents code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub testbertrand_b()
 
Dim wb As Workbook
Dim iRow As Long
Dim check As Boolean
 
Dim shName As String
Dim visible As String
Dim fdcbk As String
 
'Paramètres à modifier
 
Set wb = ThisWorkbook                                          'Par défaut, on va travailler dans ThisWorkbook, classeur d'ou on lance la macro
Dim tableName As String: tableName = "Table1"          'Nom du tableau entre ""
Dim colShName As String: colShName = "SheetName"  'Nom de la colonne contenant le nom des Feuilles entre ""
Dim ColOnOff As String: ColOnOff = "Visible"              'Nom de la colonne contenant le critère visible,non visible ""
Dim critVisible As String: critVisible = "on"                 'Critère text pour visibilité on = visible
 
With Range(tableName).ListObject
 
 For iRow = 1 To .ListRows.Count
 
     shName = .ListColumns(colShName).DataBodyRange.Rows(iRow)
 
     If SheetExists(shName, wb) Then
        visible = .ListColumns(ColOnOff).DataBodyRange.Rows(iRow)
        check = HideUnhideSheet(shName, IIf(UCase(visible) = UCase(critVisible), 1, 2), wb)
        If check = False Then fdcbk = fdcbk & vbNewLine & shName & " : Error visible code not found."
     Else
        fdcbk = fdcbk & vbNewLine & "La Feuille " & shName & " n'existe pas dans le classeur " & wb.Name & "."
     End If
 Next iRow
 
End With
 
If fdcbk <> "" Then MsgBox fdcbk
 
 
Set wb = Nothing
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Function HideUnhideSheet(ByVal shName As String, ByVal visibleCode As Integer, Optional wb As Workbook) As Boolean
 
'Code 1 = xlSheetVisible
'Code 2 = xlSheetHidden
'Code 3 = xlSheetVeryHidden
HideUnhideSheet = True
 
  If wb Is Nothing Then Set wb = ActiveWorkbook
 
    Select Case visibleCode
      Case Is = 1
       wb.Worksheets(shName).visible = xlSheetVisible
      Case Is = 2
       wb.Worksheets(shName).visible = xlSheetHidden
      Case Is = 3
       wb.Worksheets(shName).visible = xlSheetVeryHidden
      Case Else
       HideUnhideSheet = False
    End Select
 
End Function

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Function SheetExists(ByVal shName As String, Optional wb As Workbook) As Boolean
'Function de Pierre F sur Dvp
'Return True if sheet exist
'https://www.developpez.net/forums/blogs/27262-pierre-fauconnier/b8231/vba-excel-verifier-quune-feuille-existe-classeur-trouver-feuille-nom-classeur/
  Dim Counter As Long: Counter = 1
 
  If wb Is Nothing Then Set wb = ActiveWorkbook
  Do While Counter <= wb.Sheets.Count And Not SheetExists
    SheetExists = StrComp(shName, wb.Sheets(Counter).Name, vbTextCompare) = 0
    Counter = Counter + 1
  Loop
End Function

(Et le Workbook test en PJ)

05/10/2020, 15h21
bertrand_b

Merci beaucoup Mfoxy, ta méthode fonctionne parfaitement, sinon concernant mon code que vaut il vraiment ?histoire de m'améliorer
14/10/2020, 09h53
MarcelG

Bonjour Michaël,

Ce n'est pas grave bien entendu,

Je ne vois pas de classeur test en pièce jointe.