Problème ouverture page word depuis Excel

Version imprimable

02/07/2020, 17h19
BiRoy

1 pièce(s) jointe(s)

Problème ouverture page word depuis Excel

Bonjour,

Je crée une application Excel permettant entre autre de piloter le publipostage d'une macro créée dans Word.
En essayant d'exécuter directement la macro Word depuis Excel, plusieurs problèmes se posent : il m'affiche que la source de données n'est pas au bon format alors que c'est un format XLSM et que cela fonctionne si on lance la macro depuis Word et quand ce problème n’apparaît pas, il y a un problème au niveau de l'envoi disant que les destinataires ne sont pas sélectionnés, message qui n’apparaît pas non plus e exécutant la macro depuis Word.
J'ai donc décidé de faire en sorte que la macro Excel ne fasse qu'ouvrir le fichier sélectionné dans Word afin d'exécuter la macro depuis Word, ce qui permet aux utilisateurs d'éventuellement modifier les mails qu'ils souhaitent envoyer mais un message apparaît :
" L'Ouverture de ce document exécute la commande SQL suivante :
SELECT * FROM 'liste'$
Des données de votre base de données seront insérés dans le document.Voulez-vous continuer ?
Oui NON"

Je n'ai pas réussi à ce que ce message ne se génère pas, le problème n'est pas là.En effet, lorsque Excel est en plein écran ou couvre le milieu de l'écran, ce message apparaît derrière et on ne peut pas y accéder et donc pas ouvrir le fichier Word correspondant, et l'on ne peut pas déplacer la fenêtre Excel puisque la macro est en cours d'exécution et lorsque que l'on n'exécute pas la macro depuis la fenêtre de VBA, on ne peut même pas arrêter le chargement et tout se retrouve bloqué par ce message caché.

J'espère que vous pourrez m'aider sur l'un de ces problèmes.
Merci :)
02/07/2020, 18h12
Invité

Citation:

Envoyé par BiRoy

Bonjour,

Si vous faites de l'Excel vers Word, ce ne serait pas plus simple d'injecter directement vos valeurs dans des signets ?
02/07/2020, 18h52
Philippe Tulliez

Bonjour Eric,

Citation:

Si vous faites de l'Excel vers Word, ce ne serait pas plus simple d'injecter directement vos valeurs dans des signets ?

100% d'accord avec toi

Ma première expérience en VBA Excel Word, il y a 20 ans, a été de créer une interface basée sur le publipostage, le parcours du combattant. Une première release pour 2003 a renvoyé un message d'alerte de sécurité.
De plus à l'époque trouver des sites qui parlais du VBA pour Word était une véritable galère.

Depuis j'utilise les signets. Un véritable bonheur.
02/07/2020, 23h38
BiRoy

Bonjour,

Merci pour vos réponses. Je ne sais pas comment fonctionnent les signets, c'est pour cela que j'ai choisi cette méthode.
Si vous pouvez m'expliquer en quelques mots, je serai ravie d'essayer.

Merci

Citation:

Envoyé par BiRoy

(Bonjour Philippe :coucou:)

Cette solution est suffisante dans le cas d'un document créé à partir d'un modèle et utilisé une seule fois (cas d'un publipostage). Si le document créé doit être mis à jour plusieurs fois, il faudra reconstruire le signet après remplacement. Ce point est bien expliqué par Olivier LEBEAU dans son tuto VBA Word.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
 
Option Explicit
 
Sub CreerLesDocuments()
 
'Dim WApp As Word.Application, DocWord As Word.Document
Dim WApp As Object, DocWord As Object  ' En late binding
Dim LigneEncours As Long, DerniereLigne As Long
Dim AireDocuments As Range
 
    With Sheets("Feuil1")
         DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row
         Set AireDocuments = .Range(.Cells(2, 1), .Cells(DerniereLigne, 1))
    End With
 
    Set WApp = CreateObject("word.application")
    With WApp
         .Visible = True
         For LigneEncours = 1 To AireDocuments.Count
             With AireDocuments(LigneEncours)
                  Set DocWord = WApp.Documents.Add(Template:=ThisWorkbook.Path & "\Modèle courrier.dotx")
                  MajSignets DocWord, AireDocuments(LigneEncours)
                  DocWord.SaveAs Filename:=ThisWorkbook.Path & "\" & AireDocuments(LigneEncours).Value & ".docx", FileFormat:=12
                  DocWord.Close
             End With
         Next LigneEncours
    End With
    WApp.Quit
 
    MsgBox "Fin de création des courriers !", vbInformation
 
    Set DocWord = Nothing
    Set WApp = Nothing
    Set AireDocuments = Nothing
 
End Sub
 
 
Sub MajSignets(ByVal DocAModifier As Word.Document, ByVal CelluleEnCours As Range)
 
Dim ColEnCours As Integer
 
    ColEnCours = CelluleEnCours.Column
 
    With DocAModifier
         .Bookmarks("Date_étab").Range.Text = CelluleEnCours.Offset(0, 1 - ColEnCours)
         .Bookmarks("Ref").Range.Text = CelluleEnCours.Offset(0, 2 - ColEnCours)
         .Bookmarks("Nom").Range.Text = CelluleEnCours.Offset(0, 3 - ColEnCours)
         .Bookmarks("Prénom").Range.Text = CelluleEnCours.Offset(0, 4 - ColEnCours)
         .Bookmarks("Adresse").Range.Text = CelluleEnCours.Offset(0, 5 - ColEnCours)
         .Bookmarks("Complément").Range.Text = CelluleEnCours.Offset(0, 6 - ColEnCours)
         .Bookmarks("CP").Range.Text = CelluleEnCours.Offset(0, 7 - ColEnCours)
         .Bookmarks("Ville").Range.Text = CelluleEnCours.Offset(0, 8 - ColEnCours)
         .Bookmarks("Traité_par").Range.Text = CelluleEnCours.Offset(0, 9 - ColEnCours)
    End With
 
End Sub

06/07/2020, 19h01
BiRoy

Merci beaucoup !!
Je vais essayer ce morceau de code et je mettrai le problème comme résolu dès que ce sera bon pour moi ;)